¿Cómo marcar automáticamente como leídos los correos electrónicos no leídos anteriores a un número determinado de días en Outlook?

Si hay varios correos electrónicos no leídos en la carpeta Bandeja de entrada, normalmente puede usar la función *Marcar todo como leído* para marcarlos manualmente como leídos. Pero, ¿ha probado alguna vez a marcar automáticamente como leídos los correos no leídos anteriores a un número determinado de días en Outlook, sin tener que configurarlo manualmente cada vez?

Marcar automáticamente como leídos los correos no leídos anteriores a un número específico de días con código VBA

---

Marcar automáticamente como leídos los correos no leídos anteriores a un número específico de días con código VBA

Para marcar automáticamente como leídos todos los correos no leídos anteriores a un número específico de días, el siguiente código VBA le será de gran ayuda:

1. Mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. En la ventana de Microsoft Visual Basic para Aplicaciones, haga doble clic en ThisOutlookSession del panel Project1 (VbaProject.OTM) para abrir el módulo y, a continuación, copie y pegue el código siguiente en el módulo en blanco.

Código VBA: Marcar automáticamente como leídos los correos no leídos anteriores a un número específico de días:

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

Nota: En el código anterior, puede ajustar el número de días en esta secuencia de comandos:If DateDiff(«d», xItems(i).ReceivedTime, Now) >= 15Then según sus necesidades.

3. A continuación, guarde y cierre esta ventana de código; a partir de entonces, cada vez que inicie Outlook, todos los correos no leídos anteriores al número de días predefinido se marcarán como leídos automáticamente de inmediato.

Nota: Este código solo está disponible para la cuenta de datos predeterminada.