Saltar al contenido principal

Countifs con lógica OR para múltiples criterios en Excel

Normalmente, puede usar la función CONTAR.SI para contar celdas en función de una o más condiciones con lógica Y en Excel. ¿Alguna vez ha sufrido una situación en la que necesita contar más de un valor de una sola columna o un rango de celdas? Esto significa contar con múltiples condiciones y lógica OR. En este caso, puede aplicar las funciones SUM y COUNTIFS juntas, o usar la función SUMPRODUCT.


Contar celdas con condiciones OR en Excel

Por ejemplo, tengo un rango de datos como se muestra a continuación en la captura de pantalla, ahora, quiero contar el número del producto que es "Lápiz" o "Regla", aquí, discutiré dos fórmulas para resolver esta tarea en Excel.

Contar celdas con condiciones OR mediante las funciones SUM y COUNTIFS

En Excel, para contar con múltiples condiciones OR, puede usar las funciones SUM y COUNTIFS con una constante de matriz, la sintaxis genérica es:

=SUM(COUNTIF(range, {criterion1, criterion2, criterion3, …}))
  • range: El rango de datos contiene los criterios desde los que cuenta las celdas;
  • criterion1, criterion2, criterion3…: Las condiciones en las que desea contar las celdas.

Para contar la cantidad de productos que son "Lápiz" o "Regla", copie o ingrese la fórmula siguiente en una celda en blanco y luego presione Participar clave para obtener el resultado:

=SUM(COUNTIFS(B2:B13,{"Pencil","Ruler"}))


Explicación de la fórmula:

= SUMA (CONTAR.SI (B2: B13, {"Lápiz", "Regla"}))

  • {"Lápiz", "Regla"}: Primero, debe empaquetar todas las condiciones en una matriz constante como esta: {"Lápiz", "Regla"}, separe los elementos con comas.
  • COUNTIFS (B2: B13, {"Lápiz", "Regla"}): Esta función CONTAR.SI obtendrá recuentos individuales para "Lápiz" y "Regla", y obtendrá el resultado como este: {2,3}.
  • SUMA (CONTAR.SI (B2: B13, {"Lápiz", "Regla"})) = SUMA ({2,3}): Finalmente, esta función SUM suma todos los elementos de la matriz y devuelve el resultado: 5.

Tips: También puede usar referencias de celda para los criterios, aplique la fórmula de matriz a continuación y luego presione Ctrl + Shift + Enter claves juntas para obtener el resultado correcto:

=SUM(COUNTIF(B2:B13,D2:D3))


Contar celdas con condiciones OR utilizando la función SUMPRODUCT

Aquí hay otra fórmula creada por la función SUMPRODUCT que también puede ayudar a contar celdas con lógica OR. La sintaxis genérica es:

=SUMPRODUCT(1*(range ={criterion1, criterion2, criterion3, …}))
  • range: El rango de datos contiene los criterios desde los que cuenta las celdas;
  • criterion1, criterion2, criterion3…: Las condiciones en las que desea contar las celdas.

Copie o ingrese la siguiente fórmula en una celda en blanco y presione Participar clave para devolver el resultado:

=SUMPRODUCT(1*(B2:B13={"Pencil","Ruler"}))


Explicación de la fórmula:

= SUMPRODUCTO (1 * (B2: B13 = {"Lápiz", "Regla"}))

  • B2: B13 = {"Lápiz", "Regla"}: Esta expresión compara cada criterio "Lápiz", "Regla" con la celda de rango B2: B13. Si se cumple el criterio, devuelve VERDADERO; de lo contrario, se mostrará FALSO, obtendrá el resultado como este: {VERDADERO, FALSO; FALSO, FALSO; FALSO, FALSO; FALSO, VERDADERO; FALSO, FALSO; VERDADERO, FALSO ; FALSO, FALSO; FALSO, VERDADERO; FALSO, FALSO; FALSO, FALSO; FALSO, VERDADERO; FALSO, FALSO}.
  • 1 * (B2: B13 = {"Lápiz", "Regla"}): La multiplicación convierte los valores lógicos - VERDADERO y FALSO en 1 y 0, por lo que obtendrá el resultado como este: {1,0; 0,0; 0,0; 0,1; 0,0; 1,0; 0,0 , 0,1; 0,0; 0,0; 0,1; 0,0; XNUMX}.
  • SUMPRODUCT(1*(B2:B13={"Pencil","Ruler"}))= SUMPRODUCT({1,0;0,0;0,0;0,1;0,0;1,0;0,0;0,1;0,0;0,0;0,1;0,0}): Por fin, la función SUMPRODUCTO suma todos los números de la matriz para obtener el resultado: 5.

Cuente celdas con múltiples conjuntos de condiciones de quirófano en Excel

A veces, es posible que deba contar las celdas con dos o más conjuntos de condiciones OR; en este caso, puede usar SUM y COUNTIFS con una constante de matriz o SUMPRODUCT con funciones ISNUMBER MATCH.

Contar celdas con dos conjuntos de condiciones OR mediante las funciones SUM y COUNTIFS

Para manejar solo dos conjuntos de criterios OR, solo necesita agregar otra constante de matriz a la fórmula COUNTIFS.

Por ejemplo, tengo el rango de datos como se muestra a continuación en la captura de pantalla, ahora quiero contar las personas que ordenaron "Lápiz" o "Regla" y la Cantidad es <100 o> 200.

Ingrese o copie la siguiente fórmula en una celda y luego presione Participar clave para obtener el resultado, vea la captura de pantalla:

=SUM(COUNTIFS(B2:B13,{"Pencil","Ruler"},C2:C13,{"<100";">200"}))

Note: En la fórmula, debe usar un punto y coma para la segunda constante de matriz, que crea una matriz vertical.


Contar celdas con varios conjuntos de condiciones OR mediante la función SUMPRODUCTO

La fórmula anterior solo funciona para dos conjuntos de criterios OR, si necesita contar con más criterios, una fórmula compleja SUMPRODUCT junto con las funciones ISNUMBER MATCH pueden ayudarlo.

Tome los siguientes datos, por ejemplo, para contar las personas que pidieron "Lápiz" o "Regla" y el estado es "Entregado" o "En tránsito" y firmado por "Bob" o "Eko", debe aplicar una fórmula compleja. .

Copie o ingrese la fórmula a continuación en una celda en blanco y luego presione Participar para obtener el cálculo, vea la captura de pantalla:

=SUMPRODUCT(ISNUMBER(MATCH(B2:B13,{"Pencil","Ruler"},0))*ISNUMBER(MATCH(C2:C13,{"Delivered","In transit"},0))*ISNUMBER(MATCH(D2:D13,{"Bob","Eko"},0)))


Explicación de la fórmula:

=SUMPRODUCT(ISNUMBER(MATCH(B2:B13,{"Pencil","Ruler"},0))*ISNUMBER(MATCH(C2:C13,{"Delivered","In transit"},0))*ISNUMBER(MATCH(D2:D13,{"Bob","Eko"},0)))

ISNUMBER (COINCIDIR (B2: B13, {"Lápiz", "Regla"}, 0)):

  • COINCIDIR (B2: B13, {"Lápiz", "Regla"}, 0): Esta función COINCIDIR se utiliza para comparar cada celda en el rango B2: B13 con la constante de matriz correspondiente. Si se encuentra la coincidencia, devuelve una posición relativa del valor en la matriz; de lo contrario, se muestra un valor de error. Entonces, obtendrá la lista de matrices como esta: {1; # N / A; # N / A; 2; # N / A; 1; # N / A; 2; 1; # N / A; 2; # N / A}.
  • ISNUMBER(MATCH(B2:B13,{"Pencil","Ruler"},0))= ISNUMBER({1;#N/A;#N/A;2;#N/A;1;#N/A;2;1;#N/A;2;#N/A}): La función ISNUMBER convierte los números en VERDADEROS y los valores de error en FALSOS de la siguiente manera: {VERDADERO; FALSO; FALSO; VERDADERO; FALSO; VERDADERO; FALSO; VERDADERO; VERDADERO; FALSO; VERDADERO; FALSO}.

La lógica anterior también se puede aplicar a la segunda y tercera expresiones ISNUMBER.

SUMPRODUCT(ISNUMBER(MATCH(B2:B13,{"Pencil","Ruler"},0))*ISNUMBER(MATCH(C2:C13,{"Delivered","In transit"},0))*ISNUMBER(MATCH(D2:D13,{"Bob","Eko"},0))):

  • Luego, estas tres matrices se multiplican dentro de SUMPRODUCT, que convierte automáticamente los valores VERDADERO y FALSO en 1 y 0 como parte de la operación matemática como esta: SUMPRODUCTO ({1; 0; 0; 1; 0; 1; 0; 1; 1; 0; 1; 0} * {1; 1; 0; 0; 1; 1; 0; 1; 1; 0; 1; 1} * {1; 0; 0; 0; 0; 0; 0; 1; 0; 0; 1; 0}) = SUMPRODUCTO ({1; 0; 0; 0; 0; 0; 0; 1; 0; 0; 1; 0}).
  • Por último, la función SUMPRODUCTO suma todos los números de la matriz para obtener el resultado: 3.

Función relativa utilizada:

  • SUMA:
  • La función SUMA de Excel devuelve la suma de los valores proporcionados.
  • CONTAR:
  • La función CONTAR.SI es una función estadística en Excel que se utiliza para contar el número de celdas que cumplen con un criterio.
  • SUMPRODUCTO:
  • La función SUMPRODUCTO se puede usar para multiplicar dos o más columnas o matrices juntas y luego obtener la suma de productos.
  • ES NÚMERO:
  • La función ISNUMBER de Excel devuelve VERDADERO cuando una celda contiene un número y FALSO si no.
  • PARTIDO:
  • La función COINCIDIR de Microsoft Excel busca un valor específico en un rango de celdas y devuelve la posición relativa de este valor.

Más artículos:

  • Contar valores numéricos únicos según criterios
  • En la hoja de cálculo de Excel, puede sufrir un problema que cuenta el número de valores numéricos únicos en función de una condición específica. Por ejemplo, ¿cómo puedo contar los valores de cantidad únicos del producto "camiseta" del informe como se muestra a continuación? En este artículo, mostraré algunas fórmulas para lograr esta tarea en Excel.
  • Contar el número de filas con varios criterios OR
  • Para contar el número de filas con múltiples criterios en diferentes columnas, con lógica OR, la función SUMPRODUCTO puede ayudarlo. Por ejemplo, tengo un informe de producto como se muestra a continuación en la captura de pantalla, ahora quiero contar las filas donde el producto es "camiseta" o el color es "Negro". ¿Cómo lidiar con esta tarea en Excel?

Las mejores herramientas de productividad de oficina

Kutools para Excel: te ayuda a destacar entre la multitud

🤖 Asistente de IA de Kutools: Revolucionar el análisis de datos basado en: Ejecución inteligente   |  Generar codigo  |  Crear fórmulas personalizadas  |  Analizar datos y generar gráficos  |  Invocar funciones de Kutools...
Características populares: Buscar, resaltar o identificar duplicados  |  Eliminar filas en blanco  |  Combine columnas o celdas sin perder datos  |  Ronda sin fórmula ...
Súper búsqueda virtual: Múltiples criterios  |  Valor múltiple  |  En varias hojas  |  Búsqueda difusa...
Adv. La lista desplegable: Lista desplegable fácil  |  Lista desplegable dependiente  |  Lista desplegable de selección múltiple...
Administrador de columnas: Agregar un número específico de columnas  |  Mover columnas  |  Toggle Estado de visibilidad de columnas ocultas  Comparar columnas con Seleccionar celdas iguales y diferentes ...
Características destacadas: Enfoque de cuadrícula  |  Vista de diseño  |  Gran barra de fórmulas  |  Administrador de hojas y libros de trabajo | Biblioteca de Recursos (Texto automático)  |  Selector de fechas  |  Combinar hojas de trabajo  |  Cifrar/descifrar celdas  |  Enviar correos electrónicos por lista  |  Súper filtro  |  Filtro especial (filtro negrita/cursiva/tachado...) ...
Los 15 mejores conjuntos de herramientas12 Texto Herramientas (Añadir texto, Quitar caracteres ...)  |  50+ Tabla Tipos (Diagrama de Gantt ...)  |  40+ Práctico Fórmulas (Calcular la edad según el cumpleaños ...)  |  19 Inserción Herramientas (Insertar código QR, Insertar imagen desde la ruta ...)  |  12 Conversión Herramientas (Números a palabras, Conversión de Moneda ...)  |  7 Fusionar y dividir Herramientas (Filas combinadas avanzadas, Dividir celdas de Excel ...)  |  ... y más

Kutools para Excel cuenta con más de 300 funciones, Garantizar que lo que necesita está a sólo un clic de distancia...

Descripción


Ficha Office: habilite la lectura y edición con pestañas en Microsoft Office (incluya Excel)

  • ¡Un segundo para cambiar entre docenas de documentos abiertos!
  • Reduzca cientos de clics del mouse para usted todos los días, diga adiós a la mano del mouse.
  • Aumenta su productividad en un 50% al ver y editar varios documentos.
  • Trae pestañas eficientes a Office (incluido Excel), al igual que Chrome, Edge y Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations