¿Cómo obtener una lista de carpetas en Outlook?

A veces, la estructura de árbol de todas las carpetas de correo (incluidas las carpetas personales creadas) en el panel de navegación puede ayudar a los usuarios de Outlook durante su trabajo. Para enumerar rápidamente todas las carpetas de la estructura del árbol, el código VBA puede ayudarlo. En este tutorial, puede aprender cómo obtener una lista de carpetas fácilmente con el código VBA.

Obtenga una lista de carpetas en Outlook con código VBA

Obtenga una lista de carpetas en Outlook con código VBA

Para obtener una lista de carpetas en Outlook con código VBA, haga lo siguiente.

1. presione el otro + F11 teclas en el teclado para abrir el Microsoft Visual Basic para aplicaciones ventana.

2. Luego haga doble clic en el Proyecto1 > Objeto de Microsoft Outlook > Esta sesión de Outlook para abrir el Proyecto1 - ThisOutlookSession ventana. Ver captura de pantalla:

3. Luego copie y pegue el siguiente código VBA en la ventana Project1 - ThisOutlookSession.

VBA: obtenga la lista de carpetas en Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. presione el F5 en el teclado para comenzar a ejecutar el código VBA.

5. Ahora un Macro aparece el cuadro de diálogo, haga clic en el Ejecutar

6. Espere a que se ejecute la macro. Luego, la lista de todas sus carpetas de correo electrónico se muestra en una ventana de mensaje nuevo creado inmediatamente. Puede imprimirlo fácilmente. Ver captura de pantalla:

Nota:: Este código VBA se puede aplicar a Outlook 2007, 2010 y 2013.

---

Kutools para Outlook: trae 100 funciones avanzadas a Outlook y hace que el trabajo sea mucho más fácil.

• Auto CC / BCC por reglas al enviar correo electrónico; Reenvío automático Varios correos electrónicos personalizados; Respuesta automática sin servidor de intercambio y más funciones automáticas ...
• Advertencia de BCC - mostrar mensaje cuando intente responder a todos si su dirección de correo está en la lista CCO; Recordar si faltan archivos adjuntosy más funciones de recordatorio ...
• Responder (todos) con todos los archivos adjuntos en la conversación de correo; Responder muchos correos electrónicos en segundos; Agregar saludo automáticamente cuando responda; Agregar fecha al asunto ...
• Herramientas de archivos adjuntos: administre todos los archivos adjuntos en todos los correos, Desconexión automática, Comprimir todo, Renombrar todo, Guardar todo ... Informe rápido, Contar correos seleccionados...
• Potentes correos electrónicos no deseados por costumbre; Eliminar correos y contactos duplicados... Le permite hacerlo de forma más inteligente, más rápida y mejor en Outlook.

Leer más ... Descargar ahora...