¿Cómo obtener una lista de las carpetas en Outlook?

A veces, la estructura en árbol de todas las carpetas de correo (incluidas las carpetas personales que haya creado) en el panel de Navegación resulta muy útil para los usuarios de Outlook durante su trabajo. Para obtener rápidamente la estructura completa en árbol de sus carpetas, puede usar código VBA. En este tutorial aprenderá cómo generar fácilmente una lista de carpetas mediante código VBA.

Obtener una lista de carpetas en Outlook con código VBA

---

Obtener una lista de carpetas en Outlook con código VBA

Para obtener una lista de carpetas en Outlook con código VBA, siga estos pasos:

1. Pulse las teclas «Alt» + «F11» para abrir la ventana de «Microsoft Visual Basic para Aplicaciones».

2. A continuación, haga doble clic en «Project1» > «Objetos de Microsoft Outlook» > «ThisOutlookSession» para abrir la ventana «Project1 – ThisOutlookSession». Consulte la captura de pantalla:

3. A continuación, copie y pegue el siguiente código VBA en la ventana «Project1 – ThisOutlookSession».

VBA: obtener una lista de carpetas en Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Pulse la tecla «F5» del teclado para ejecutar el código VBA.

5. Ahora aparecerá un cuadro de diálogo «Macro»; haga clic en el botón «Ejecutar».

6. Espere a que se ejecute la macro. A continuación, la lista de todas sus carpetas de correo aparecerá inmediatamente en una nueva ventana de mensaje. ¡Podrá imprimirla fácilmente! Vea la captura de pantalla:

Nota: Este código VBA es compatible con Outlook 2007, 2010 y 2013.