KutoolsforOffice — Una solución, cinco potentes herramientas.Lograr más con menos esfuerzo.Oferta de marzo: 20 % de descuento

Sumar valores por número de semana o día de la semana en Excel

AutoraSiluvia Fecha de modificación

Este tutorial le guía paso a paso mediante fórmulas que le permitirán sumar valores en un rango determinado según el número de semana o el día de la semana especificado en Excel.

¿Cómo sumar valores por Número de semana en Excel?
¿Cómo sumar valores por día de la semana en Excel?

¿Cómo sumar valores por número de semana en Excel?

Tal como se muestra en la siguiente captura de pantalla, ofrecemos dos fórmulas para sumar los valores de la columna *Importe* en función de las fechas correspondientes a una semana específica.

doc-sum-by-week-number-weekday-1

Fórmulas genéricas

=SUMIFS( value_range, helper_column_range, week_number)

=SUMPRODUCT(--(WEEKNUM(date_range+0,1)=week_number),value_range)

Argumentos

Rango_valores: El rango de valores que desea sumar en función del Número de semana;
Rango_columna_auxiliar: El rango de Número de semana extraídos de la fecha;
Número_semana: El Número de semana utilizado como criterio para sumar valores.

¿Cómo se utiliza esta fórmula?

Usar la fórmula SUMAR.SI.CONJUNTO y una columna auxiliar

Para utilizar la fórmula SUMAR.SI.CONJUNTO, primero debe aplicar la función NÚM.DE.SEMANA para crear una columna auxiliar que calcule el número de semana correspondiente a las fechas de la columna Fecha.

=WEEKNUM (serial_num, [return_type])

La función NÚM.DE.SEMANA devuelve el número de semana correspondiente a la fecha indicada dentro del año.

1. En este caso, selecciono una celda (F5) junto al primer valor de la columna Importe.

2. Introduzca la siguiente fórmula en ella y pulse la tecla Entrar para obtener el número de semana de la primera fecha. Seleccione la celda con el resultado y arrastre su controlador de autorrelleno hacia abajo para obtener los demás números de semana. Vea la captura de pantalla:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. Seleccione una celda para mostrar el importe total, introduzca la siguiente fórmula y pulse la tecla EntrarA continuación, seleccione la celda con el resultado y arrastre su controlador de autorrelleno hacia abajo para obtener los demás resultados.

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

Usar la fórmula SUMAPRODUCTO

No necesita crear una columna auxiliar al usar la fórmula SUMAPRODUCTO para resolver este problema.

1. Seleccione una celda vacía, introduzca la siguiente fórmula en ella y pulse la tecla Entrar.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Seleccione la celda con el resultado y arrastre su controlador de autorrelleno hacia abajo para obtener los demás resultados según sus necesidades.

doc-sum-by-week-number-weekday-4

Explicación de la fórmula

=SUMAR.SI.CONJUNTO($E$5:$E$14;$F$5:$F$14;H6)

Tras calcular el Número de semana con la función NÚM.DE.SEMANA, la función SUMAR.SI.CONJUNTO suma los valores del rango E5:E14 si los Número de semana de la columna auxiliar F5:F14 coinciden con la semana indicada en H6.

=SUMAPRODUCTO(--(NÚM.DE.SEMANA($C$5:$C$14+0;1)=G6);$E$5:$E$14)

NÚM.DE.SEMANA($C$5:$C$14+0,1): La función NÚM.DE.SEMANA calcula el Número de semana de cada fecha del rango C5:C14 y devuelve una matriz como esta: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: Aquí se compara cada Número de semana de la matriz con el Número de semana indicado en G6 y se devuelve una nueva matriz: {VERDADERO;VERDADERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO};
--{VERDADERO;VERDADERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}: Estos dos signos menos convierten los valores «VERDADERO» y «FALSO» en 1 y 0. Aquí obtendrá una nueva matriz: {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: Cada par de elementos de las matrices se multiplica entre sí y devuelve {1428;2010;0;0;0;0;0;0;0;0};
SUMAPRODUCTO({1428;2010;0;0;0;0;0;0;0;0}): La función SUMAPRODUCTO suma todos los números de la matriz y devuelve el resultado final 1428+2010=3438.

¿Cómo sumar valores según el día de la semana en Excel?

Tal como se muestra en la siguiente captura de pantalla, para sumar los valores de la columna *Importe* correspondientes a un día de la semana específico en Excel, puede utilizar la función SUMAPRODUCTO combinada con la función DIA.SEML.

En este caso, dado que debemos sumar el importe total para cada día de la semana, antes de aplicar la fórmula creamos una columna auxiliar con los números 1 a 7 para indicar de forma independiente de lunes a domingo.

doc-sum-by-week-number-weekday-6

Fórmula genérica

=SUMPRODUCT((WEEKDAY(date_range,2)=weekday_number)*value_range)

Argumentos

Rango_fechas: El Rango de fechas en el que desea evaluar los días de la semana indicados;
Rango_valores: El rango de valores que desea sumar en función del día de la semana;
2: El número 2 representa los números del 1 (lunes) al 7 (domingo);
Número_día_semana: El número de día de la semana utilizado como criterio para sumar valores. Puede ser Una referencia de celda o un número del 1 al 7.

¿Cómo se utiliza esta fórmula?

1. Seleccione una celda junto a la que contiene el número 1. En este caso, he seleccionado I6.

2. Copie o introduzca la siguiente fórmula y pulse la tecla Entrar. Seleccione la celda con el resultado y arrastre su controlador de autorrelleno hacia abajo para obtener los resultados correspondientes al resto de los días de la semana.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Nota: Si solo necesita sumar valores en función de un día de la semana específico, como el viernes, puede introducir directamente el número 5 en la fórmula, tal como se muestra a continuación.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=5)*$E$5:$E$14)

Explicación de la fórmula

=SUMAPRODUCTO((DIA.SEML($C$5:$C$14;2)=H6)*$E$5:$E$14)

DIA.SEML($C$5:$C$14,2): La función DIA.SEML devuelve números enteros del 1 al 7 para representar el Semana de lunes a domingo en el rango C5:C14: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: Aquí se comparan los Semana de la matriz con el número de día de la semana indicado en H6 y se devuelve una nueva matriz: {FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO};
{FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO}*$E$5:$E$14: Aquí los valores VERDADERO y FALSO se convierten en 1 y 0 y, a continuación, se multiplican por los valores de E5:E14 para devolver la matriz: {0;0;2288;0;0;0;1325;0;0;0};
SUMAPRODUCTO{0;0;2288;0;0;0;1325;0;0;0}: La función SUMAPRODUCTO suma todos los números de la matriz y devuelve el resultado final 2288+1325=3613.

Funciones relacionadas

Función WEEKNUM de Excel
La función WEEKNUM de Excel devuelve el número de semana correspondiente a la fecha indicada en un año, contando las semanas desde el 1 de enero.

Función SUMPRODUCT de Excel
La función SUMPRODUCT de Excel permite multiplicar dos o más columnas o matrices entre sí y, a continuación, sumar los productos resultantes.

Función WEEKDAY de Excel
La función WEEKDAY de Excel devuelve un número entero comprendido entre 1 y 7 para representar el día de la semana de una fecha dada en Excel.

Fórmulas relacionadas

Sumar valores por mes (con o sin año)
Este tutorial muestra detalladamente dos fórmulas para ayudarte a sumar valores correspondientes a un mes y año concretos, o a sumar valores de un mes determinado ignorando el año en Excel.

Suma valores según la semana de una fecha dada
Este tutorial te muestra cómo sumar valores en función de la semana a la que pertenece una fecha determinada.

Sumar cada n filas o columnas en un rango
Este tutorial presenta dos fórmulas, basadas en las funciones SUMA y DESREF, para sumar cada n filas o columnas dentro de un rango limitado en Excel.

Sumar cada n-ésima fila o columna en un rango
Este tutorial le mostrará cómo crear una fórmula con las funciones SUMAPRODUCTO, RESIDUO y COLUMNA para sumar cada n-ésima fila o columna dentro de un rango en Excel.

Las mejores herramientas de productividad para Office

Kutools para Excel - Le ayuda a destacar entre la multitud

🤖KUTOOLS AI Asistente: Revolucione Análisis de datos basándose en:Ejecución inteligente   |  Generar código|  Crear fórmulas personalizadas  |  Analizar datos y generar gráficos|  Invocar Funciones mejoradas…
Funciones populares:Buscar, resaltar o Marcar duplicados  |  Eliminar filas en blanco  |  Combinar Columnas o celdas sin perder datos  |  Redondeo sin usar fórmulas...
Super VLookup:Múltiples criterios  |  Múltiples valores  |  En varias hojas  |  Coincidencia difusa...
Avanzado: lista desplegable...:Lista desplegable sencilla  |  Lista desplegable dependiente  |  Lista desplegable de selección múltiple
Gestor de columnas:Añadir un número específico de columnas  |  Mover columnas  |  Alternar la visibilidad de columnas ocultas  |Comparar columnas para Seleccionar celdas iguales/diferentes...
Funciones destacadas:Cuadrícula de enfoque  |  Vista de diseño  |  Barra de fórmulas mejorada  |  Gestor de libros y hojas|Biblioteca de recursos(Texto automático)|  Selector de Fecha  |  Combinar Hojas de Cálculo  |  Cifrar/Descifrar celdas  |  Enviar correos electrónicos por lista  |  Super Filtro  |  Filtro especial(Filtrar celdas con fuente en negrita/cursiva/tachado...) ...
Principales conjuntos de herramientas 15:12 Herramientasde texto(Agregar texto,Eliminar caracteres específicos...)|  50+Tiposde gráfico(Diagrama de Gantt...)|  40+ Fórmulas prácticas(Calcular la edad basada en la fecha de nacimiento...)|  19 Herramientasde inserción(Insertar Código QR,Insertar imagen desde ruta...)|  12 Herramientasde conversión(Convertir a palabras,Conversión de moneda...)|  7 Combinar y dividirHerramientas(Combinar filas avanzado,Dividir celdas de Excel...)|... y más
Use Kutools en su idioma preferido: compatible con inglés, español, alemán, francés, chino y 40+ más idiomas.¡

Kutools para Excel Cuenta con más de 300 funciones,asegurando que lo que necesita esté siempre a un clic...

Office Tab - Habilita la lectura y edición con pestañas en Microsoft Office (incluido Excel)

  • ¡Alterne entre decenas de documentos abiertos en un segundo!
  • Reduzca cientos de clics del ratón cada día y despídase del síndrome del ratón.
  • Aumente su productividad en un 50 % al ver y editar varios documentos simultáneamente.
  • Lleva una navegación eficiente con pestañas a Office (incluido Excel), al estilo de Chrome, Edge y Firefox.