Fórmula de Excel: Extraer texto desde la derecha hasta un carácter

En este tutorial, se proporciona una fórmula para extraer texto desde la derecha del texto dado hasta encontrar un carácter específico, y se explican los argumentos de cada fórmula.

Fórmula genérica:

SI.ERROR(DERECHA(txt,LARGO(txt)-BUSCAR("$",SUSTITUIR(txt," char","$",LARGO(txt)-LARGO(SUSTITUIR(txt,"char",""))))), txt)

Argumentos

Txt: la referencia de celda o cadena de texto que utiliza.

Char: el carácter hasta el que desea extraer texto desde la derecha.

Nota

Si la fórmula no encuentra el carácter especificado, devuelve los datos originales.

Cómo funciona esta fórmula

Por ejemplo, si necesita extraer el texto desde la derecha de la cadena de texto en la celda B3 hasta un espacio, utilice la siguiente fórmula:

=SI.ERROR(DERECHA(B3,LARGO(B3)-BUSCAR("$",SUSTITUIR(B3," ","$",LARGO(B3)-LARGO(SUSTITUIR(B3," ",""))))), B3)

Pulse Enter para extraer el texto.

Explicación

La función SUSTITUIR se utiliza para reemplazar un texto o carácter con uno nuevo. Aquí, la fórmula SUSTITUIR(B3," ","") dentro de la fórmula larga reemplaza el espacio por nada y devuelve “Gotolastcell”.

LARGO función cuenta el número de caracteres en el texto dado. Ahora, LARGO(SUSTITUIR(B3," ","")) puede verse como LARGO(“Gotolastcell”) que devuelve 12.

Entonces, la fórmula LARGO(B3)-LARGO(SUSTITUIR(B3," ","")) devuelve 3. Luego, la fórmula SUSTITUIR(B3," ","$",LARGO(B3)-LARGO(SUSTITUIR(B3," ",""))) puede verse como SUSTITUIR(B3," ","$",3), que devuelve “Go to last$cell”.

BUSCAR función encuentra la ubicación del texto en un texto dado. La fórmula BUSCAR("$",SUSTITUIR(B3," ","$",LARGO(B3)-LARGO(SUSTITUIR(B3," ",""))))) puede verse como BUSCAR("$","Go to last$cell") que devuelve 11.

Función DERECHA extrae texto desde el lado derecho del texto. Aquí DERECHA(B3,LARGO(B3)-BUSCAR("$",SUSTITUIR(B3," ","$",LARGO(B3)-LARGO(SUSTITUIR(B3," ",""))))) puede verse como
DERECHA(B3,LARGO(B3)-11)
=DERECHA(B3,3)
=”cell”

Función SI.ERROR se utiliza para capturar y manejar errores. Aquí, si la fórmula no encuentra el carácter “ “, devuelve los datos originales.

Archivo de muestra

Haga clic para descargar el archivo de muestra

---

Fórmulas relacionadas

• Primera letra en minúscula
  Aquí se introduce la fórmula para agregar nuevo texto en una posición determinada de la cadena de texto.
• Recortar texto a N palabras
  Aquí se presenta la fórmula para extraer n palabras desde el lado izquierdo de una cadena de texto.
• Agregar ceros iniciales para longitud fija
  Este tutorial proporciona fórmulas para agregar ceros iniciales para que el texto tenga la misma longitud.
• Agregar guiones al número de teléfono
  Para agregar guiones al número de teléfono, puede usar una fórmula para resolverlo en Excel.

---

Funciones relacionadas

• Función DERECHA
  Extraer texto desde el lado derecho.
• Función SUSTITUIR
  Reemplazar texto antiguo con uno nuevo.
• Función LARGO
  Obtener el número de caracteres en el texto.
• Función BUSCAR
  Encuentra la posición de un carácter o subcadena específica en la cadena de texto dada.
• Función ENCONTRAR
  Buscar una cadena dentro de otra cadena