Tutorial de Excel – extraer texto o número por posición específica

En muchos casos, es posible que solo necesites extraer el contenido útil de una frase o cadena de texto en una celda, como extraer la provincia de una dirección, extraer la dirección de correo electrónico de una frase, extraer el número de guía de una conversación, entre otros. Este tutorial se enfoca en la extracción desde una posición específica dentro de una celda y recopila diferentes métodos para ayudarte a extraer texto o números de una celda según una posición específica en Excel.

Extraer texto por posición

Esta sección reúne las posiciones comunes desde donde se puede extraer texto de una celda y proporciona métodos correspondientes para manejarlas paso a paso. Puede examinar para más detalles.

1. Extraer el número de caracteres desde la izquierda o la derecha

Para extraer el número de caracteres desde el lado izquierdo o derecho de una cadena, puedes probar uno de los siguientes métodos.

1.1 Extraer los primeros o últimos N caracteres con fórmulas

Supongamos que tienes una lista de cadenas de texto en la columna B, como se muestra en la captura de pantalla a continuación. Para extraer los primeros 2 caracteres y los últimos 2 caracteres de cada cadena, puedes aplicar las siguientes fórmulas.

Extraer los primeros N caracteres de una cadena de texto

La función IZQUIERDA puede ayudar a extraer fácilmente los primeros N caracteres de una cadena de texto en Excel.

Fórmula genérica

=IZQUIERDA(texto_cadena,[num_caracteres])

Argumentos

Ahora puedes aplicar esta fórmula para extraer los primeros 2 caracteres de las celdas en la columna B.

1. Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el primer resultado. Seleccione la celda del resultado y arrastre su Controlador de Autocompletar hacia abajo para aplicar la fórmula a otras celdas.

=LEFT(B5,2)

Ahora has extraído los primeros 2 caracteres en cada celda del rango dado.

Extraer los últimos N caracteres de una cadena de texto

Aquí aplicamos la función DERECHA para extraer los últimos N caracteres de una cadena de texto en Excel.

Fórmula genérica

=DERECHA(cadena_de_texto,[num_caracteres])

Argumentos

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Luego, seleccione esta celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para obtener otros resultados.

=RIGHT(B5,2)

1.2 Extraer los primeros o últimos N caracteres con una herramienta asombrosa

Aunque las fórmulas anteriores son simples, para extraer los primeros o últimos n caracteres de una larga lista de cadenas de texto, todavía necesitas arrastrar el controlador de AutoRelleno de arriba hacia abajo, lo que puede ser un poco consumidor de tiempo. Aquí, recomendamos la utilidad "Extraer texto" de "Kutools para Excel" para ayudarte a extraer los primeros o últimos N caracteres de una lista de cadenas de texto en masa.

1. Seleccione de antemano la lista de cadenas de texto de la que desea extraer texto y haga clic en "Kutools" > "Texto" > "Extraer texto".

2. En el cuadro de diálogo "Extraer texto" que aparece, debe configurar lo siguiente.

Nota: Para que el resultado sea dinámico cuando cambie la cadena de texto, puede marcar la casilla "Insertar como fórmula".

3. En el siguiente cuadro de diálogo "Extraer texto" que aparece, elija una celda para mostrar los caracteres extraídos y luego haga clic en "Aceptar".

Luego, se extraen los primeros N o últimos N caracteres de las celdas seleccionadas en masa.

Haz clic para saber más sobre esta función.

2. Extraer texto antes o después de un determinado carácter/palabra

Para extraer texto antes o después de un determinado carácter o palabra, los diferentes escenarios en esta sección satisfarán tus necesidades.

2.1 Extraer texto antes o después del primer delimitador (un carácter)

Como se muestra en la captura de pantalla a continuación, para extraer texto antes o después del primer delimitador de cada celda en el rango B4:B10, puedes aplicar uno de los siguientes métodos.

2.1.1 Extraer texto antes del primer delimitador con fórmula

Aplicar una fórmula basada en las funciones IZQUIERDA y ENCONTRAR puede ayudarte a extraer el texto antes del primer delimitador de una celda. Puedes seguir los pasos a continuación para llevarlo a cabo.

Fórmula genérica

=IZQUIERDA(cadena_de_texto,ENCONTRAR("delimitador",cadena_de_texto,1)-1)

Argumentos

Seleccione una celda en blanco, copie o introduzca la fórmula a continuación en ella y presione la tecla "Enter" para obtener el primer resultado. Seleccione la primera celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para obtener los textos antes del primer delimitador de otras celdas.

=LEFT(B5,FIND("-",B5,1)-1)

2.1.2 Extraer texto después del primer delimitador con fórmula

La siguiente fórmula ayuda a extraer texto después del primer delimitador de una celda en Excel.

Fórmula genérica

=EXTRAE(cadena_de_texto,ENCONTRAR("delimitador",cadena_de_texto)+1,LARGO(cadena_de_texto))

Argumentos

=MID(B5,FIND("-",B5)+1,LEN(B5))

2.1.3 Extraer texto antes o después del primer delimitador con una herramienta asombrosa

Aquí, recomendamos encarecidamente la utilidad "Extraer texto" de "Kutools para Excel". Con esta función, puede extraer fácilmente textos antes o después del primer delimitador de un rango de celdas en masa.

1. Seleccione el rango de celdas del que desea extraer el texto y, a continuación, haga clic en "Kutools" > "Texto" > "Extraer texto".

2. En el cuadro de diálogo "Extraer texto", debe configurar lo siguiente.

Nota: Para que el resultado sea dinámico cuando cambie la cadena de texto, puede marcar la casilla Insertar como fórmula.

3. Luego, aparece otro cuadro de diálogo "Extraer texto", elija una celda para mostrar los resultados y haga clic en "Aceptar".

Luego, los textos antes o después del primer delimitador se extraen de las celdas seleccionadas de una vez.

Para obtener más información sobre esta función, visite: Extraer rápidamente cierto texto de las celdas en Excel.

2.2 Extraer texto antes o después del último delimitador (un carácter)

En los pasos anteriores, hemos aprendido los métodos para extraer texto antes o después del primer delimitador de una celda. Como se muestra en la captura de pantalla a continuación, esta sección le mostrará dos fórmulas para extraer texto antes o después del último delimitador de una celda. Puede seguir los pasos a continuación para llevarlo a cabo.

2.2.1 Extraer texto antes del último delimitador con fórmula

Para extraer el texto antes del último delimitador de una celda, puedes usar las funciones BUSCAR, LARGO y SUSTITUIR dentro de la función IZQUIERDA.

Fórmula genérica

=IZQUIERDA(cadena_de_texto,BUSCAR("#",SUSTITUIR(cadena_de_texto,"delimitador","#",LARGO(cadena_de_texto)-LARGO(SUSTITUIR(cadena_de_texto,"delimitador",""))))-1)

Argumentos

Seleccione una celda, ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para extraer los textos de otras cadenas de texto en la misma columna.

=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)

2.2.2 Extraer texto después del último delimitador con fórmula

Después de extraer el texto antes del último delimitador de una celda, puedes aplicar la fórmula a continuación para extraer el texto después del último delimitador según lo necesites.

Fórmula genérica

=DERECHA(cadena_texto,LARGO(cadena_texto)-BUSCAR("#",SUSTITUIR(cadena_texto,"delimitador","#",LARGO(cadena_texto)-LARGO(SUSTITUIR(cadena_texto,"delimitador","")))))

Argumentos

Seleccione una celda, ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para extraer los textos de otras cadenas de texto en la misma columna.

=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))

2.3 Extraer texto después del carácter enésimo

Observa el ejemplo a continuación, hay una lista de cadenas de texto en el rango B4:B10. Para extraer el texto después del tercer carácter de cada celda, puedes aplicar una fórmula basada en la función MEDIO y la función LARGO.

Fórmula genérica

=EXTRAE(cadena_de_texto,nth_char+1,LARGO(cadena_de_texto))

Argumentos

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación en ella y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para obtener otros resultados.

=MID(B5,3+1,LEN(B5))

2.4 Extraer la palabra N de una cadena de texto

Supongamos que tienes una lista de cadenas de texto como se muestra en la captura de pantalla a continuación, y deseas extraer solo la n-ésima palabra de la cadena de texto; esta sección te ofrece tres métodos para lograrlo.

2.4.1 Extraer la palabra N con fórmula

Puedes combinar las funciones TRIM, MEDIO, SUSTITUIR, REPETIR y LARGO para extraer la n-ésima palabra de una cadena de texto en una celda.

Fórmula genérica

=RECORTAR(EXTRAE(SUSTITUIR(texto_cadena," ",REPETIR(" ",LARGO((texto_cadena))), (N-1)*LARGO((texto_cadena)+1, LARGO((texto_cadena)))

Argumentos

En este caso, el rango B5:B10 contiene las cadenas de texto, D5:D10 contiene los números que representan la n-ésima palabra, apliquemos esta fórmula para extraer la n-ésima palabra de la cadena de texto.

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación en ella y presione la tecla "Enter" para obtener el primer resultado. Seleccione esta celda de resultado y arrastre su Controlador de Autocompletar hacia abajo para obtener la n-ésima palabra de otras celdas.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))

Nota: Puede escribir directamente el número enésimo en la fórmula de la siguiente manera.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))

2.4.2 Extraer la palabra N con una función definida por el usuario

Además de la fórmula anterior, también puedes aplicar una función definida por el usuario para extraer la palabra N de una celda en Excel.

1. Presiona las teclas "Alt" + "F11" para abrir la ventana "Microsoft Visual Basic for Applications".

2. En la ventana "Microsoft Visual Basic for Applications", haga clic en "Insertar" > "Módulo", y luego copie el siguiente código VBA en la ventana de Código.

Código VBA: Extraer la palabra N de una cadena de texto en una celda

Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
    FindWord = ""
Else
    FindWord = arr(Position - 1)
End If
End Function

3. Presione las teclas "Alt" + "Q" para cerrar la ventana "Microsoft Visual Basic for Applications".

4. Vuelva a la hoja de cálculo que contiene las cadenas de texto de las que desea extraer la n-ésima palabra. Seleccione una celda en blanco, copie o introduzca la fórmula a continuación en ella y presione la tecla "Enter" para obtener la n-ésima palabra.

=FindWord(B5,D5)

O

=FindWord(B5,2)

Nota: en la fórmula, D5 es la celda que contiene un número que representa la n-ésima palabra. Alternativamente, puedes reemplazar directamente la referencia de la celda por un número.

5. Seleccione la celda de resultado y arrastre su controlador de relleno automático hacia abajo para extraer la n-ésima palabra de las cadenas de texto de otras celdas.

2.4.3 Extraer la palabra N con una herramienta asombrosa

Si no desea aplicar manualmente una fórmula o una función definida por el usuario proporcionada anteriormente, aquí recomendamos la utilidad "Extraer la palabra N de una celda" de Kutools para Excel. Con esta función, puede extraer fácilmente la enésima palabra de una cadena de texto en una celda con solo unos pocos clics.

1. Seleccione una celda para colocar el resultado, y haga clic en "Kutools" > "Asistente de fórmulas" > "Texto" > "Extraer" "la palabra N en una celda". Vea la captura de pantalla:

2. En el cuadro de diálogo "Asistente de fórmulas", debe configurar lo siguiente.

3. Luego, la n-ésima (segunda) palabra se extrae de la cadena de texto en la celda B5, y puedes ver que al mismo tiempo se crea una fórmula. Selecciona esta celda de resultado y arrastra su controlador de autocompletado hacia abajo para obtener la n-ésima palabra de otras cadenas de texto.

Haz clic para saber más sobre esta función.

2.5 Extraer texto antes o después de la n-ésima aparición de un delimitador

Supongamos que tienes una lista de cadenas de texto como se muestra en la captura de pantalla a continuación. Para extraer el texto antes o después de la segunda aparición de un espacio, esta sección proporciona dos fórmulas para ayudarte a lograrlo.

2.5.1 Extraer texto antes de la n-ésima aparición de un delimitador

Puede usar la función IZQUIERDA junto con las funciones SUSTITUIR y ENCONTRAR para extraer texto antes de la n-ésima aparición de un delimitador en una celda de Excel.

Fórmula genérica

=IZQUIERDA(SUSTITUIR(cadena_texto,"delimitador",CARACTER(9),n),ENCONTRAR(CARACTER(9),SUSTITUIR(cadena_texto,"delimitador",CARACTER(9),n),1)-1)

Argumentos

Seleccione una celda, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y arrastre el controlador de AutoFill hacia abajo para obtener otros resultados en la lista.

=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)

Nota: En la fórmula, B5 es la celda que contiene la cadena de texto de la cual desea extraer el texto; “ ” aquí representa un espacio y el número 2 representa la segunda aparición de un espacio. Puede cambiarlos según sus necesidades.

2.5.2 Extraer texto después de la n-ésima aparición de un delimitador

Para extraer texto después de la n-ésima aparición de un delimitador, puedes aplicar la función DERECHA junto con las funciones SUSTITUIR, LARGO y ENCONTRAR.

Fórmula genérica

=DERECHA(SUSTITUIR(texto_cadena, "delimitador", CARACTER(9), n), LARGO(texto_cadena)- ENCONTRAR(CARACTER(9), SUSTITUIR(texto_cadena, "delimitador", CARACTER(9), n), 1) + 1)

Argumentos

Ahora puede aplicar esta fórmula para extraer el texto después de la segunda aparición del espacio en cada celda del rango B5:B10 de la siguiente manera.

Seleccione una celda, ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y arrastre el controlador de AutoFill hacia abajo para obtener otros resultados.

=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)

2.6 Extraer texto antes o después de un salto de línea

Supongamos que tienes una lista de pedidos en la columna B y deseas extraer solo la parte de la fecha y el número de producto de cada celda. Puedes usar las siguientes fórmulas de Excel para hacerlo.

2.6.1 Extraer texto antes del primer salto de línea con fórmula

Como puede ver en la captura de pantalla anterior, la parte de la fecha se encuentra antes del primer salto de línea dentro de la celda. En esta sección, se demostrará una función IZQUIERDA junto con la función BUSCAR para ayudarle a extraer el texto antes del primer salto de línea dentro de una celda.

Fórmula genérica

=IZQUIERDA(celda, BUSCAR(CARACTER(10), celda)-1)

Argumentos

Seleccione una celda en blanco, copie o introduzca la fórmula a continuación en ella y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=LEFT(B5, SEARCH(CHAR(10), B5)-1)

Luego puedes ver que el texto antes del primer salto de línea en cada celda del rango B5:B8 se ha extraído, como se muestra en la captura de pantalla a continuación.

Nota: En la fórmula, CARACTER(10) representa un salto de línea en Windows.

2.6.2 Extraer texto después del último salto de línea con fórmula

En el paso anterior, hablamos sobre cómo extraer texto antes del primer salto de línea dentro de una celda. Y esta parte le guiará sobre cómo extraer texto después del último salto de línea dentro de una celda utilizando una fórmula diferente.

Fórmula genérica

=RECORTAR(DERECHA(SUSTITUIR(celda,CARACTER(10),REPETIR(" ",200)),200))

Argumentos

Seleccione una celda en blanco, introduzca la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su controlador de AutoFill hacia abajo para aplicar la fórmula a otras celdas.

=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))

Luego, se extrae la parte del número de producto de cada celda en la lista, tal como se muestra en la captura de pantalla anterior.

Nota: En la fórmula, CARACTER(10) representa un salto de línea en Windows.

  2.7 Extraer texto antes o después de una palabra

En las partes anteriores, hemos aprendido cómo extraer texto antes o después de un carácter o delimitador. ¿Qué debe hacer para extraer texto antes o después de una palabra completa? Esta sección presentará tres métodos para ayudarle a realizar esta tarea.

2.7.1 Extraer texto antes de una palabra específica con fórmula

La siguiente fórmula te ayuda a extraer el texto antes de una palabra específica dentro de una celda en Excel.

Fórmula genérica

=SI.ERROR(IZQUIERDA(celda,HALLAR(palabra,celda)-1),celda)

Argumentos

Seleccione una celda en blanco, ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

En este ejemplo, vamos a extraer todos los textos antes de la palabra “Excel”, así que escribimos directamente la palabra en la fórmula y la encerramos entre comillas dobles. O también puedes hacer referencia a una celda que contenga la palabra “Excel”.

=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)

Notas:

2.7.2 Extraer texto después de una palabra específica con fórmula

Para extraer texto después de una palabra específica, puedes aplicar la siguiente fórmula para lograrlo.

Fórmula genérica

=RECORTAR(EXTRAE(celda,BUSCAR(word,celda)+LARGO(word),255))

Argumentos

Seleccione una celda, ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione la celda del resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))

Luego puedes ver que todos los textos después de la palabra “Excel” en cada celda se han extraído, como se muestra en la captura de pantalla a continuación.

Notas:

2.7.3 Extraer texto antes o después de una palabra específica con una herramienta asombrosa

Si sientes que el uso de fórmulas puede causar muchas inconveniencias, aquí te recomendamos encarecidamente la utilidad "Extraer texto" de "Kutools for Excel". Esta función ayuda a automatizar la tarea de Extracción en Excel con solo unos pocos clics.

1. Haga clic en "Kutools" > "Texto" > "Extraer texto" para habilitar esta función.

2. En el cuadro de diálogo "Extraer texto", realiza la siguiente configuración.

2.1) Asegúrese de que está en la pestaña "Extraer por posición";

2.2) En el cuadro "Rango", haz clic en el botón para seleccionar el rango de celdas donde desea extraer los textos;

2.3) En la sección "Opciones":

Para extraer todos los textos antes de una palabra, seleccione el botón de opción "antes del texto" y luego ingrese la palabra en el cuadro de texto.

Para extraer todos los textos después de una palabra, elija el botón de radio "después del texto" y luego ingrese la palabra en el cuadro de texto.

2.4) Haga clic en el botón "Aceptar". Vea la captura de pantalla:

Notas: Si desea crear resultados dinámicos, marque la casilla "Insertar como fórmula". Luego, los resultados se actualizarán automáticamente cuando cambien los datos en el rango.

3. Luego aparece un cuadro de diálogo "Extraer texto", necesitas seleccionar una celda para mostrar el resultado y luego hacer clic en el botón "Aceptar".

Luego, los textos antes o después de una palabra específica dentro de cada celda en el rango seleccionado se extraen de inmediato.

Nota: Esta función distingue entre mayúsculas y minúsculas.

Haz clic para saber más sobre esta función.

3. Extraer entre caracteres/palabras

Si desea extraer texto entre ciertos caracteres o palabras, pruebe los siguientes métodos.

3.1 Extraer texto entre dos caracteres

Para extraer texto entre dos caracteres, los cuales pueden ser iguales o diferentes. Esta sección proporciona varios métodos, y puedes elegir el que mejor se adapte a tus necesidades.

 3.1.1 Extraer texto entre dos mismos caracteres con fórmula

Como se muestra en la captura de pantalla a continuación, hay una lista de cadenas de texto en la columna B, y desea extraer la parte numérica entre los caracteres “/” de cada celda en el rango; la siguiente fórmula puede ayudarle.

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione la celda del resultado y luego arrastre el controlador de AutoFill hacia abajo para obtener resultados para otras celdas en la lista.

=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")

Luego, se extrae el texto entre dos caracteres iguales “/” de cada celda en el rango. Ver captura de pantalla:

Nota:

 3.1.2 Extraer texto entre dos caracteres diferentes con fórmula

Después de aprender cómo extraer texto entre dos caracteres iguales dentro de una celda, aquí demostraremos una fórmula para extraer texto entre dos caracteres diferentes. Como se muestra en la captura de pantalla a continuación, para extraer solo la dirección de correo electrónico entre los símbolos “<” y “>” de cada celda en la columna B, puede hacer lo siguiente.

Fórmula genérica

=EXTRAE(IZQUIERDA(celda,HALLAR("end_char",celda)-1),HALLAR("start_char",celda)+1,LARGO(celda))

Argumentos

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))

Puede ver que solo se extrae el texto entre los caracteres especificados, como se muestra en la captura de pantalla anterior.

3.1.3 Extraer texto entre dos caracteres con una herramienta asombrosa

Aquí, recomendamos encarecidamente la función "Extraer el texto entre textos especificados" de "Kutools para Excel" para ayudarte a extraer fácilmente texto entre dos caracteres iguales o diferentes dentro de una celda en Excel.

1. Seleccione una celda en blanco para mostrar el resultado y, a continuación, haga clic en "Kutools" > "Asistente de fórmulas" > "Asistente de fórmulas".

2. En el cuadro de diálogo "Asistente de fórmulas", realiza la siguiente configuración.

3. Luego, solo se extrae el texto entre “<” y “>” dentro de la celda B5. Al mismo tiempo, se ha creado una fórmula; puede seleccionar esta celda de resultado y luego arrastrar su controlador de autocompletado hacia abajo para extraer textos de otras celdas en la misma lista.

Haz clic para saber más sobre esta función.

3.1.4 Extraer texto entre dos caracteres (incluyendo los caracteres) por regla

Si desea conservar los dos caracteres después de la extracción, intente aplicar una regla en la función Extraer texto de Kutools para Excel.

1. Haga clic en "Kutools" > "Texto" > "Extraer texto".

2. En el cuadro de diálogo "Extraer texto", realiza la siguiente configuración.

2.1) Haga clic en la pestaña "Extract by rule";

2.2) En la sección "Rango", haz clic en el botón para seleccionar el rango de celdas donde desea extraer el texto entre caracteres;

2.3) En el cuadro "Texto", ingrese "<*>";

Consejos: "<" y ">" son los caracteres entre los que desea extraer el texto, * es un comodín que representa cualquier número de caracteres. Puede ingresar la condición según sus necesidades.

2.4) Haga clic en el botón "Agregar" para añadir la condición al cuadro de lista "Descripción de la regla".

2.5) Haga clic en el botón "Aceptar". Vea la captura de pantalla:

3. Aparece otro cuadro de diálogo "Extraer texto". Seleccione una celda para mostrar el resultado y, a continuación, haga clic en el botón "Aceptar".

Luego, el texto entre los caracteres especificados (incluyendo los caracteres) se extrae de cada celda en el rango seleccionado en masa.

3.2 Extraer texto entre dos palabras

Además de extraer texto entre dos caracteres, es posible que también necesites extraer texto entre dos palabras. Por ejemplo, extraer todas las cadenas de texto entre las palabras “KTE” y “feature” de cada celda en la columna B, como se muestra en la captura de pantalla a continuación. Puedes probar uno de los siguientes métodos para lograrlo.

3.2.1 Extraer texto entre dos palabras con fórmula

Puedes usar una fórmula basada en la función MID y la función SEARCH para extraer todas las cadenas de texto entre dos palabras dentro de una celda.

Fórmula genérica

=EXTRAE(celda,BUSCAR("palabra_inicio",celda)+3,BUSCAR("palabra_fin",celda)-BUSCAR("palabra_inicio",celda)-4)

Argumentos

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)

Nota: En la fórmula, el número 3 representa la longitud de caracteres de la palabra "KTE"; el número 4 representa la longitud de caracteres de la palabra "KTE" más 1.

Puede ver que todas las cadenas de texto entre las dos palabras especificadas se han extraído de cada celda en la columna B.

3.2.2 Extraer texto entre dos palabras con una herramienta asombrosa

Para muchos usuarios de Excel, las fórmulas pueden ser difíciles de recordar y manejar. Aquí, con la función "Extraer el texto entre textos especificados" de "Kutools para Excel", puedes extraer fácilmente texto entre dos palabras con solo unos pocos clics.

1. Seleccione una celda para mostrar el resultado y luego haga clic en "Kutools" > "Asistente de fórmulas" > "Asistente de fórmulas".

2. En el cuadro de diálogo "Asistente de fórmulas", debe configurar lo siguiente.

3. Luego, se extraen todas las cadenas de texto entre las dos palabras "KTE" y "feature" dentro de la celda B5. Al mismo tiempo, se ha creado una fórmula, puede seleccionar esta celda de resultado y luego arrastrar su controlador de AutoFill hacia abajo para extraer textos de otras celdas en la misma lista.

Extraer números por posición

Para una lista de cadenas alfanuméricas, pueden darse tres casos:

1. El número está al principio del texto;
2. El número está al final del texto;
3. El número puede estar en cualquier lugar del texto.

En esta sección, proporcionaremos diferentes métodos que se pueden utilizar para extraer los números en cada uno de los casos mencionados anteriormente.

1 Extraer número desde la izquierda de una cadena

Esta parte presentará una fórmula para ayudarte a extraer solo los números que aparecen antes del texto en una celda.

Fórmula genérica

=IZQUIERDA(celda, COINCIDIR(FALSO, ESNUMERO(EXTRAE(celda, FILA(INDIRECTO("1:"&LARGO(celda)+1)), 1) *1), 0) -1)

Argumentos

Nota:

Seleccione una celda en blanco, ingrese la fórmula a continuación y presione "Ctrl" + "Shift" + "Enter" o la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para obtener los números de otras celdas.

=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)

Notas:

2 Extraer número desde la derecha de una cadena

Como se muestra en la captura de pantalla a continuación, para extraer solo los números que aparecen después del texto en una celda, prueba la siguiente fórmula.

Fórmula genérica

=DERECHA(celda, LARGO(celda) - MAX(SI(ESNUMERO(EXTRAE(celda, FILA(INDIRECTO("1:"&LARGO(celda))), 1) *1)=FALSO, FILA(INDIRECTO("1:"&LARGO(celda))), 0)))

Argumentos

Nota:

Seleccione una celda en blanco, ingrese la fórmula a continuación y presione "Ctrl" + "Shift" + "Enter" o la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su controlador de AutoFill hacia abajo para obtener los números de otras celdas.

=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))

Notas:

3. Extraer todos los números de cualquier posición en una cadena de texto

Los métodos anteriores ayudan a extraer solo números desde la izquierda o derecha de una cadena de texto. Si deseas extraer todos los números de cualquier parte de una cadena de texto, aquí te proporcionamos tres métodos para lograrlo.

3.1 Extraer todos los números de cualquier parte de una cadena con fórmula

Puede aplicar la siguiente fórmula para extraer todos los números de cualquier parte de una cadena de texto en Excel.

1. Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener todos los números de la celda B5.

=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)

2. Seleccione la celda de resultado y luego arrastre su controlador de AutoFill hacia abajo para obtener todos los números de las otras celdas.

3.2 Extraer todos los números de cualquier parte de una cadena con VBA

La fórmula anterior es demasiado larga y complicada para muchos usuarios de Excel. En realidad, puedes ejecutar un script de VBA para automatizar la tarea en Excel. Puedes hacer lo siguiente.

1. Presiona las teclas "Alt" + "F11" para abrir la ventana "Microsoft Visual Basic for Applications".

2. En la ventana que se abre de "Microsoft Visual Basic for Applications", haga clic en "Insertar" > "Módulo". Luego, copie el siguiente código VBA en la ventana de código del Módulo.

Código VBA: Extraer todos los números de cualquier parte de una cadena de texto

Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
    Dim xRg As Range
    Dim xDRg As Range
    Dim xRRg As Range
    Dim nCellLength As Integer
    Dim xNumber As Integer
    Dim strNumber As String
    Dim xTitleId As String
    Dim xI As Integer
    xTitleId = "KutoolsforExcel"
    Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
    If TypeName(xDRg) = "Nothing" Then Exit Sub
    Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
    If TypeName(xRRg) = "Nothing" Then Exit Sub
    xI = 0
    strNumber = ""
  For Each xRg In xDRg
    xI = xI + 1
    nCellLength = Len(xRg)
    For xNumber = 1 To nCellLength
      If IsNumeric(Mid(xRg, xNumber, 1)) Then
        strNumber = strNumber & Mid(xRg, xNumber, 1)
      End If
    Next xNumber
    xRRg.Item(xI) = strNumber
    strNumber = ""
  Next xRg
End Sub

3. Presione la tecla "F5" para ejecutar el código. En el cuadro de diálogo "KutoolsforExcel" que se abre, seleccione el rango de celdas del que desea extraer todos los números de cada celda y luego haga clic en el botón "Aceptar".

4. Luego aparece otro cuadro de diálogo "Kutools for Excel". En este cuadro de diálogo, seleccione una celda de destino y haga clic en "Aceptar".

Luego, todos los números se extraen en bloque de cada celda en el rango seleccionado.

4. Extraer números después de un texto específico

Como se muestra en la captura de pantalla a continuación, para extraer cualquier número después del texto específico "No.", esta sección proporciona dos métodos para ayudarte a lograrlo.

4.1 Extraer números después de un texto específico con fórmula

Puede aplicar la siguiente fórmula para extraer números después de un texto específico en una celda en Excel.

Fórmula genérica:

=BUSCAR(10^6,1*EXTRAE(celda,MIN(ENCONTRAR({0,1,2,3,4,5,6,7,8,9},celda&"0123456789",ENCONTRAR("texto"," "&celda&" "))),{2,3,4,5,6}))

Argumentos

Seleccione una celda en blanco, copie o ingrese la fórmula a continuación y presione la tecla "Enter" para obtener el resultado. Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))

Notas:

4.2 Extraer números después de un texto específico con una función definida por el usuario

La siguiente función definida por el usuario también puede ayudar a extraer números después de un texto específico en una celda. Por favor, proceda de la siguiente manera.

1. Presiona las teclas "Alt" + "F11" para abrir la ventana "Microsoft Visual Basic for Applications".

2. En la ventana "Microsoft Visual Basic for Applications", haga clic en "Insertar" > "Módulo", y luego copie el siguiente código VBA en la ventana de código del Módulo.

Código VBA: extraer números después de un texto específico en una celda

Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
    xValue = Rng.Text
    xStart = InStr(1, xValue, Char, vbTextCompare)
    If IsEmpty(xStart) Then
            GetNumberAfterTheChar = ""
            Exit Function
    End If
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xStart = xStart - 1 + Len(Char)
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xValue = Mid(xValue, xStart + 1)
    xRntString = ""
    For xI = 1 To Len(xValue)
        xC = Mid(xValue, xI, 1)
        Select Case Asc(xC)
        Case 48 To 57
            xRntString = xRntString & xC
       Case Else
            Exit For
        End Select
    Next
   GetNumberAfterTheChar = xRntString
End Function

3. Presione las teclas "Alt" + "Q" para cerrar la ventana "Microsoft Visual Basic for Applications".

4. Seleccione una celda, ingrese la fórmula a continuación y presione la tecla "Enter". Seleccione esta celda de resultado y luego arrastre su Controlador de Autocompletar hacia abajo para aplicar esta fórmula a otras celdas.

=GetNumberAfterTheChar(B5,"No. ")

Notas:

Artículos relacionados: