¿Cómo realizar un seguimiento de los cambios sin compartir el libro de trabajo?

Normalmente, cuando aplicas la función Seguimiento de Cambios en Excel, el libro de trabajo se compartirá al mismo tiempo, lo cual puede ser molesto porque algunas de las funciones de Excel se desactivarán. ¿Cómo podrías hacer un seguimiento de los cambios sin compartir el libro de trabajo? Aquí te recomendaré un código VBA.

Realizar un seguimiento de los cambios sin compartir el libro de trabajo con código VBA

Convertir texto a tabla en Outlook

No hay una manera directa de resolver este problema, pero puedes usar un código VBA flexible. Por favor, sigue estos pasos:

1. Haz clic derecho en la pestaña de la hoja en la que deseas hacer un seguimiento de las celdas modificadas y selecciona Ver Código en el menú contextual; en la ventana emergente de Microsoft Visual Basic para Aplicaciones, copia y pega el siguiente código en el Módulo en blanco:

Código VBA: Realizar un seguimiento de los cambios sin compartir el libro de trabajo:

Private Sub Worksheet_Change(ByVal Target As Range)
  'Updateby Extendoffice
    Const xRg As String = "A1:Z1000"
    Dim strOld As String
    Dim strNew As String
    Dim strCmt As String
    Dim xLen As Long
    With Target(1)
        If Intersect(.Cells, Range(xRg)) Is Nothing Then Exit Sub
        strNew = .Text
        Application.EnableEvents = False
        Application.Undo
        strOld = .Text
        .Value = strNew
        Application.EnableEvents = True
        strCmt = "Edit: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " by " & _
        Application.UserName & Chr(10) & "Previous Text :- " & strOld
        If Target(1).Comment Is Nothing Then
            .AddComment
        Else
            xLen = Len(.Comment.Shape.TextFrame.Characters.Text)
        End If
        With .Comment.Shape.TextFrame
            .AutoSize = True
            .Characters(Start:=xLen + 1).Insert IIf(xLen, vbLf, "") & strCmt
        End With
    End With
End Sub

Nota: En el código anterior, A1:Z1000 es el rango de datos en el que deseas realizar un seguimiento de los cambios.

2. Luego guarda y cierra esta ventana de código. Ahora, cuando cambies los valores en cualquier celda dentro del rango especificado, los cambios se registrarán sin necesidad de compartir el libro de trabajo. Ver captura de pantalla: