¿Cómo imprimir automáticamente los adjuntos cuando llegan correos electrónicos en Outlook?

Author: Siluvia Last Modified: 2025-08-06

Este tutorial demuestra un método para combinar un script VBA y una regla de Outlook para ayudarte a imprimir automáticamente los adjuntos de ciertos correos electrónicos cuando lleguen a Outlook.

Imprimir automáticamente adjuntos cuando lleguen ciertos correos electrónicos

Paso 1: Crear un script en Outlook

Paso 2: Construir una regla para usar el script

Imprimir automáticamente adjuntos cuando lleguen ciertos correos electrónicos

Supongamos que quieres imprimir automáticamente los adjuntos de los correos electrónicos entrantes de un remitente específico. Puedes hacer lo siguiente para lograrlo.

Paso 1: Crear un script en Outlook

Primero, necesitas crear un script VBA en Outlook.

1. Abre tu Outlook, presiona simultáneamente las teclas Alt + F11 para abrir la ventana Microsoft Visual Basic for Applications.

2. En la ventana Microsoft Visual Basic for Applications, haz doble clic en Project1 > Microsoft Outlook Objects > ThisOutlookSession para abrir la ventana ThisOutlookSession (Código), y luego copia el siguiente código en esta ventana de código.

steps of auto printing attachments when emails arrive in Outlook

Código VBA 1: Imprimir automáticamente adjuntos (todos los tipos de adjuntos) cuando lleguen correos electrónicos

Sub AttachementAutoPrint(Item As Outlook.MailItem)
'Updated by Extendoffice 20230223
  Dim xFS As FileSystemObject
  Dim xTempFolder As String
  Dim xAtt As Attachment
  Dim xShell As Object
  Dim xFolder As Object, xFolderItem As Object
  Dim xFileName As String
  On Error GoTo xError
  If Item.Attachments.Count = 0 Then Exit Sub
  Set xFS = New FileSystemObject
  xTempFolder = xFS.GetSpecialFolder(TemporaryFolder)
  xTempFolder = xTempFolder & "\ATMP" & Format(Item.ReceivedTime, "yyyymmddhhmmss")
  If Not xFS.FolderExists(xTempFolder) Then
    MkDir (xTempFolder)
  End If
  Set xShell = CreateObject("Shell.Application")
  Set xFolder = xShell.NameSpace(0)
  For Each xAtt In Item.Attachments
    If IsEmbeddedAttachment(xAtt) = False Then
      xFileName = xTempFolder & "\" & xAtt.FileName
      xAtt.SaveAsFile (xFileName)
      Set xFolderItem = xFolder.ParseName(xFileName)
      xFolderItem.InvokeVerbEx ("print")
    End If
  Next xAtt
  Set xFS = Nothing
  Set xFolder = Nothing
  Set xFolderItem = Nothing
  Set xShell = Nothing
xError:
  If Err <> 0 Then
    MsgBox Err.Number & " - " & Err.Description, , "Kutools for Outlook"
    Err.Clear
  End If
Exit Sub
End Sub

Function IsEmbeddedAttachment(Attach As Attachment)
Dim xItem As MailItem
Dim xCid As String
Dim xID As String
Dim xHtml As String
On Error Resume Next
IsEmbeddedAttachment = False
Set xItem = Attach.Parent
If xItem.BodyFormat <> olFormatHTML Then Exit Function
xCid = ""
xCid = Attach.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001F")
If xCid <> "" Then
    xHtml = xItem.HTMLBody
    xID = "cid:" & xCid
    If InStr(xHtml, xID) > 0 Then
        IsEmbeddedAttachment = True
    End If
End If
End Function

Nota: Este código admite la impresión de todos los tipos de adjuntos recibidos en correos electrónicos. Si deseas imprimir solo un tipo específico de adjunto, como archivos pdf, aplica el siguiente código VBA.

Código VBA 2: Imprimir automáticamente el tipo especificado de adjuntos cuando lleguen correos electrónicos

Sub AttachementAutoPrint(Item As Outlook.MailItem)
'Updated by Extendoffice 20230223
  Dim xFS As FileSystemObject
  Dim xTempFolder As String
  Dim xAtt As Attachment
  Dim xShell As Object
  Dim xFolder As Object, xFolderItem As Object
  Dim xFileType As String, xFileName As String
  On Error GoTo xError
  If Item.Attachments.Count = 0 Then Exit Sub
  Set xFS = New FileSystemObject
  xTempFolder = xFS.GetSpecialFolder(TemporaryFolder)
  xTempFolder = xTempFolder & "\ATMP" & Format(Item.ReceivedTime, "yyyymmddhhmmss")
  If Not xFS.FolderExists(xTempFolder) Then
    MkDir (xTempFolder)
  End If
  Set xShell = CreateObject("Shell.Application")
  Set xFolder = xShell.NameSpace(0)
  For Each xAtt In Item.Attachments
    If IsEmbeddedAttachment(xAtt) = False Then
      xFileName = xAtt.FileName
      xFileType = LCase$(Right$(xFileName, VBA.Len(xFileName) - VBA.InStrRev(xFileName, ".")))
      xFileName = xTempFolder & "\" & xFileName
      Select Case xFileType
        Case "pdf"   'change "pdf" to the file extension you want to print
          xAtt.SaveAsFile (xFileName)
          Set xFolderItem = xFolder.ParseName(xFileName)
          xFolderItem.InvokeVerbEx ("print")
      End Select
    End If
  Next xAtt
  Set xFS = Nothing
  Set xFolder = Nothing
  Set xFolderItem = Nothing
  Set xShell = Nothing
xError:
  If Err <> 0 Then
    MsgBox Err.Number & " - " & Err.Description, , "Kutools for Outlook"
    Err.Clear
  End If
  Exit Sub
End Sub

Function IsEmbeddedAttachment(Attach As Attachment)
Dim xItem As MailItem
Dim xCid As String
Dim xID As String
Dim xHtml As String
On Error Resume Next
IsEmbeddedAttachment = False
Set xItem = Attach.Parent
If xItem.BodyFormat <> olFormatHTML Then Exit Function
xCid = ""
xCid = Attach.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001F")
If xCid <> "" Then
    xHtml = xItem.HTMLBody
    xID = "cid:" & xCid
    If InStr(xHtml, xID) > 0 Then
        IsEmbeddedAttachment = True
    End If
End If
End Function

Notas:

1. Antes de aplicar este código VBA para imprimir solo el archivo pdf en los correos electrónicos entrantes, primero debes descargar e instalar Adobe Acrobat Reader y configurarlo como el lector de pdf predeterminado en tu computadora.

2. En la línea Case "pdf", cambia "pdf" a la extensión de archivo que deseas imprimir.

3. Ve a Herramientas > Referencias. En el cuadro de diálogo Referencias – Project1 que aparece, marca la casilla Microsoft Scripting Runtime y luego haz clic en el botón Aceptar.

4. Guarda el código y presiona las teclas Alt + Q para cerrar la ventana Microsoft Visual Basic for Applications.

Nota: Asegúrate de que la opción Habilitar todas las macros esté activada en tu Outlook. Puedes verificar esta opción siguiendo los pasos que se muestran a continuación.

Paso 2: Construir una regla para usar el script

Después de agregar el script VBA en Outlook, necesitas crear una regla para usar el script basado en ciertas condiciones.

1. Ve a la pestaña Inicio, haz clic en Reglas > Administrar reglas y alertas.

2. En el cuadro de diálogo Reglas y alertas, haz clic en el botón Nueva regla para crear una regla.

Consejos: Si has agregado varias cuentas de correo electrónico a tu Outlook, especifica una cuenta en la lista desplegable Aplicar cambios a esta carpeta donde quieras aplicar la regla. De lo contrario, se aplicará a la bandeja de entrada de la cuenta de correo electrónico seleccionada actualmente.

3. En el primer cuadro de diálogo Asistente de reglas, selecciona Aplicar regla a los mensajes que recibo en el cuadro Paso 1, y luego haz clic en Siguiente.

4. En el segundo cuadro de diálogo Asistente de reglas, necesitas:

4.1) Especificar una o más condiciones en el cuadro Paso 1 según tus necesidades;

En este caso, quiero imprimir solo los adjuntos en los correos electrónicos entrantes de un remitente especificado. Aquí, marco la casilla de personas o grupo público.

4.2) Haz clic en el valor subrayado en el cuadro Paso 2 para editar la condición;

4.3) Haz clic en Siguiente. Ver captura de pantalla:

5. En el tercer cuadro de diálogo Asistente de reglas, necesitas configurar lo siguiente.

5.1) En la sección Paso 1: Seleccionar acción(es), marca la casilla ejecutar un script;

5.2) En la sección Paso 2, haz clic en el texto subrayado “un script”;

5.3) En el cuadro de diálogo Seleccionar script que se abre, haz clic en el nombre del código VBA que agregaste anteriormente, y luego haz clic en Aceptar;

5.4) Haz clic en el botón Siguiente. Ver captura de pantalla:

Consejos: Si la opción ejecutar un script no aparece en tu Asistente de reglas, puedes mostrarla siguiendo el método mencionado en este artículo: restaurar la opción Ejecutar un script faltante en la regla de Outlook.

6. Luego aparecerá otro Asistente de reglas preguntando por excepciones. Puedes seleccionar las excepciones si es necesario, de lo contrario, haz clic en el botón Siguiente sin realizar ninguna selección.

7. En el último Asistente de reglas, necesitas especificar un nombre para la regla, y luego hacer clic en el botón Finalizar.

8. Luego volverás al cuadro de diálogo Reglas y alertas, podrás ver la regla que creaste listada dentro, haz clic en el botón Aceptar para finalizar toda la configuración.