¿Cómo imprimir tareas por categoría en Outlook?

Supongamos que hay varias Categoría de color en sus tareas de Outlook y que ahora desea imprimir listas de tareas organizadas por categorías en páginas distintas. ¿Cómo puede realizar esta tarea en Outlook?

Imprimir tareas según las categorías en páginas distintas manualmente, una a una

Imprimir tareas según las categorías en páginas distintas con código VBA

---

Imprimir tareas según las categorías en páginas distintas manualmente, una a una

En Outlook, puede imprimir manualmente las tareas por categorías, una a una, en páginas separadas. Siga estos pasos:

1. Inicie Outlook, vaya al panel de tareas y seleccione la carpeta de tareas que desea imprimir. A continuación, pulse Ctrl + E para activar el cuadro de búsqueda y, en la pestaña Búsqueda, haga clic en el icono Categorizado y elija la categoría de color que desee imprimir, como se muestra en la captura de pantalla:

2. A continuación, aparecerán inmediatamente todas las tareas con esa categoría de color específica, como se muestra en la captura de pantalla:

3. A continuación, haga clic en Archivo > Imprimir para imprimir esta lista de tareas, tal como se muestra en la siguiente captura de pantalla:

4. Repita los pasos anteriores para imprimir manualmente, una a una, las listas de tareas correspondientes a las demás categorías de color.

---

Imprimir tareas según las categorías en páginas distintas con código VBA

A continuación, encontrará un código VBA que le permite imprimir automáticamente las tareas por categoría, cada una en páginas distintas. Siga estos pasos:

1. Vaya al panel de Tareas y seleccione la carpeta de tareas que desea imprimir.

2. A continuación, mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

3. A continuación, haga clic en Insertar > Módulo y copie y pegue el siguiente código en el módulo en blanco que se abre:

Código VBA: Imprimir tareas según las categorías en páginas distintas:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. A continuación, haga clic en Herramientas > Referencias en la ventana de Microsoft Visual Basic para Aplicaciones. En el cuadro de diálogo emergente Referencias - Proyecto1, active las opciones Microsoft Excel Object Library y Microsoft Scripting Runtime en el cuadro de lista Referencias disponibles, como se muestra en la captura de pantalla:

5. A continuación, haga clic en el botón Aceptar y, a continuación, pulse la tecla F5 para ejecutar este código. Una vez finalizada la ejecución, las listas de tareas con distintas categorías se imprimirán en páginas separadas.