¿Cómo marcar automáticamente los correos electrónicos según un archivo adjunto específico en Outlook?

Al recibir ciertos correos electrónicos con un archivo adjunto importante específico, es posible que desee marcarlos para localizarlos rápida y fácilmente más adelante. En este artículo le explicaré una forma sencilla de marcar automáticamente los mensajes cuyos archivos adjuntos tengan nombres específicos.

Marcar automáticamente correos electrónicos en función de un archivo adjunto específico con código VBA

---

Marcar automáticamente correos electrónicos en función de un archivo adjunto específico con código VBA

Para marcar automáticamente los correos que contengan un archivo adjunto específico, aplique el siguiente código VBA:

1. Inicie Outlook y, a continuación, mantenga pulsadas las teclas «ALT + F11» para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. En la ventana de «Microsoft Visual Basic para Aplicaciones», haga doble clic en «ThisOutlookSession» del panel «Project1 (VbaProject.OTM)» para abrir un nuevo módulo y, a continuación, copie y pegue el siguiente código en el módulo en blanco.

Código VBA: Marcar automáticamente correos en función de un archivo adjunto específico:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Nota: En el código anterior, puede modificar la extensión y el nombre del archivo adjunto según sus necesidades.

3. A continuación, guarde el código y reinicie Outlook para que surta efecto. A partir de ahora, al recibir correos electrónicos cuyos nombres de archivos adjuntos contengan el texto especificado, Outlook los marcará automáticamente para seguimiento; consulte la captura de pantalla: