Buscar y recuperar toda la columna
Para buscar y recuperar una columna completa haciendo coincidir un valor específico, una fórmula combinada de INDICE y COINCIDIR te será de ayuda.
Buscar y recuperar una columna completa basada en un valor específico
Sumar una columna completa basada en un valor específico
Análisis adicional de una columna completa basada en un valor específico
Buscar y recuperar una columna completa basada en un valor específico
Para obtener una lista de las ventas del segundo trimestre según la tabla anterior, puedes usar primero la función COINCIDIR para devolver la posición de las ventas del segundo trimestre, y luego proporcionarla a INDICE para recuperar los valores en esa posición.
Sintaxis genérica
=INDICE(rango_devuelto,0,COINCIDIR(valor_búsqueda,rango_búsqueda,0))
√ Nota: Esta es una fórmula matricial que requiere que presiones Ctrl + Shift + Enter para ingresarla.
- rango_devuelto: El rango desde donde deseas que la fórmula combinada devuelva la lista de ventas del segundo trimestre. Aquí se refiere al rango de ventas.
- valor_búsqueda: El valor que la fórmula combinada utiliza para encontrar su información de ventas correspondiente. Aquí se refiere al trimestre dado.
- rango_búsqueda: El rango de celdas donde se busca el valor_búsqueda. Aquí se refiere a los encabezados de los trimestres.
- tipo_coincidencia 0: Obliga a COINCIDIR a encontrar el primer valor que sea exactamente igual al valor_búsqueda.
Para obtener una lista de las ventas del segundo trimestre, copia o introduce la siguiente fórmula en la celda I6, presiona Ctrl + Shift + Enter, y luego haz doble clic en la celda y presiona F9 para obtener el resultado:
=INDICE(C5:F11,0,COINCIDIR("Q2",C4:F4,0))
O, usa una referencia de celda para hacer que la fórmula sea dinámica:
=INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0))
Explicación de la fórmula
=INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0))
- COINCIDIR(I5,C4:F4,0): El tipo_coincidencia 0 obliga a la función COINCIDIR a devolver la posición de Q2, el valor en I5, en el rango C4:F5, que es 2.
- INDICE(C5:F11C5:F11,0,COINCIDIR(I5,C4:F4,0)) = INDICE(C5:F11C5:F11,0,2): La función INDICE devuelve todos los valores en la segunda columna del rango C5:F11 en una matriz como esta: {7865;4322;8534;5463;3252;7683;3654}. Ten en cuenta que para hacer visible la matriz en Excel, debes hacer doble clic en la celda donde ingresaste la fórmula y luego presionar F9.
Sumar una columna completa basada en un valor específico
Dado que ya tenemos la lista de ventas en mano, obtener el volumen total de ventas del segundo trimestre sería un caso sencillo para nosotros. Todo lo que necesitamos hacer es agregar la función SUMA a la fórmula para sumar todos los valores de ventas de la lista.
Sintaxis genérica
=SUMA(INDICE(rango_devuelto,0,COINCIDIR(valor_búsqueda,rango_búsqueda,0)))
En este ejemplo concreto, para obtener el volumen total de ventas del segundo trimestre, copia o introduce la siguiente fórmula en la celda I8, y presiona Enter para obtener el resultado:
=SUMA(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)))
Explicación de la fórmula
=SUMA(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)))
- COINCIDIR(I5,C4:F4,0): El tipo_coincidencia 0 obliga a la función COINCIDIR a devolver la posición de Q2, el valor en I5, en el rango C4:F5, que es 2.
- INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)) = INDICE(C5:F11,0,2): La función INDICE devuelve todos los valores en la segunda columna del rango C5:F11 en una matriz como esta: {7865;4322;8534;5463;3252;7683;3654}.
- SUMA(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0))) = SUMA({7865;4322;8534;5463;3252;7683;3654}): La función SUMA suma todos los valores en la matriz y luego obtiene el volumen total de ventas del segundo trimestre, $40,773.
Análisis adicional de una columna completa basada en un valor específico
Para procesamiento adicional en la lista de ventas del segundo trimestre, simplemente puedes agregar otras funciones como SUMA, PROMEDIO, MAX, MIN, GRANDE, etc., a la fórmula.
Por ejemplo, para obtener un volumen de ventas promedio durante el segundo trimestre, puedes usar la fórmula:
=PROMEDIO(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)))
Para averiguar las ventas más altas durante el segundo trimestre, usa una de las siguientes fórmulas:
=MAX(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)))
O
=GRANDE(INDICE(C5:F11,0,COINCIDIR(I5,C4:F4,0)),1)
Funciones relacionadas
La función INDICE de Excel devuelve el valor mostrado basado en una posición dada de un rango o una matriz.
La función COINCIDIR de Excel busca un valor específico en un rango de celdas y devuelve la posición relativa del valor.
Fórmulas relacionadas
Buscar y recuperar toda la fila
Para buscar y recuperar una fila completa de datos haciendo coincidir un valor específico, puedes usar las funciones INDICE y COINCIDIR para crear una fórmula matricial.
Coincidencia exacta con INDICE y COINCIDIR
Si necesitas encontrar la información enumerada en Excel sobre un producto, película o persona específica, etc., deberías aprovechar bien la combinación de las funciones INDICE y COINCIDIR.
Coincidencia aproximada con INDICE y COINCIDIR
Hay momentos en los que necesitamos encontrar coincidencias aproximadas en Excel para evaluar el desempeño de los empleados, calificar las puntuaciones de los estudiantes, calcular el envío postal según el peso, etc. En este tutorial, hablaremos sobre cómo usar las funciones INDICE y COINCIDIR para recuperar los resultados que necesitamos.
Búsqueda sensible a mayúsculas y minúsculas
Es posible que sepas que puedes combinar las funciones INDICE y COINCIDIR, o usar la función BUSCARV para buscar valores en Excel. Sin embargo, las búsquedas no son sensibles a mayúsculas y minúsculas. Por lo tanto, para realizar una coincidencia sensible a mayúsculas y minúsculas, deberías aprovechar las funciones EXACTO y ELEGIR.
Las Mejores Herramientas de Productividad para Office
Kutools para Excel - Te Ayuda a Sobresalir de la Multitud
Kutools para Excel cuenta con más de 300 funciones, asegurando que lo que necesitas esté a solo un clic de distancia...
Office Tab - Habilita Lectura y Edición con Pestañas en Microsoft Office (incluye Excel)
- ¡Un segundo para cambiar entre docenas de documentos abiertos!
- Reduce cientos de clics del ratón cada día, di adiós al síndrome del túnel carpiano.
- Incrementa tu productividad en un 50% al visualizar y editar múltiples documentos.
- Trae pestañas eficientes a Office (incluye Excel), tal como Chrome, Edge y Firefox.