Skip to main content

Eliminar texto antes o después del primer o último carácter específico de las cadenas de texto

Author: Xiaoyang Last Modified: 2025-08-06

Este tutorial explicará cómo eliminar el texto antes o después del primer o último carácter específico, como un espacio o una coma, de una lista de cadenas de texto en Excel.

doc-remove-after-first-space-01

Eliminar texto antes o después del primer carácter específico de las cadenas de texto

Eliminar texto antes del primer carácter específico (como un espacio o una coma)

Para eliminar el texto antes del primer carácter específico de las cadenas de texto, las funciones DERECHA, LARGO y ENCONTRAR pueden ayudarte. La sintaxis general es:

=DERECHA(celda, LARGO(celda)-ENCONTRAR("carácter", celda))
  • celda: La referencia de la celda o cadena de texto de la que deseas eliminar el texto.
  • carácter: El separador específico según el cual deseas eliminar el texto.

Por favor, introduce o copia la siguiente fórmula en una celda vacía donde deseas obtener el resultado:

=DERECHA(A2,LARGO(A2)-ENCONTRAR(" ",A2))

Luego, arrastra el controlador de relleno hacia abajo hasta las celdas donde deseas aplicar esta fórmula, y todo el texto antes del primer espacio se habrá eliminado de las cadenas de texto, como se muestra en la captura de pantalla:

doc-remove-after-first-space-02

Explicación de la fórmula:

1.LARGO(A2)-ENCONTRAR(" ",A2): Esta parte de la fórmula se reconoce como los num_chars dentro de la función DERECHA.

  • ENCONTRAR(" ",A2): La función ENCONTRAR se utiliza para obtener la posición del primer espacio, devuelve el número 11.
  • LARGO(A2): Esta función LARGO devolverá el número total de caracteres en la celda A2. Obtendrá el número 27.
  • LARGO(A2)-ENCONTRAR(" ",A2)=27-11: Restar la posición del primer espacio de la longitud total de la celda A2 obtendrá el número de caracteres que están después del primer espacio.

2. DERECHA(A2,LARGO(A2)-ENCONTRAR(" ",A2))=DERECHA(A2, 16): Finalmente, esta función DERECHA extraerá 16 caracteres desde el lado derecho de la cadena de texto en la celda A2.

Eliminar texto después del primer carácter específico (como un espacio o una coma)

En Excel, con la combinación de las funciones IZQUIERDA y ENCONTRAR, puedes eliminar rápidamente el texto después del primer carácter específico. La sintaxis general es:

=IZQUIERDA(celda,ENCONTRAR("carácter",celda)-1)
  • celda: La referencia de la celda o cadena de texto de la que deseas eliminar el texto.
  • carácter: El separador específico según el cual deseas eliminar el texto.

Por favor, aplica la siguiente fórmula en una celda vacía:

=IZQUIERDA(A2,ENCONTRAR(" ",A2)-1)

Y luego, arrastra el controlador de relleno hacia abajo a las celdas donde deseas aplicar esta fórmula, y todo el texto después del primer espacio se habrá eliminado al instante, como se muestra en la captura de pantalla:

doc-remove-after-first-space-03

Explicación de la fórmula:

1.ENCONTRAR(" ",A2)-1: Esta función ENCONTRAR obtiene la posición del primer espacio en la celda A2, restar 1 significa excluir el carácter de espacio. Obtendrá el resultado 10. Se reconoce como los num_chars dentro de la función IZQUIERDA.

2. IZQUIERDA(A2,ENCONTRAR(" ",A2)-1)=IZQUIERDA(A2, 10): Esta función IZQUIERDA extraerá 10 caracteres desde el lado izquierdo de la cadena de texto en la celda A2.

Eliminar texto antes o después del último carácter específico de las cadenas de texto

Eliminar texto antes del último carácter específico (como un espacio o una coma)

Si necesitas eliminar todo el texto antes del último carácter específico y solo dejar las subcadenas después del último carácter específico, las funciones DERECHA, LARGO, BUSCAR y SUSTITUIR pueden ayudarte. La sintaxis general es:

=DERECHA(celda,LARGO(celda)-BUSCAR("#",SUSTITUIR(celda,"carácter","#",LARGO(celda)-LARGO(SUSTITUIR(celda,"carácter","")))))
  • celda: La referencia de la celda o cadena de texto de la que deseas eliminar el texto.
  • carácter: El separador específico según el cual deseas eliminar el texto.

Para resolver esta tarea, por favor copia o escribe la siguiente fórmula en una celda vacía:

=DERECHA(A2,LARGO(A2)-BUSCAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ","")))))

Y luego, arrastra el controlador de relleno para llenar esta fórmula en otras celdas que necesites, y ahora, todo el texto antes del último espacio se habrá eliminado, solo se mantendrá el texto después del último espacio, como se muestra en la captura de pantalla:

doc-remove-after-first-space-04

Explicación de la fórmula:

1. LARGO(A2)-BUSCAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ","")))):

  • SUSTITUIR(A2," ",""): Esta función SUSTITUIR se utiliza para reemplazar todos los caracteres de espacio con nada en la celda A2, y obtendrás el resultado así: “Tom-Grade1HoustonTexasUS”.
  • LARGO(SUSTITUIR(A2," ","")): Esta función LARGO devuelve el número de caracteres de la cadena de texto que fue devuelta por la función SUSTITUIR sin espacios. Obtendrá el número 24.
  • LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))=27-24: Restar el número de caracteres sin espacio de la longitud total de la celda A2 obtendrá el número de espacios entre la cadena de texto. Esto obtendrá el número 3.
  • SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ","")))= SUSTITUIR(A2," ","#", 3): Esta función SUSTITUIR se utiliza para reemplazar el último carácter de espacio con un carácter # específico, el resultado es: “Tom-Grade1 Houston Texas#US”.
  • BUSCAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))= BUSCAR("#", "Tom-Grade1 Houston Texas#US") : Esta función BUSCAR encontrará la posición del carácter # específico dentro de la cadena de texto devuelta por la función SUSTITUIR. Obtendrá el número 25.
  • LARGO(A2)-BUSCAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))=27-25: La longitud total del texto en la celda A2 resta la posición del último espacio, obtendrá el número de caracteres que están después del último espacio. Y esto obtendrá el número 2.

2. DERECHA(A2,LARGO(A2)-BUSCAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ","")))))=DERECHA(A2, 2): Finalmente, esta función DERECHA extraerá 2 caracteres desde el lado derecho de la cadena de texto en la celda A2.

Eliminar texto después del último carácter específico (como un espacio o una coma)

Para eliminar el texto después del último carácter específico, las funciones IZQUIERDA, ENCONTRAR, SUSTITUIR y LARGO pueden ayudarte, la sintaxis general es:

=IZQUIERDA(celda,ENCONTRAR("#",SUSTITUIR(celda,"carácter","#",LARGO(celda)-LARGO(SUSTITUIR(celda,"carácter",""))))-1)
  • celda: La referencia de la celda o cadena de texto de la que deseas eliminar el texto.
  • carácter: El separador específico según el cual deseas eliminar el texto.

Por favor, introduce o copia la siguiente fórmula en una celda vacía:

=IZQUIERDA(A2,ENCONTRAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))-1)

Y luego, arrastra el controlador de relleno hacia abajo a las celdas donde deseas aplicar esta fórmula, y obtendrás el resultado como se muestra en la captura de pantalla a continuación:

doc-remove-after-first-space-05

Explicación de la fórmula:

1. ENCONTRAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))-1:

  • SUSTITUIR(A2," ",""): Esta función SUSTITUIR se utiliza para reemplazar todos los caracteres de espacio con nada en la celda A2, y obtendrás el resultado así: “Tom-Grade1HoustonTexasUS”.
  • LARGO(SUSTITUIR(A2," ","")): Esta función LARGO devuelve el número de caracteres de la cadena de texto que fue devuelta por la función SUSTITUIR sin espacios. Obtendrá el número 24.
  • LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))=27-24: Restar el número de caracteres sin espacio de la longitud total de la celda A2 obtendrá el número de espacios entre la cadena de texto. Esto obtendrá el número 3.
  • SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ","")))= SUSTITUIR(A2," ","#", 3): Esta función SUSTITUIR se utiliza para reemplazar el último carácter de espacio con un carácter # específico, el resultado es: “Tom-Grade1 Houston Texas#US”.
  • ENCONTRAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))-1=ENCONTRAR("#", "Tom-Grade1 Houston Texas#US ")-1=25-1: Esta función ENCONTRAR devolverá la posición del carácter # específico en la cadena de texto que fue devuelta por la función SUSTITUIR, restar 1 significa excluir el carácter de espacio. Y esto obtendrá el número 24.

2. IZQUIERDA(A2,ENCONTRAR("#",SUSTITUIR(A2," ","#",LARGO(A2)-LARGO(SUSTITUIR(A2," ",""))))-1)=IZQUIERDA(A2, 24): Finalmente, esta función IZQUIERDA se utiliza para extraer 24 caracteres desde el lado izquierdo de la cadena de texto de la celda A2.

Funciones relacionadas utilizadas:

  • IZQUIERDA:
  • La función IZQUIERDA extrae el número dado de caracteres del lado izquierdo de una cadena suministrada.
  • DERECHA:
  • La función DERECHA se utiliza para extraer un número específico de caracteres del lado derecho de la cadena de texto.
  • ENCONTRAR:
  • La función ENCONTRAR se utiliza para encontrar una cadena dentro de otra cadena y devuelve la posición inicial de la cadena dentro de otra.
  • BUSCAR:
  • La función BUSCAR puede ayudarte a encontrar la posición de un carácter o subcadena específica desde la cadena de texto dada.
  • SUSTITUIR:
  • La función SUSTITUIR de Excel reemplaza texto o caracteres dentro de una cadena de texto con otro texto o caracteres.
  • LARGO:
  • La función LARGO devuelve el número de caracteres en una cadena de texto.

Más artículos:

  • Eliminar o quitar caracteres no numéricos de cadenas de texto
  • A veces, es posible que necesites eliminar todos los caracteres no numéricos de las cadenas de texto y solo mantener los números, como se muestra en la captura de pantalla a continuación. Este artículo presentará algunas fórmulas para resolver esta tarea en Excel.

Las Mejores Herramientas de Productividad para Office

Kutools para Excel - Te Ayuda a Sobresalir de la Multitud

🤖 Asistente de KUTOOLS AI: Revoluciona el análisis de datos basado en: Ejecución Inteligente   |  Generar Código  |  Crear Fórmulas Personalizadas  |  Analizar Datos y Generar Gráficos  |  Invocar Funciones de Kutools…
Funciones Populares: Buscar, Resaltar o Identificar Duplicados  |  Eliminar Filas en Blanco  |  Combinar Columnas o Celdas sin Perder Datos  |  Redondear sin Fórmula ...
Super VLookup: Criterios Múltiples  |  Valores Múltiples  |  A través de Hojas Múltiples  |  Coincidencia Difusa...
Lista Desplegable Avanzada: Lista Desplegable Fácil  |  Lista Desplegable Dependiente  |  Lista Desplegable con Selección Múltiple...
Administrador de Columnas: Agregar un Número Específico de Columnas  |  Mover Columnas  |  Cambiar Estado de Visibilidad de Columnas Ocultas  |  Comparar Columnas para Seleccionar Celdas Iguales y Diferentes ...
Funciones Destacadas: Cuadrícula de Enfoque  |  Vista de Diseño  |  Barra de Fórmulas Mejorada  |  Administrador de Libros y Hojas de Trabajo | Biblioteca de Recursos (AutoTexto)  |  Selector de Fechas  |  Combinar Hojas de Trabajo  |  Encriptar/Descifrar Celdas  |  Enviar Correos Electrónicos por Lista  |  Super Filtro  |  Filtro Especial (filtrar negrita/cursiva/tachado...) ...
Los 15 Mejores Conjuntos de Herramientas:  12 Herramientas de Texto (Agregar Texto, Eliminar Caracteres ...)  |  +50 Tipos de Gráficos (Diagrama de Gantt ...)  |  +40 Fórmulas Prácticas (Calcular edad basada en la fecha de nacimiento ...)  |  19 Herramientas de Inserción (Insertar código QR, Insertar imagen desde Ruta ...)  |  12 Herramientas de Conversión (Convertir a palabras, Conversión de moneda ...)  |  7 Herramientas de Combinación y División (Combinar Filas Avanzado, Dividir celdas de Excel ...)  |  ... y más
Usa Kutools en tu idioma preferido – compatible con inglés, español, alemán, francés, chino y más de 40 otros idiomas.

Kutools para Excel cuenta con más de 300 funciones, asegurando que lo que necesitas esté a solo un clic de distancia...

Office Tab - Habilita Lectura y Edición con Pestañas en Microsoft Office (incluye Excel)

  • ¡Un segundo para cambiar entre docenas de documentos abiertos!
  • Reduce cientos de clics del ratón cada día, di adiós al síndrome del túnel carpiano.
  • Incrementa tu productividad en un 50% al visualizar y editar múltiples documentos.
  • Trae pestañas eficientes a Office (incluye Excel), tal como Chrome, Edge y Firefox.