Separar números de las unidades de medida
Este artículo explica cómo usar una fórmula para separar los números de las unidades de medida.
¿Cómo separar números de las unidades de medida?
Las siguientes tres fórmulas pueden ayudarte a dividir los números de las unidades de medida para que estén en dos columnas separadas.
Primero, localiza el primer carácter de la unidad
1. Selecciona una celda en blanco para mostrar el resultado.
2. Introduce o copia la siguiente fórmula en ella y presiona la tecla Enter. Selecciona la celda del resultado y luego arrastra el controlador de relleno para aplicar la fórmula a otras celdas según sea necesario.
=MAX(ESNUMERO(VALOR(EXTRAE(B5,{1,2,3,4,5,6,7,8,9},1)))*{1,2,3,4,5,6,7,8,9})+1
En segundo lugar, separa los números de las unidades
1. Selecciona una celda en blanco para mostrar el resultado.
2. Introduce la siguiente fórmula en ella y presiona la tecla Enter. Selecciona la celda del resultado y luego arrastra el controlador de relleno para aplicar la fórmula a otras celdas según sea necesario.
=VALOR(IZQUIERDA(B5,C5-1))
Finalmente, obtén las unidades
1. Selecciona una celda en blanco para mostrar el resultado.
2. Introduce la siguiente fórmula en ella y presiona la tecla Enter. Selecciona la celda del resultado y luego arrastra el controlador de relleno para aplicar la fórmula a otras celdas según sea necesario.
=ESPACIOS(DERECHA(B5,LARGO(B5)-C5+1))
¿Cómo funcionan estas fórmulas?
=MAX(ESNUMERO(VALOR(EXTRAE(B5,{1,2,3,4,5,6,7,8,9},1)))*{1,2,3,4,5,6,7,8,9})+1
- 1. EXTRAE(B5,{1,2,3,4,5,6,7,8,9},1): La función EXTRAE extrae los primeros 9 valores en B5 y devuelve el resultado como una matriz: {"1","m","q","","","","","",""};
- VALOR({"1","m","q","","","","","",""}): La función VALOR convierte los números en formato de texto a números reales y devuelve el resultado como {1,#¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!};
- 2. ESNUMERO({1,#¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!, #¡VALOR!}) *{1,2,3,4,5,6,7,8,9}: La función ESNUMERO verifica si hay números o no en la matriz y devuelve {VERDADERO,FALSO, FALSO, FALSO, FALSO, FALSO, FALSO, FALSO, FALSO}. Luego, esta matriz multiplica otra matriz con 9 números y devuelve {1,0,0,0,0,0,0,0,0,};
- 3. MAX({1,0,0,0,0,0,0,0,0,})+1: Luego, la función MAX obtiene el valor más grande "1" en la matriz. Este valor más grande es la posición del último número en B5. Necesitamos sumar 1 para obtener la posición del primer carácter de la unidad. Aquí el resultado es 1+1=2.
=VALOR(IZQUIERDA(B5,C5-1)):
- La función IZQUIERDA extrae 1 (2-1=1) carácter comenzando desde el lado izquierdo de B5 y devuelve 1. Luego, la función VALOR convierte este número en formato de texto a un número real.
=ESPACIOS(DERECHA(B5,LARGO(B5)-C5+1))
- 1. LARGO(B5): La función LARGO calcula la longitud total del texto de B5. El resultado es 3;
- 2. ESPACIOS(DERECHA(B5,2)): La función DERECHA extrae dos caracteres comenzando desde el lado derecho de B5 y devuelve el resultado mg. Y la función ESPACIOS eliminará todos los espacios del resultado si hay espacio entre el número y la unidad.
Nota: La primera fórmula en este artículo solo funciona bien para números cuya longitud es igual o menor a 9 caracteres.
Funciones relacionadas
Función MAX de Excel
La función MAX de Excel devuelve el valor más grande en un conjunto de valores.
Función ESNUMERO de Excel
La función ESNUMERO de Excel comprueba si un valor es un número y devuelve VERDADERO o FALSO.
Función VALOR de Excel
La función VALOR de Excel ayuda a convertir una cadena de texto que representa un número (como número, fecha u hora) en un número.
Función EXTRAE de Excel
La función EXTRAE de Excel se utiliza para encontrar y devolver un número específico de caracteres del medio de una cadena de texto dada.
Función IZQUIERDA de Excel
La función IZQUIERDA extrae el número dado de caracteres del lado izquierdo de una cadena proporcionada.
Función ESPACIOS de Excel
La función ESPACIOS de Excel elimina todos los espacios adicionales de una cadena de texto y solo deja un espacio entre palabras.
Función DERECHA de Excel
La función DERECHA extrae un número específico de caracteres del lado derecho de la cadena de texto.
Fórmulas relacionadas
Dividir dimensiones en longitud, altura y ancho individuales
Este artículo explica cómo dividir las dimensiones en una celda en tres partes (dimensiones individuales que incluyen longitud, altura y ancho).
Dividir dimensiones en dos partes en Excel
Este artículo explica cómo usar una fórmula para dividir las dimensiones en una celda en dos partes sin unidades (longitud y ancho individuales).
Las Mejores Herramientas de Productividad para Office
Kutools para Excel - Te Ayuda a Sobresalir Entre la Multitud
Kutools para Excel Presume de Más de 300 Funciones, Asegurando Que Lo Que Necesitas Está a Solo Un Clic de Distancia...
Office Tab - Habilita Lectura y Edición con Pestañas en Microsoft Office (incluye Excel)
- ¡Un segundo para cambiar entre decenas de documentos abiertos!
- Reduce cientos de clics de ratón para ti todos los días, di adiós al síndrome del túnel carpiano.
- Aumenta tu productividad en un 50% al ver y editar múltiples documentos.
- Trae Pestañas Eficientes a Office (incluye Excel), Al Igual Que Chrome, Edge y Firefox.