¿Cómo copiar la estructura de carpetas de Outlook al Escritorio (Explorador de Windows)?

Como sabe, podemos utilizar la función Archivar para copiar la estructura de carpetas a otra instancia de Outlook, pero ¿sabe cómo copiar la estructura de carpetas de Outlook a una carpeta específica del sistema, como el escritorio? Este artículo presenta un código VBA para copiar fácilmente la estructura de carpetas de Outlook al Explorador de Windows.

Copiar carpetas de Outlook Estructura de carpetas al escritorio (Explorador de Windows)

---

Copiar carpetas de Outlook Estructura de carpetas al escritorio (Explorador de Windows)

Siga los pasos que se indican a continuación para copiar la estructura de carpetas de Outlook al escritorio o al Explorador de Windows.

1. En el panel de Navegación, haga clic para resaltar la carpeta específica cuya estructura de carpetas desea copiar y pulse las teclas «Alt» + "F11" para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en **Herramientas** > **Referencias** para abrir el cuadro de diálogo *Referencias*. A continuación, active la opción **Microsoft Scripting Runtime** y haga clic en **Aceptar**. Vea la captura de pantalla:

3. Haga clic en «Insertar» > «Módulo» y copie y pegue el siguiente código VBA en la nueva ventana del módulo.

VBA: Copiar carpetas de Outlook Estructura de carpetas al Explorador de Windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Pulse la tecla "F5" o haga clic en el botón «Ejecutar» para poner en marcha este código VBA.

5. En el cuadro de diálogo emergente «Examinar en busca de carpetas», selecciona la carpeta específica donde colocarás la estructura de carpetas copiada y haz clic en el botón «Aceptar». Consulta la captura de pantalla:

Ahora vaya a la carpeta especificada y verá que la estructura de carpetas se ha copiado en el disco duro indicado. Consulte la captura de pantalla:

Nota: los elementos de la carpeta, como correos electrónicos, citas, tareas, etc., también se copian en las carpetas correspondientes del disco duro.

---

Artículos relacionados

¿Cómo copiar la estructura de carpetas a un nuevo archivo de datos PST en Outlook?