KutoolsforOffice — Una solución, cinco potentes herramientas.Lograr más con menos esfuerzo.Venta de marzo: 20 % de descuento

Cuente fácilmente valores únicos y distintos – 7 ejemplos

AutorXiaoyang Fecha de modificación

Normalmente, en Excel, los valores únicos son aquellos que aparecen una sola vez en una lista, sin duplicados, mientras que los valores distintos incluyen todos los valores diferentes (es decir, los valores únicos más la primera aparición de cada valor duplicado). Al trabajar con grandes conjuntos de datos, es posible que necesites contar cuántos valores únicos y distintos hay en una lista de celdas, como se muestra en la siguiente captura de pantalla. Este tutorial te presentará algunos trucos rápidos para contar valores únicos y distintos en Excel.

Contar valores únicos o valores distintos en una lista

Contar el número de valores únicos en un rango en Excel

Contar únicos valores (únicos y primeras apariciones de duplicados) en Excel

Descargar archivo de ejemplo

Contar valores únicos distintos

Contar el número de valores únicos en un rango en Excel

Esta sección presenta algunos ejemplos de fórmulas para contar el número de valores únicos, incluida la división por texto y número en una lista.

Contar el número de valores únicos en un rango con fórmulas

Supongamos que tengo una lista de nombres que contiene algunos duplicados. Ahora necesito obtener únicamente el número de nombres únicos (resaltados en amarillo), tal como se muestra en la siguiente captura de pantalla:

datos de ejemplo

Para resolver este problema, la siguiente fórmula matricial le será de gran ayuda:

Paso 1: Introducir la fórmula

Introduzca o copie la siguiente fórmula en una celda vacía donde desee mostrar el resultado:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
Nota: En la fórmula anterior, «A2:A12» es la lista de datos cuyos valores únicos desea contar.

Paso 2: Pulse las teclas Ctrl + Mayús + Intro para obtener el resultado correcto:

Contar valores únicos con fórmula

Notas:

  1. Si su lista de celdas incluye otros tipos de datos, como números, valores booleanos, errores, etc., al aplicar la fórmula anterior obtendrá el recuento de valores únicos, independientemente del tipo de dato.
  2. Cuando la lista de datos contiene celdas vacías, esta fórmula las excluye automáticamente.
  3. Para contar únicamente los valores de texto únicos si hay otro tipo de datos, aplique la siguiente fórmula matricial y, a continuación, pulse las teclas «Ctrl» + «Mayús» + «Intro» para obtener el resultado:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Para contar únicamente los números únicos de una lista de celdas que contiene cualquier tipo de datos, utilice la siguiente fórmula matricial y, a continuación, pulse las teclas «Ctrl» + «Mayús» + «Intro» para obtener el resultado:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Contar el número de valores únicos en un rango con pocos clics mediante Kutools para Excel

Le resultará complicado recordar las fórmulas cuando necesite aplicarlas de nuevo. Sin embargo, si cuenta con «Kutools para Excel», podrá obtener el resultado en solo unos clics gracias a su opción «Contar el número de valores únicos en un rango» del  «Asistente de fórmulas». ¡Mire la siguiente demostración:

  1. Haga clic en una celda para mostrar el resultado;
  2. Active esta función haciendo clic en «Kutools» > «Asistente de fórmulas» > «Asistente de fórmulas» > «Estadísticas» > «Contar el número de valores únicos en un rango»;
  3. Seleccione la lista de datos y haga clic en «Aceptar».
    Contar valores únicos con Kutools
Consejos:
  1. Para utilizar esta función, debe descargar e instalar Kutools para Excel.
  2. La función «Asistente de fórmulas» reúne más de 40 fórmulas de uso común, como «Extraer valores únicos», «Extraer las celdas con valores únicos de un rango (incluyendo los primeros duplicados)», «Contar el número de valores separados por comas en una celda», «Sumar según el mismo texto» y muchas más...

Contar el número de valores únicos en un rango en Excel 365/2021 con fórmulas

Si utiliza Excel 365 o Excel 2021, cuenta con la nueva función UNIQUE, que le permite crear fórmulas más sencillas para contar el número de valores únicos en un rango dentro de un conjunto de datos.

Por ejemplo, para contar el número de nombres únicos en el rango A2:A12, introduzca la siguiente fórmula：

Paso 1: Copie o introduzca la siguiente fórmula

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Nota: En esta fórmula, «A2:A12» es la lista de datos que desea Contar el número de valores únicos en un rango.

Paso 2: Pulse la tecla Intro para obtener el resultado:

Contar valores únicos en Excel 365/2021 con fórmula

Consejos:

  1. Si la lista de datos incluye distintos tipos de información —como texto, números, valores booleanos, errores, etc.—, esta fórmula contará el número de valores únicos sin importar su tipo.
  2. La fórmula anterior cuenta el número de valores únicos en un rango, incluyendo celdas vacías. Si desea excluir las celdas vacías, aplique la siguiente fórmula y pulse únicamente la tecla **Intro**:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Contar únicos valores (únicos y primeras apariciones de duplicados) en Excel

Para contar los valores distintos (valores únicos y las primeras apariciones de duplicados) en una lista de celdas, aquí tiene otras fórmulas que le permitirán lograrlo.

Contar únicos valores con fórmulas

En Excel, puede aplicar cualquiera de las siguientes fórmulas para obtener el número de valores únicos.

Paso 1: Introduzca cualquiera de las siguientes fórmulas

Fórmula 1: Tras introducir la fórmula, pulse la tecla «Intro».

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Fórmula 2: Tras introducir la fórmula, pulse las teclas «Ctrl» + «Mayús» + «Intro».

=SUM(1/COUNTIF(A2:A12,A2:A12))
Nota: En estas fórmulas, «A2:A12» es la lista de datos cuyos valores desea contar Valor diferente.

Resultado:

Contar valores distintos con fórmula

Consejos:

  1. Si la lista de datos incluye otros tipos de datos, como números, valores booleanos, valores de error, etc., esta fórmula obtendrá los valores distintos independientemente de su tipo.
  2. Al utilizar la fórmula anterior, obtendrá el valor de error #DIV/0 si la lista de datos contiene celdas vacías. Para corregirlo e ignorar las celdas vacías, debe aplicar una de las siguientes fórmulas:
    Fórmula 1: tras introducir la fórmula, pulse la tecla «Intro».
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Fórmula 2: tras introducir la fórmula, pulse las teclas «Ctrl» + «Mayús» + «Intro».
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Contar valores distintos excluyendo celdas vacías con fórmula

  3. Para obtener únicamente el número de valores de texto distintos dentro de una lista de datos, aplique la siguiente fórmula matricial y pulse las teclas «Ctrl» + «Mayús» + «Intro» para obtener el resultado:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Para contar únicamente los valores numéricos distintos, utilice la siguiente fórmula matricial y pulse las teclas «Ctrl» + «Mayús» + «Intro» para obtener el resultado:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Contar únicos valores con unos pocos clics mediante Kutools para Excel

Si aplica fórmulas con frecuencia en su libro de trabajo, le resultará complicado recordarlas cuando las necesite nuevamente. Sin embargo, con «Kutools para Excel» y su opción «Contar celdas con valores únicos (incluir la primera duplicada)» del «Asistente de fórmulas», obtendrá el resultado en solo unos clics. Consulte la siguiente demostración:

  1. Haga clic en una celda para mostrar el resultado;
  2. Active esta función haciendo clic en «Kutools» > «Asistente de fórmulas» > «Estadísticas» > «Contar celdas únicas con valores únicos (incluir la primera duplicada)»;
  3. Seleccione la lista de datos y haga clic en «Aceptar».
    Contar valores distintos con Kutools
Consejos:
  1. Para utilizar esta función, debe descargar e instalar Kutools para Excel.
  2. La función «Asistente de fórmulas» reúne más de 40 fórmulas de uso común, como «Extraer valores únicos», «Extraer las celdas con valores únicos de un rango (incluyendo los primeros duplicados)», «Contar el número de valores separados por comas en una celda», «Sumar según el mismo texto» y muchas más…

Contar únicos valores con tabla dinámica

En Excel, la tabla dinámica también puede ayudarle a obtener el número de valores únicos en una lista de datos. Siga estos pasos:

Paso 1: Crear una Tabla Dinámica

  1. Seleccione la lista de datos y, a continuación, haga clic en «Insertar» > «Tabla dinámica» desde la Cinta de opciones, consulte la captura de pantalla:
    crear una tabla dinámica para los datos seleccionados
  2. En el cuadro de diálogo emergente «Tabla dinámica desde tabla o rango»:
    (1). Elija una hoja de cálculo nueva o una hoja de cálculo existente donde desee colocar la tabla dinámica;
    (2). A continuación, active la casilla «Agregar estos datos al modelo de datos».
    (3). Luego, haga clic en el botón «Aceptar».
    establecer opciones en la tabla dinámica desde el cuadro de diálogo Tabla o rango

Paso 2: Organizar el campo y seleccionar la opción Recuento distinto

  1. Se muestra el panel «Campos de tabla dinámica». Arrastre el campo «Nombres» al área «Valores»; consulte la siguiente demostración:
    Organizar el campo para la tabla dinámica
  2. A continuación, haga clic en la flecha desplegable de «Recuento de Nombres» y seleccione «Configuración de campos de valor», consulte la captura de pantalla:
    hacer clic en la opción Configuración de campo de valores
  3. A continuación, se abrirá el cuadro de diálogo «Configuración de campos de valor». En la pestaña «Resumir valor por», seleccione «Recuento distinto» en la lista y haga clic en «Aceptar». Consulte la captura de pantalla:
    seleccionar la opción Recuento distinto

Resultado:

Ahora, la Tabla Dinámica creada mostrará el recuento distinto de la lista de datos, tal como se muestra en la siguiente captura de pantalla:

Resultado de la tabla dinámica para contar valores distintos

Consejos:

  1. Si actualiza sus datos de origen, para obtener el recuento más reciente solo tiene que hacer clic con el botón derecho en la tabla dinámica y seleccionar la opción «Actualizar».
  2. La opción «Recuento distinto» solo está disponible a partir de Excel 2013.

Contar únicos valores en Excel 365/2021 con fórmulas

En Excel 365 o Excel 2021, puede combinar la nueva función UNIQUE con la función CONTARA para crear una fórmula sencilla.

Copie o introduzca la fórmula siguiente en una celda vacía y pulse la tecla «Entrar» para obtener el resultado:

=COUNTA(UNIQUE(A2:A12))
Nota: En esta fórmula, «A2:A12» es la lista de datos cuyos valores desea Contar únicos.

Contar valores distintos en Excel 365/2021 con fórmula

Consejos:

  1. Si la lista de datos incluye distintos tipos de información —como texto, números, valores booleanos, errores, etc.—, esta fórmula contará el número de valores únicos sin importar su tipo.
  2. La fórmula anterior cuenta los valores únicos, incluyendo las celdas vacías. Si desea excluir las celdas vacías, aplique la siguiente fórmula y pulse la tecla «Intro» para obtener el resultado:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Contar valores distintos en Excel 365/2021 con fórmula excluyendo celdas vacías

Artículos relacionados:

  • Contar el número de valores únicos en un rango en Tabla Dinámica
  • De forma predeterminada, cuando creamos una Tabla Dinámica basada en un rango de datos que contiene algunos Valores duplicados, se cuentan todos los registros, pero a veces queremos contar únicamente los valores únicos de una columna para obtener el resultado correcto. En este artículo explicaré cómo contar los valores únicos en Tabla Dinámica.
  • Contar el número de valores únicos en un rango con múltiples criterios
  • Aquí tiene un rango de datos con varios nombres, proyectos y ubicaciones. Su objetivo es identificar los nombres que coincidan con los criterios que he enumerado y contar cada nombre coincidente una sola vez, tal como se muestra en la siguiente captura de pantalla. ¿Conoce algún truco para resolver esta tarea? En este artículo, le presentaré precisamente esos trucos.
  • Concatenar valores únicos
  • Si tengo una lista larga de valores con algunos duplicados y quiero obtener solo los valores únicos concatenados en una sola celda, ¿cómo puedo resolverlo de forma rápida y sencilla en Excel?