¿Cómo exportar la estructura de carpetas de Outlook a Excel?

En este artículo, le explicamos cómo exportar la estructura de carpetas de una cuenta de Outlook a un archivo de Excel. Siga los pasos detallados para lograrlo con facilidad.

Exporte Estructura de carpetas de una cuenta desde Outlook a Excel mediante código VBA

---

Exporte Estructura de carpetas de una cuenta desde Outlook a Excel mediante código VBA

El siguiente código VBA puede ayudarle; siga los pasos que se indican a continuación:

1. Abra Excel y mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en Insertar > Módulo y pegue el siguiente código en la ventana del Módulo.

Código VBA: Exportar Estructura de carpetas de una cuenta desde Outlook a Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Todavía en la ventana de Microsoft Visual Basic para Aplicaciones, haga clic en Herramientas>Referenciaspara abrir el cuadro de diálogo Referencias-Proyecto1y active la opción Biblioteca de objetos Microsoft Excelen el cuadro de lista Referencias disponibles, tal como se muestra en la captura de pantalla:

4. A continuación, haga clic en el botón Aceptar y pulse la tecla F5 para ejecutar este código. Aparecerá un cuadro de diálogo Seleccionar carpeta; seleccione la cuenta de correo electrónico cuya estructura de carpetas desea exportar, tal como se muestra en la captura de pantalla:

5. A continuación, haga clic en el botón Aceptar y aparecerá una ventana de Guardar archivo; especifique una ubicación y un nombre para el archivo exportado, tal como se muestra en la captura de pantalla:

6. Por último, haga clic en el botón Guardar y podrá ir al libro de Excel específico donde haya guardado el archivo para ver la estructura de carpetas exportada, tal como se muestra en la captura de pantalla: