Outlook: Cómo reenviar automáticamente un correo electrónico si no hay respuesta

Cuando envíe un correo electrónico a un colega, socio colaborador u otra persona y necesite una respuesta de forma urgente, puede configurar un ajuste para que el mensaje se reenvíe automáticamente si no recibe respuesta antes de la hora establecida.

Uso de recordatorios y VBA para configurar el reenvío automático si no hay respuesta

---

Uso de recordatorios y VBA para configurar el reenvío automático si no hay respuesta

Parte 1: configure un recordatorio para que le avise en un momento especificado

1. Haga clic con el botón derecho en un correo electrónico de la carpeta «Elementos enviados» que desee reenviar si no recibe respuesta y, en el menú contextual emergente, seleccione «Seguimiento» > «Agregar recordatorio».

2. En el cuadro de diálogo emergente «Personalizar», mantenga marcada la casilla «Recordatorio» y, en los cuadros desplegables inferiores, seleccione la fecha y hora anteriores a las que desea recibir la respuesta. También puede introducir directamente la fecha y la hora en dichos cuadros. Haga clic en «Aceptar».

Parte 2: Inserte un código VBA para reenviar correos electrónicos si no hay respuesta en el tiempo especificado

3. Pulse las teclas «Alt» + «F11» para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

4. Haga doble clic en «ThisOutlookSession» en el panel «Proyecto – Proyecto1» para crear un script en blanco y copie y pegue el siguiente código VBA en él.

VBA: Reenviar correo electrónico si no hay respuesta

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Guarde el código y regrese a la interfaz principal. Haga clic en «Archivo» > «Opciones». En la ventana «Opciones de Outlook», seleccione «Centro de confianza» en el panel izquierdo y, a continuación, haga clic en «Configuración del Centro de confianza». En la nueva ventana, elija «Configuración de macros» y asegúrese de que esté seleccionada la opción «Habilitar todas las macros (no se recomienda; puede ejecutarse código potencialmente peligroso)» en la sección derecha. Finalmente, haga clic en «Aceptar» > «Aceptar».

6. Ahora, si el correo electrónico enviado al que se ha asignado un recordatorio no recibe respuesta cuando llegue la hora especificada, aparecerá un cuadro de diálogo emergente para preguntarle si desea reenviar el mensaje como recordatorio.

7. Al hacer clic en «Sí», se abrirá una ventana de mensaje con el correo anterior adjunto, donde podrá editar nuevamente el cuerpo del mensaje y hacer clic en «Enviar» para reenviarlo.

8. Al hacer clic en «No», se eliminará el recordatorio.

Nota: Si el correo electrónico recibe una respuesta antes de la hora indicada, el recordatorio se eliminará automáticamente mediante el código VBA.