¿Cómo encontrar y reemplazar texto y luego conservar el formato en Excel?

La función Buscar y Reemplazar es poderosa y útil cuando necesitamos encontrar un valor específico y reemplazarlo por otro. Sin embargo, si hay un rango de celdas y algunas de las celdas incluyen valores con diferentes formatos, usar la función Buscar y Reemplazar para encontrar y reemplazar valores romperá el formato de los valores en las celdas, como se muestra en la captura de pantalla a continuación. Entonces, ¿cómo podemos conservar el formato de los valores en cada celda mientras buscamos y reemplazamos en Excel?

Buscar y reemplazar conservando el formato con código de Macro

Buscar y reemplazar conservando el formato con código de Macro

No hay otros métodos, solo el código de macro puede ayudarte a buscar y reemplazar texto y conservar el formato.

1. Presiona las teclas Alt + F11 para abrir la ventana Microsoft Visual Basic for Application.

2. Haz clic en Insertar > Módulo, y pega el siguiente código en el script.

VBA: Buscar y reemplazar conservando el formato

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

Consejo: En el código, KK es la cadena que deseas encontrar, y Kutools es la cadena con la que deseas reemplazarla; puedes cambiarlas según sea necesario.

3. Presiona F5 y aparecerá un cuadro de diálogo para que selecciones un rango donde buscar y reemplazar, como se muestra en la captura de pantalla:

4. Haz clic en Aceptar, y la cadena específica en las celdas seleccionadas será reemplazada por otra, manteniendo el formato.