Note: The other languages of the website are Google-translated. Back to English

Octetos separados de la dirección IP en Excel

¿Alguna vez ha intentado dividir las direcciones IP en columnas separadas en la hoja de cálculo de Excel? Tal vez la función Texto a columna pueda ayudarlo a resolver este trabajo rápidamente, pero, en este artículo, hablaré sobre algunas fórmulas para lograr esta tarea en Excel.


Dividir octetos de direcciones IP en columnas separadas en Excel

Normalmente, en Excel, las funciones LEFT, MID, LEN y FIND pueden ayudarlo a extraer cada octeto de la dirección IP en diferentes columnas. Siga los siguientes pasos:

Divida el primer octeto de las direcciones IP:

Para extraer el primer octeto de la dirección IP, aplique la siguiente fórmula en una celda en blanco:

=LEFT(A2,FIND(".",A2)-1)

Y luego, arrastre el controlador de relleno hacia las celdas a las que desea aplicar esta fórmula, y se extrajo todo el primer octeto de las direcciones IP, vea la captura de pantalla:

Explicación de la fórmula:

FIND (".", A2) -1: Esta función ENCONTRAR devuelve la posición del primer punto de la celda A2, resta 1 significa excluir el punto en sí, obtendrá el resultado 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):La función IZQUIERDA se usa para extraer 2 caracteres del lado izquierdo de la cadena en la celda A2.


Divida el segundo octeto de las direcciones IP:

Para obtener el segundo octeto de las direcciones IP, copie o ingrese la siguiente fórmula en una celda en blanco:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Luego, arrastre el controlador de relleno hacia las celdas para completar esta fórmula, y obtendrá el resultado que necesite, vea la captura de pantalla:

Explicación de la fórmula:

1. BUSCAR (".", A2) +1: Esta función ENCONTRAR devuelve la posición del primer punto de la celda A2, agrega 1 significa a la extracción del siguiente carácter, obtendrá el resultado el número 4. Esta parte de la fórmula se reconoce como el argumento núm_inicio de la función MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Esta parte se reconoce como el argumento num_chars dentro de la función MID.

  • ENCONTRAR (".", A2, ENCONTRAR (".", A2) +1) = ENCONTRAR (".", A2,4): Esta función BUSCAR devolverá la posición del segundo punto. Y obtendrás el número 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Reste la posición del primer punto de la posición del segundo punto, y luego reste 1 del resultado significa eliminar un punto inicial. Y el resultado es 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Finalmente, esta función MID se usa para extraer 2 caracteres que comienzan en el cuarto carácter de la celda A2.


Divida el tercer octeto de las direcciones IP:

Para extraer el tercer octeto de las direcciones IP, las funciones MID y FIND también pueden hacerle un favor, ingrese o copie la siguiente fórmula en una celda en blanco:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Luego, arrastre el controlador de relleno hacia abajo para obtener los resultados que necesite, y solo se dividió el tercer octeto de las direcciones IP, vea la captura de pantalla:

Explicación de la fórmula:

1. FIND(".",A2,FIND(".",A2)+1)+1: Esta función FIND anidada se usa para obtener la posición del segundo punto en la celda A2, agregando 1 significa a la extracción del siguiente carácter, y obtendrá el número 7. Esta parte se reconoce como el argumento start_num de la función MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Esta parte de la fórmula se reconoce como el argumento num_chars de la función MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Esta función ENCONTRAR anidada se usa para obtener la posición del tercer punto en la celda A2, devuelve el número 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Reste la posición del segundo punto de la posición del tercer punto, y el resultado es 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Esta función MID obtendrá 1 carácter que comienza en el séptimo carácter de la celda A2.


Divida el cuarto octeto de las direcciones IP:

La siguiente fórmula puede ayudar a extraer el último octeto de la dirección IP, copie o ingrese la fórmula en una celda en blanco:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

Y luego, arrastre el controlador de relleno para completar esta fórmula a otras celdas que necesita, obtendrá el resultado como se muestra a continuación:

Explicación de la fórmula:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Esta función FIND anidada se usa para obtener la posición del tercer punto en la celda A2, agregando 1 significa a la extracción del siguiente carácter, y obtendrá el número 9. Esta parte se reconoce como el argumento start_num de la función MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • LEN (A2): La función LEN devuelve el número total de caracteres en la celda A2. Obtendrá el número 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: La longitud total de la celda A2 resta la posición del tercer punto para obtener el número del carácter restante. Esto obtendrá el número 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): Por fin, esta función MID obtendrá 3 caracteres que comienzan en el noveno carácter de la celda A2.


Funciones relativas utilizadas:

  • LEFT:
  • La función IZQUIERDA extrae el número dado de caracteres del lado izquierdo de una cadena proporcionada.
  • MID:
  • La función MID se utiliza para buscar y devolver un número específico de caracteres desde el medio de una cadena de texto dada.
  • FIND:
  • La función ENCONTRAR se usa para encontrar una cadena dentro de otra cadena y devuelve la posición inicial de la cadena dentro de otra.
  • LEN:
  • La función LEN devuelve el número de caracteres en una cadena de texto.

Más artículos:

  • Dividir texto y números en una celda en Excel
  • Suponiendo que los datos de una celda se mezclan con texto y números, ¿cómo puede dividirlos en celdas de columna separadas? Este tutorial le mostrará los pasos detallados para aprender a usar fórmulas.

Las mejores herramientas de productividad de oficina

Kutools para Excel: te ayuda a destacar entre la multitud

¿Le gustaría completar su trabajo diario de forma rápida y perfecta? Kutools for Excel ofrece 300 potentes funciones avanzadas (combinar libros de trabajo, sumar por color, dividir contenido de celdas, convertir fecha, etc.) y ahorrarle un 80% de tiempo.

  • Diseñado para 1500 escenarios de trabajo, te ayuda a resolver el 80% de problemas de Excel.
  • Reduzca miles de clics de teclado y mouse todos los días, alivie sus ojos y manos cansados.
  • Conviértete en un experto en Excel en 3 minutos. Ya no es necesario recordar fórmulas dolorosas y códigos VBA.
  • Prueba gratuita ilimitada de 30 días. Garantía de devolución de dinero de 60 días. Actualización y soporte gratuitos durante 2 años.
Cinta de Excel (con Kutools para Excel instalado)

Ficha Office: habilite la lectura y edición con pestañas en Microsoft Office (incluya Excel)

  • ¡Un segundo para cambiar entre docenas de documentos abiertos!
  • Reduzca cientos de clics del mouse para usted todos los días, diga adiós a la mano del mouse.
  • Aumenta su productividad en un 50% al ver y editar varios documentos.
  • Trae pestañas eficientes a Office (incluye Excel), al igual que Chrome, Firefox y el nuevo Internet Explorer.
Captura de pantalla de Excel (con la pestaña Office instalada)
Comentarios (1)
5 clasificado de 5 · 1 calificaciones
Este comentario fue minimizado por el moderador en el sitio
¡Esto funcionó muy bien, gracias por esta información!
5 clasificado de 5
No hay comentarios publicados aquí todavía
Deje sus comentarios
Publicar como invitado
×
Califica esta publicación:
0   Personajes
Ubicaciones sugeridas

Siganos

Copyright © 2009 - www.extendoffice.com. | Reservados todos los derechos. Energizado por ExtendOffice, | Mapa del Sitio
Microsoft y el logotipo de Office son marcas comerciales o marcas comerciales registradas de Microsoft Corporation en los Estados Unidos y / o en otros países.
Protegido por Sectigo SSL