¿Cómo desactivar la advertencia de asunto vacío en Outlook?

Cuando utiliza Outlook 2010 y 2013, cada vez que envíe un mensaje de correo electrónico sin asunto, aparecerá un cuadro de aviso recordándoselo. Si realmente no desea incluir un asunto, esta advertencia puede resultarle muy molesta. Para ayudarle a eliminar dicha alerta, le ofrecemos un sencillo truco en el siguiente tutorial.

Desactive o deshabilite la advertencia de asunto vacío en Outlook

---

Desactive o deshabilite la advertencia de asunto vacío en Outlook

En Outlook 2007 no aparece ninguna advertencia al enviar un mensaje de correo electrónico sin asunto. Esta función está activada en Outlook 2010 y 2013, pero no existe una opción directa para desactivarla. En este tutorial le mostraremos un código VBA que le permitirá hacerlo.

1. Pulse las teclas «Alt» + «F11» para abrir el cuadro de diálogo «Microsoft Visual Basic para Aplicaciones».

2. Expanda «Project1» > «Objetos de Microsoft Outlook» haciendo doble clic en ellos y, a continuación, haga doble clic en «ThisOutlookSession» para abrir la ventana «VbaProject.OTM».

3. Copie y pegue el siguiente código VBA en la ventana.

VBA: Desactive o deshabilite la advertencia de asunto vacío

Option Explicit
Private WithEvents oInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set oInspectors = Outlook.Inspectors
End Sub

Private Sub oInspectors_NewInspector(ByVal Inspector As Inspector)
    Dim oItem As Object
    On Error GoTo ExitProc
    Set oItem = Inspector.CurrentItem
    If oItem.Sent = False Then
        If oItem.Subject = "" Then oItem.Subject = " "
    End If
ExitProc:
    Set oItem = Nothing
    Set Inspector = Nothing
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    On Error Resume Next
    Item.Subject = Trim(Item.Subject)
End Sub

Private Sub Application_Quit()
    Set oInspectors = Nothing
End Sub

4. Haga clic en el botón «Guardar» para almacenar su código VBA.

5. Reinicie la aplicación Outlook.

Entonces, el código VBA entrará en vigor y, al enviar un mensaje sin asunto, ya no aparecerá el cuadro de advertencia por asunto vacío.

Nota: Asegúrese de que la opción «Habilitar todas las macros» esté seleccionada. (Para verificarlo, haga clic en «Archivo» > «Opciones» > «Centro de confianza» > «Configuración del Centro de confianza» y, en el cuadro de diálogo «Centro de confianza», elija «Configuración de macros» > «Habilitar todas las macros»). Consulte la captura de pantalla: