Contar el número de celdas de fecha en un rango por día de la semana

Excel proporciona la combinación de las funciones SUMAPRODUCTO y DIASEM para ayudarnos a contar fácilmente el número de días de la semana especificados dentro de un rango. Este tutorial ofrece una guía paso a paso para ayudarte a lograrlo.

¿Cómo contar celdas de fecha por día de la semana?

Como se muestra en la siguiente captura de pantalla, B3:B9 es el rango de datos original donde deseas contar las fechas, D3:D9 contiene los nombres secuenciales de los días de la semana, y E3:E9 contiene los números secuenciales del 1 al 7 para representar los números de los días de la semana. Para contar cuántas fechas en B3:B9 son iguales a lunes, martes, miércoles, etc., puedes hacer lo siguiente.

Fórmula genérica

=SUMAPRODUCTO(--(DIASEM(fechas)=num_dia))

Argumentos

¿Cómo usar esta fórmula?

1. Selecciona una celda en blanco para mostrar el resultado.

2. Ingresa la siguiente fórmula en ella y presiona la tecla Enter. Selecciona la celda del resultado y luego arrastra su controlador de relleno automático hacia abajo a otras celdas en la columna actual para aplicar la fórmula.

=SUMAPRODUCTO(--(DIASEM($B$3:$B$9,2)=E3))

Nota: Si hay celdas en blanco en el rango original, obtendrás resultados incorrectos. Para excluir celdas en blanco, aplica la siguiente fórmula:

=SUMAPRODUCTO((DIASEM($B$3:$B$9,2)=E3)*($B$3:$B$9<>""))

¿Cómo funciona esta fórmula?

=SUMAPRODUCTO(--(DIASEM($B$3:$B$9,2)=E3))

• DIASEM($B$3:$B$9,2): La función DIASEM devuelve un número entero del 1 al 7 para representar el día de la semana desde B3:B9. Aquí el resultado es {5;3;1;2;2;4;1}.
• {5;3;1;2;2;4;1}=E3: {5;3;1;2;2;4;1}=1 Aquí se verifica si cada número en la matriz es igual a 1, y devuelve una matriz de valores VERDADERO/FALSO como {FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO}.
• --({FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO}): Estos dos signos menos convierten “VERDADERO” en 1 y “FALSO” en 0. Aquí obtendrás una nueva matriz como {0;0;1;0;0;0;1}.
• SUMAPRODUCTO{0;0;1;0;0;0;1}: La función SUMAPRODUCTO suma todos los números en la matriz y devuelve el resultado final como 2.

Funciones relacionadas

Fórmulas relacionadas