Dominar las funciones SI anidadas en Excel – Guía paso a paso

En Excel, aunque la función SI es fundamental para pruebas lógicas básicas, las condiciones complejas suelen requerir funciones SI anidadas para un procesamiento de datos más avanzado. En esta guía completa, exploraremos en detalle los fundamentos del SI anidado: desde su sintaxis hasta aplicaciones prácticas, incluyendo combinaciones con las funciones Y y O. Además, te mostraremos cómo mejorar la legibilidad de las fórmulas SI anidadas, compartiremos consejos útiles para su uso eficaz y analizaremos alternativas potentes como BUSCARV, SI.CONJUNTO y otras, que simplifican y optimizan las operaciones lógicas complejas.

• Sintaxis del SI anidado
• Ejemplos prácticos de SI anidado
• SI anidado con condiciones Y / O

• Cómo hacer que el SI anidado sea fácil de leer
• El orden de las funciones SI anidadas
• Los números y el texto deben tratarse de forma diferente
• Limitaciones del SI anidado

• Uso de BUSCARV
• Uso de SI.CONJUNTO
• Uso de ELEGIR y COINCIDIR

Función SI de Excel frente a funciones SI anidadas

La función SI y las funciones SI anidadas en Excel persiguen propósitos similares, pero difieren notablemente en complejidad y aplicación.

Uso de SI anidado

Esta sección presenta el uso básico de las funciones SI anidadas en Excel, incluyendo su sintaxis, ejemplos prácticos y su aplicación combinada con las condiciones Y u O.

Sintaxis del SI anidado

Comprender la sintaxis de una función es fundamental para aplicarla correctamente y con eficacia en Excel. Empecemos por la sintaxis de las funciones SI anidadas.

Sintaxis:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argumentos:

• Condición1, Condición2, Condición3: estas son las condiciones que desea probar. Cada condición se evalúa en orden, comenzando por Condición1.
• Resultado1: Este es el valor que se devuelve si la Condición1 es VERDADERA.
• Resultado2: Este valor se devuelve si Condición1 es FALSA y Condición2 es VERDADERA. Ten en cuenta que Resultado2 solo se evalúa cuando Condición1 es FALSA.
• Resultado3: Este valor se devuelve cuando tanto Condición1 como Condición2 son FALSAS y Condición3 es VERDADERA. Es decir, para que se evalúe Resultado3, las condiciones anteriores (Condición1 y Condición2) deben ser ambas FALSAS.
• Resultado4: Este resultado se devuelve si todas las condiciones (Condición1, Condición2 y Condición3) son FALSAS.
  
  En resumen, esta expresión puede interpretarse de la siguiente manera:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

Recuerde que, en una estructura de SI anidado, cada condición posterior solo se evalúa si todas las anteriores son FALSAS. Esta evaluación secuencial es clave para comprender el funcionamiento de los SI anidados.

Ejemplos prácticos de SI anidado

Ahora, exploremos el uso del SI anidado con dos ejemplos prácticos.

Ejemplo 1: Sistema de calificaciones

Como se muestra en la siguiente captura de pantalla, imagine que dispone de una lista con las puntuaciones de los estudiantes y desea asignarles calificaciones en función de dichas puntuaciones. Para ello, puede utilizar la función SI anidada.

Seleccione una celda vacía (en este caso, C2), introduzca la siguiente fórmula y pulse Entrar para obtener el resultado. Luego, arrastre el controlador de relleno hacia abajo para obtener el resto de los resultados.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Ejemplo 2: Cálculo de comisiones por ventas

Imagínese un escenario en el que los representantes comerciales reciben distintas tasas de comisión según sus logros en ventas. Como se muestra en la siguiente captura de pantalla, puede calcular la comisión de un vendedor en función de estos umbrales de ventas utilizando funciones SI anidadas.

Seleccione una celda vacía (en este caso, C2), introduzca la siguiente fórmula y pulse Entrar para obtener el resultado. Luego, arrastre el controlador de relleno hacia abajo para completar el resto de los resultados.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

SI anidado con condiciones Y / O

En esta sección, modifico el primer ejemplo anterior, «el sistema de calificaciones», para mostrar cómo combinar la función SI anidada con las condiciones Y u O en Excel. En la versión actualizada del ejemplo de calificaciones, he añadido una condición adicional basada en la «tasa de asistencia».

Uso de SI anidado con condición Y

Si un estudiante cumple tanto el criterio de puntuación como el de asistencia, su calificación se mejorará automáticamente. Por ejemplo, un alumno con una puntuación igual o superior a 60 y una tasa de asistencia del 95 % o más verá su calificación elevada un nivel: de A a A+, de B a B+, etc. No obstante, si la asistencia es inferior al 95 %, la calificación se asignará exclusivamente según los criterios originales basados en la puntuación. En estos casos, debemos utilizar una función SI anidada combinada con una condición Y.

Seleccione una celda vacía (como D2), introduzca la siguiente fórmula y pulse Entrar para obtener el resultado. Luego, arrastre el controlador de relleno hacia abajo para completar el resto de los resultados.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Uso de SI anidado con condición O

En este caso, la calificación de un estudiante subirá un nivel si obtiene una puntuación de 95 o más, o si su tasa de asistencia alcanza el 95 % o superior. A continuación, se explica cómo lograrlo mediante funciones SI anidadas y la condición O.

Seleccione una celda vacía (en este caso, D2), introduzca la siguiente fórmula y pulse Entrar para obtener el resultado. Luego, arrastre el controlador de relleno hacia abajo para completar el resto de los resultados.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Consejos y trucos para SI anidado

Esta sección incluye cuatro consejos y trucos prácticos para aprovechar al máximo el uso de SI anidado.

Cómo hacer que el SI anidado sea fácil de leer

Una función SI anidada puede parecer compacta, pero suele resultar difícil de interpretar.

En la siguiente fórmula, resulta difícil identificar rápidamente dónde termina una condición y empieza otra, especialmente a medida que crece su complejidad.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Solución: añadir saltos de línea y sangrías

Para facilitar la lectura de un SI anidado, puede dividir la fórmula en varias líneas colocando cada función SI anidada en un salto de línea. En la fórmula, sitúe el cursor delante de la función SI y pulse Alt + Entrar.

Tras dividir la fórmula anterior, se mostrará de la siguiente forma:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Este formato muestra claramente dónde se ubica cada condición y su resultado correspondiente, lo que mejora la legibilidad de la fórmula.

El orden de las funciones SI anidadas

El orden de las condiciones lógicas en una fórmula de SI anidado es fundamental, ya que determina cómo Excel evalúa dichas condiciones y, por ende, influye directamente en el resultado final de la fórmula.

Fórmula correcta

En el ejemplo del sistema de calificaciones, utilizamos la siguiente fórmula para asignar calificaciones en función de las puntuaciones.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel evalúa las condiciones en una fórmula de SI anidado de forma secuencial, desde la primera hasta la última. Esta fórmula comprueba primero el umbral de puntuación más alto (>=90 para una «A») y luego avanza hacia los umbrales inferiores, asegurando que cada puntuación se asigne a la calificación más alta para la que cumple los requisitos. Si la primera condición es verdadera (A2>=90), devuelve «A» y omite la evaluación de cualquier condición adicional.

Fórmula con orden incorrecto

Si se invirtiera el orden de las condiciones, empezando por el umbral más bajo, se obtendrían resultados incorrectos.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

En esta fórmula incorrecta, una puntuación de 95 cumpliría inmediatamente la primera condición (B2>=60) y se le asignaría erróneamente la calificación «D».

Los números y el texto deben tratarse de forma diferente

Esta sección muestra cómo los números y el texto se manejan de forma distinta en las funciones SI anidadas.

Números

Los números se utilizan para comparaciones aritméticas y cálculos. En las funciones SI anidadas, puedes comparar números directamente mediante operadores como >, = y <=.

Texto

En las funciones SI anidadas, el texto debe ir entre comillas dobles. Observe las letras A, B, C, D y F en la fórmula siguiente:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Limitaciones del SI anidado

Esta sección presenta diversas limitaciones y desventajas del SI anidado.

Complejidad y legibilidad:

Aunque Excel permite anidar hasta 64 funciones SI distintas, hacerlo no es en absoluto recomendable. Cuantos más niveles de anidamiento incluya una fórmula, mayor será su complejidad, lo que puede derivar en expresiones difíciles de leer, entender y mantener.

Propensión a errores:

Además, las funciones SI anidadas complejas pueden volverse propensas a errores y difíciles de depurar o modificar.

Dificultad para ampliar o escalar:

Si su lógica cambia o necesita añadir más condiciones, las funciones SI profundamente anidadas pueden volverse difíciles de modificar o ampliar.

Comprender estas limitaciones es fundamental para aprovechar al máximo las funciones SI anidadas en Excel. A menudo, combinar el SI anidado con otras funciones o explorar enfoques alternativos permite obtener soluciones más eficientes y sencillas de mantener.

Alternativas al SI anidado

Esta sección presenta diversas funciones de Excel que ofrecen alternativas eficaces a las funciones SI anidadas.

Uso de BUSCARV

Puede utilizar la función BUSCARV en lugar de funciones SI anidadas para resolver los dos ejemplos prácticos anteriores. A continuación, le explicamos cómo hacerlo:

Ejemplo 1: Sistema de calificaciones con BUSCARV

A continuación, te muestro cómo usar BUSCARV para asignar calificaciones en función de las puntuaciones.

Paso 1: crear una tabla de búsqueda para las calificaciones

En primer lugar, debe crear una tabla de búsqueda (como E1:F6 en este caso) para el rango de puntuaciones y las calificaciones correspondientes.Nota:Las puntuaciones de la primera columna de la tabla deben estar ordenadas en orden ascendente.

Paso 2: aplicar la función BUSCARV para asignar calificaciones

Seleccione una celda vacía (en este caso, C2), introduzca la siguiente fórmula y pulse Entrar para obtener la primera calificación. A continuación, seleccione dicha celda y arrastre su controlador de relleno hacia abajo para generar el resto de las calificaciones.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Ejemplo 2: Cálculo de comisiones por ventas con BUSCARV

También puede usar BUSCARV para calcular las comisiones por ventas en Excel. Siga estos pasos.

Paso 1: Crear una tabla de búsqueda para las calificaciones

En primer lugar, debe crear una tabla de búsqueda para las ventas y la tasa de comisión correspondiente, como E2:F4 en este caso.Nota: Las ventas de la primera columna de la tabla deben estar ordenadas en orden ascendente.

Paso 2: Aplicar la función BUSCARV para asignar calificaciones

Seleccione una celda en blanco (en este caso, C2), introduzca la siguiente fórmula y pulse la tecla Entrar para obtener la primera comisión. A continuación, seleccione esta celda con la fórmula y arrastre su controlador de relleno hacia abajo para obtener el resto de los resultados.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Uso de SI.CONJUNTO

La función IFS simplifica el proceso al eliminar la necesidad de anidar funciones, haciendo que las fórmulas sean más fáciles de leer y gestionar. Mejora la legibilidad y agiliza el manejo de múltiples comprobaciones condicionales. Para usar la función IFS, asegúrese de tener Excel 2019 o una versión posterior, o bien una suscripción a Office 365. Veamos cómo aplicarla en ejemplos prácticos.

Ejemplo 1: Sistema de calificaciones con IFS

Suponiendo los mismos criterios de calificación que antes, la función IFS se puede utilizar de la siguiente manera:

Seleccione una celda en blanco, como C2, introduzca la fórmula siguiente y pulse Entrar para obtener el primer resultado. A continuación, seleccione esta celda con el resultado y arrastre su controlador de relleno hacia abajo para obtener el resto de los resultados.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Ejemplo 2: Cálculo de comisiones de ventas con IFS

En el escenario de cálculo de comisiones de ventas, la función IFS se aplica de la siguiente forma:

Seleccione una celda en blanco, como C2, introduzca la fórmula siguiente y pulse Entrar para obtener el primer resultado. A continuación, seleccione dicha celda y arrastre su controlador de relleno hacia abajo para obtener el resto de los resultados.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Uso de ELEGIR y COINCIDIR

El enfoque con las funciones CHOOSE y MATCH resulta más eficiente y fácil de gestionar que las funciones SI anidadas. Este método simplifica la fórmula y facilita las actualizaciones o modificaciones. A continuación, te muestro cómo usar la combinación de CHOOSE y MATCH para abordar los dos ejemplos prácticos de este artículo.

Ejemplo 1: Sistema de calificaciones con CHOOSE y MATCH

Puede combinar las funciones CHOOSE y MATCH para asignar calificaciones según distintas puntuaciones.

Paso 1: Crear una matriz de búsqueda con Valor de búsqueda

En primer lugar, debe crear un rango de celdas que contenga los valores umbral que la función MATCH buscará, como $E$2:$E$6 en este caso.Nota:Los números de este rango deben estar ordenados de forma ascendente para que la función MATCH funcione correctamente al utilizar un tipo de coincidencia aproximada.

Paso 2: Aplicar CHOOSE y MATCH para asignar calificaciones

Seleccione una celda en blanco (C2 en este caso), introduzca la siguiente fórmula y pulse la tecla Entrar para obtener la primera calificación. Seleccione esta celda con la fórmula y arrastre su controlador de relleno hacia abajo para obtener el resto de los resultados.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Ejemplo 2: Cálculo de comisiones de ventas con IFS

Combinar las funciones CHOOSE y MATCH para calcular comisiones de ventas puede ser muy eficaz, especialmente cuando las tasas de comisión dependen de umbrales de ventas específicos. Veamos cómo hacerlo.

Paso 1: Crear una matriz de búsqueda con Valor de búsqueda

En primer lugar, debe crear un rango de celdas que contenga los valores umbral que la función MATCH buscará, como $E$2:$E$4 en este caso.Nota:Los números de este rango deben estar ordenados de forma ascendente para que la función MATCH funcione correctamente al utilizar un tipo de coincidencia aproximada.

Paso 2: Aplicar CHOOSE y MATCH para obtener los resultados

Seleccione una celda en blanco (como C2), introduzca la fórmula siguiente y pulse Entrar para obtener la primera calificación. A continuación, seleccione esa celda y arrastre su controlador de relleno hacia abajo para obtener el resto de los resultados.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

En conclusión, dominar las funciones SI anidadas en Excel es una habilidad clave que potencia su capacidad para gestionar escenarios lógicos complejos en análisis de datos y en procesos de toma de decisiones. Aunque las funciones SI anidadas son muy potentes para operaciones lógicas avanzadas, es fundamental conocer sus limitaciones. Alternativas más ágiles —como BUSCARV, IFS o la combinación de CHOOSE con MATCH— pueden ofrecer soluciones más eficientes en determinados casos. Con estos conocimientos, podrá aplicar con total confianza las técnicas de Excel más adecuadas a sus tareas de análisis de datos, garantizando claridad, precisión y eficiencia en sus hojas de cálculo. ¿Quiere seguir profundizando en las posibilidades de Excel? En nuestra web encontrará una amplia variedad de tutoriales.Descubra más consejos y trucos de Excel aquí.

Artículos relacionados