¿Cómo buscar una carpeta (con su ruta completa) en Outlook por nombre de carpeta?

Siga los pasos que se indican a continuación para buscar carpetas por nombre de carpeta mediante VBA en Outlook.

1. Pulse simultáneamente las teclas «Alt» + "F11" para abrir la ventana de «Microsoft Visual Basic para Aplicaciones».

2. Haga clic en «Insertar» > «Módulo» y, a continuación, pegue el siguiente código VBA en la nueva ventana del módulo.

VBA: Buscar y Abrir carpeta por Nombre de carpeta en Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Pulse la tecla «F5» o haga clic en el botón «Ejecutar» para poner en marcha este código VBA.

4. En el cuadro de diálogo emergente «Buscar carpeta», escriba el nombre de la carpeta específica que desea buscar y haga clic en el botón «Aceptar».

Nota: Este código VBA admite el comodín asterisco (*). Por ejemplo, puede escribir tes* para encontrar todas las carpetas cuyo nombre empiece por «tes».

5. Ahora aparece un cuadro de diálogo que muestra la ruta del archivo de la carpeta encontrada. Si desea abrir la carpeta localizada, haga clic en el botón «Sí».

Y ahora la carpeta encontrada se abre en el Navegación, tal como se muestra en la siguiente captura de pantalla:

Nota: Si hay más de una carpeta con el nombre especificado, este código VBA solo encontrará y abrirá una de ellas.

Si tiene instalado «Kutools para Outlook», puede usar su función «Ir a» para encontrar rápidamente todas las carpetas con un nombre determinado y abrir fácilmente cualquiera de ellas.

1. Haga clic en «KUTOOLS PLUS» > «Ir a» para activar esta función.

2. En el cuadro de diálogo «Ir a», escriba el nombre de la carpeta especificado en el campo «Buscar», seleccione una carpeta entre los resultados de la búsqueda y haga clic en el botón «Aceptar».

Ahora se localiza y abre de inmediato la carpeta especificada con el nombre de carpeta determinado.