Extraer nombre de archivo de una ruta en Excel
Este tutorial explica cómo aplicar fórmulas para extraer el nombre de archivo con o sin extensión desde una ruta de archivo en una celda específica en Excel.
Extraer nombre de archivo con extensión de una ruta
Extraer nombre de archivo sin extensión de una ruta
Extraer nombre de archivo con extensión de una ruta
Como se muestra en la siguiente captura de pantalla, hay una lista que contiene diferentes rutas de archivos, y desea extraer solo los nombres de archivo con extensiones de ellas. La siguiente fórmula le ayudará a resolver el problema.
Fórmula genérica
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
Argumentos
A1: Representa la celda que contiene la ruta de archivo desde la cual extraerá el nombre de archivo.
¿Cómo usar esta fórmula?
1. Seleccione una celda en blanco para mostrar el nombre de archivo. En este caso, selecciono la celda D3.
2. Introduzca la siguiente fórmula en ella y presione la tecla Enter. Seleccione la celda del resultado y luego arrastre su controlador de relleno hacia abajo para aplicarlo a otras celdas.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Ahora todos los nombres de archivo con extensiones en las rutas específicas se han extraído como se muestra en la captura de pantalla anterior.
Notas:
- En esta fórmula, B3 es la celda que contiene la ruta de archivo. Por favor, cámbielo según sea necesario.
- Si el nombre de archivo tiene una longitud de no más de 99 caracteres, también se puede usar la siguiente fórmula más corta para resolver el problema. Vea la captura de pantalla mostrada a continuación.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
¿Cómo funciona esta fórmula?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): La función LEN calcula la longitud total en "D:\\files\work\Q1\Jan\text.txt" y devuelve el resultado como 30;
- LEN(SUBSTITUTE(B3,"\","")): La función SUBSTITUTE reemplaza el carácter "\" con nada. El resultado es "D:filesworkQ1Jantext.txt". Luego, la función LEN calcula la longitud total de "D:filesworkQ1Jantext.txt" y obtiene el resultado 24;
- SUBSTITUTE(B3,"\","*",30-24): La función SUBSTITUTE reemplaza el tercer carácter (30-24=6) "\" en "D:\\files\work\Q1\Jan\text.txt" con un solo carácter "*". Aquí el resultado es "D:\\files\work\Q1\Jan*text.txt";
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): La función FIND localiza la posición del carácter "*" en "D:\\files\work\Q1\Jan*text.txt" y finalmente devuelve 22. Esto significa que el carácter "*" está en la posición 22 en "D:\\files\work\Q1\Jan*text.txt".
2. =MID(B3,22+1,LEN(B3))
- Como se explicó anteriormente, LEN(B3) devuelve el resultado como 30, aquí la función MID puede mostrarse como =MID("D:\\files\work\Q1\Jan\text.txt",23,30). Esto significa que la función MID extrae 30 caracteres de la cadena "D:\\files\work\Q1\Jan\text.txt", comenzando en el carácter 23. Aquí el resultado es text.txt.
Extraer nombre de archivo sin extensión de una ruta
En otra circunstancia, es posible que solo necesite extraer el nombre de archivo sin extensión de una ruta como se muestra en la siguiente captura de pantalla. Esta sección proporcionará una fórmula larga para ayudarle a lograrlo.
Fórmula genérica
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
Argumentos
A1: Representa la celda que contiene la ruta de archivo desde la cual extraerá el nombre de archivo.
CHAR(1): El CHAR(1) aquí puede ser reemplazado por cualquier número CHAR que necesite. O puede ser reemplazado por un símbolo específico encerrado entre comillas como "*".
¿Cómo usar esta fórmula?
1. Seleccione una celda en blanco para mostrar el nombre de archivo sin la extensión.
2. Introduzca la siguiente fórmula en ella y presione la tecla Enter. Seleccione la celda del resultado y luego arrastre su controlador de relleno hacia abajo para aplicarlo a otras celdas.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Nota: En esta fórmula, B3 es la celda que contiene la ruta de archivo. Por favor, cámbielo según sea necesario.
Funciones relacionadas
Función MID de Excel
La función MID de Excel se utiliza para encontrar y devolver un número específico de caracteres desde el medio de una cadena de texto dada.
Función FIND de Excel
La función FIND de Excel se utiliza para encontrar una cadena dentro de otra cadena y devuelve la posición inicial de la cadena dentro de la otra.
Función SUBSTITUTE de Excel
La función SUBSTITUTE de Excel reemplaza texto o caracteres dentro de una cadena de texto con otro texto o caracteres.
Función LEN de Excel
La función LEN de Excel devuelve el número de caracteres en una cadena de texto.
Función IFERROR de Excel
La función IFERROR se utiliza para devolver un resultado personalizado cuando una fórmula evalúa un error, y devuelve un resultado normal cuando no ocurre ningún error.
Fórmulas relacionadas
Extraer múltiples líneas de una celda
Si tiene una lista de cadenas de texto separadas por saltos de línea (que ocurren al presionar las teclas Alt + Enter al ingresar el texto) y desea extraer estas líneas de texto en varias celdas, la fórmula en este tutorial le ayudará.
Extraer la última línea de texto de una celda de múltiples líneas
Para extraer la última línea de texto de una cadena de texto separada por saltos de línea, una fórmula en este tutorial puede ayudarle a manejar esta tarea en Excel.
Extraer la palabra N de una cadena de texto en Excel
Este artículo explica cómo usar una fórmula para extraer la palabra N específica de una cadena de texto en una celda en Excel.
Extraer las últimas dos palabras de una celda en Excel
Este tutorial explica cómo usar una fórmula para extraer las últimas dos palabras de una celda en Excel.
Extraer palabra que comienza con un carácter específico en Excel
Este tutorial proporciona una fórmula con pasos detallados para ayudarle a extraer la palabra que comienza con un carácter específico de una cadena de texto en una celda en Excel.
Extraer todas las palabras excepto la primera o la última
En este tutorial, aprenderá cómo usar fórmulas para extraer todas las palabras de una celda excepto la primera o la última en Excel.
Las Mejores Herramientas de Productividad para Office
Kutools para Excel - Te Ayuda a Sobresalir de la Multitud
Kutools para Excel cuenta con más de 300 funciones, asegurando que lo que necesitas esté a solo un clic de distancia...
Office Tab - Habilita la Lectura y Edición con Pestañas en Microsoft Office (incluye Excel)
- ¡Un segundo para cambiar entre docenas de documentos abiertos!
- Reduce cientos de clics del ratón para ti cada día, di adiós al síndrome del túnel carpiano.
- Aumenta tu productividad en un 50% al ver y editar múltiples documentos.
- Trae pestañas eficientes a Office (incluye Excel), igual que Chrome, Edge y Firefox.