Skip to main content

Sumar si las celdas contienen o son iguales a x o y en Excel

Author: Siluvia Last Modified: 2025-08-06

Para sumar las celdas si contienen o son iguales a un valor u otro, este tutorial proporciona dos fórmulas detalladas para ayudar a resolver los problemas.

¿Cómo sumar si las celdas contienen x o y en Excel?
¿Cómo sumar si las celdas son iguales a x o y en Excel?

¿Cómo sumar si las celdas contienen x o y en Excel?

Como se muestra en la captura de pantalla a continuación, para sumar las celdas en la columna D si las celdas en la columna C contienen “manzana” o “lichí”, puedes aplicar una fórmula basada en las funciones SUMAPRODUCTO, ESNUMERO y BUSCAR.

doc-sum-if-cells-contain-either-x-or-y-1

Fórmulas genéricas

=SUMAPRODUCTO(--((ESNUMERO(BUSCAR("criterio1",rango1)) + ESNUMERO(BUSCAR("criterio2",rango2)))>0),rango_suma)

Argumentos

Criterio_rango1: El rango de celdas que deseas evaluar con el criterio1;
Criterio_rango2: El rango de celdas que deseas evaluar con el criterio2;
Criterio1: El criterio utilizado para definir qué celdas en Criterio_rango1 se sumarán;
Criterio2: El criterio utilizado para definir qué celdas en Criterio_rango2 se sumarán.
Rango_suma: El rango de celdas a sumar;

¿Cómo usar esta fórmula?

Selecciona una celda en blanco, copia o introduce la siguiente fórmula y presiona la tecla Intro para obtener el resultado.

=SUMAPRODUCTO(--((ESNUMERO(BUSCAR(G4,C5:C12))+ESNUMERO(BUSCAR(G5,C5:C12)))>0),D5:D12)

doc-sum-if-cells-contain-either-x-or-y-2

Notas: En esta fórmula, G4 y G5 son las celdas que contienen las dos condiciones. Alternativamente, puedes escribir directamente los valores de texto reales entre comillas dobles.

=SUMAPRODUCTO(--((ESNUMERO(BUSCAR("manzana",C5:C12))+ESNUMERO(BUSCAR("lichí",C5:C12)))>0),D5:D12)

Explicación de la fórmula

=SUMAPRODUCTO(--((ESNUMERO(BUSCAR("manzana",C5:C12))+ESNUMERO(BUSCAR("lichí",C5:C12)))>0),D5:D12)

ESNUMERO(BUSCAR("manzana",C5:C12))
> BUSCAR("manzana",C5:C12): La función BUSCAR localiza la posición del primer carácter de “manzana” en cada celda del rango C5:C12 y devuelve una matriz como esta {#¡VALOR!;#¡VALOR!;1;9;1;#¡VALOR!;#¡VALOR!;18}. Los #¡VALOR! significan que “manzana” no se encuentra en la celda correspondiente;
> ESNUMERO({#¡VALOR!;#¡VALOR!;1;9;1;#¡VALOR!;#¡VALOR!;18}): Aquí la función ESNUMERO verifica si el valor referido en la matriz es numérico o no numérico. Si el parámetro de valor es numérico, devuelve “VERDADERO”; si no, devuelve “FALSO”. Luego obtendrás una nueva matriz {FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO;FALSO;FALSO;VERDADERO}.
ESNUMERO(BUSCAR("lichí",C5:C12)): La explicación de esta parte es la misma que la anterior. Aquí, la función ESNUMERO finalmente devuelve una matriz como esta {FALSO;FALSO;FALSO;VERDADERO;FALSO;FALSO;VERDADERO;VERDADERO};
{FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO;FALSO;FALSO;VERDADERO} + {FALSO;FALSO;FALSO;VERDADERO;FALSO;FALSO;VERDADERO;VERDADERO}: Luego sumamos estas matrices juntas, y la operación matemática convierte los valores VERDADERO y FALSO en 1s y 0s. Finalmente obtenemos una matriz numérica {0;0;1;2;1;0;1;2};
({0;0;1;2;1;0;1;2}) > 0: Cada número en la matriz se compara con el número 0 y devuelve una matriz VERDADERO y FALSO como esta {FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO;FALSO;VERDADERO;VERDADERO};
--({FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO;FALSO;VERDADERO;VERDADERO}): Estos dos signos menos convierten “VERDADERO” en 1 y “FALSO” en 0. Aquí obtendrás una nueva matriz como {0;0;1;1;1;0;1;1};
SUMAPRODUCTO({0;0;1;1;1;0;1;1},D5:D12) = SUMAPRODUCTO({0;0;1;1;1;0;1;1},{2000;1600;980;1200;600;900;150;300}): La función SUMAPRODUCTO multiplica los componentes correspondientes de las dos matrices y devuelve una matriz como {0;0;980;1200;600;0;150;300}, luego suma todos los resultados en la matriz y finalmente devuelve 3230.

¿Cómo sumar si las celdas son iguales a x o y en Excel?

En la sección anterior, introdujimos la fórmula para sumar las celdas si contienen un valor u otro. Esta sección demostrará cómo sumar dos funciones SUMAR.SI juntas para sumar las celdas si son iguales a x o y.

El ejemplo a continuación es para sumar ventas si el producto es igual a “manzana” o “lichí”.

doc-sum-if-cells-contain-either-x-or-y-3

Fórmula genérica

=SUMAR.SI(rango_criterios1,"criterio1",rango_suma)+SUMAR.SI(rango_criterios2,"criterio2",rango_suma)

Argumentos

Rango_criterios1: El rango de celdas que deseas evaluar con el criterio1;
Rango_criterios2: El rango de celdas que deseas evaluar con el criterio2;
Criterio1: El criterio que define qué celdas en Rango_criterios1 se sumarán.
Criterio2: El criterio que define qué celdas en Rango_criterios2 se sumarán.
Rango_suma: El rango de celdas a sumar;

¿Cómo usar esta fórmula?

Selecciona una celda en blanco, copia o introduce la siguiente fórmula en ella y presiona la tecla Intro para obtener el resultado.

=SUMAR.SI(C5:C12,G4,D5:D12)+SUMAR.SI(C5:C12,G5,D5:D12)

doc-sum-if-cells-contain-either-x-or-y-4

Nota: Esta fórmula hace referencia a dos celdas G4 y G5 que contienen las dos condiciones. Puedes escribir directamente los valores de texto entre comillas dobles como criterios en la fórmula.

=SUMAR.SI(C5:C12,"manzana",D5:D12)+SUMAR.SI(C5:C12,"lichí",D5:D12)

Explicación de esta fórmula

=SUMAR.SI(C5:C12,"manzana",D5:D12)+SUMAR.SI(C5:C12,"lichí",D5:D12)

La primera función SUMAR.SI suma las ventas de “manzana”, y la segunda función SUMAR.SI suma las ventas de “lichí”. Estos dos resultados luego se suman para obtener las ventas totales.

Funciones relacionadas

Función SUMAPRODUCTO de Excel
La función SUMAPRODUCTO de Excel puede usarse para multiplicar dos o más columnas o matrices juntas, y luego obtener la suma de productos.

Función ESNUMERO de Excel
La función ESNUMERO de Excel devuelve VERDADERO cuando una celda contiene un número, y FALSO si no.

Función BUSCAR de Excel
La función BUSCAR de Excel puede ayudarte a encontrar la posición de un carácter o subcadena específica desde la cadena de texto dada.

Función SUMAR.SI.CONJUNTO de Excel
La función SUMAR.SI de Excel puede ayudar a sumar valores de celdas basados en múltiples criterios.

Fórmulas relacionadas

Sumar si las celdas contienen un asterisco
Para sumar celdas que contienen un asterisco que se considera un carácter literal y no un comodín, este tutorial explica una fórmula basada en la función SUMAR.SI y la tilde (~).

Sumar si las celdas contienen tanto x como y
Este tutorial paso a paso demuestra cómo sumar un rango de celdas si las celdas correspondientes contienen tanto x como y utilizando la función SUMAR.SI.CONJUNTO.

Sumar si la fecha está entre dos fechas
Este tutorial demuestra cómo sumar valores dentro de un rango de fechas específico en Excel con una fórmula basada en la función SUMAR.SI.CONJUNTO.

Sumar si las celdas son iguales o no iguales a un cierto valor
Este tutorial paso a paso explica dos fórmulas para sumar un rango de celdas que sean iguales o no iguales a un cierto valor basado en la función SUMAR.SI.

Las Mejores Herramientas de Productividad para Office

Kutools para Excel - Te Ayuda a Sobresalir de la Multitud

🤖 Asistente de KUTOOLS AI: Revoluciona el análisis de datos basado en: Ejecución Inteligente   |  Generar Código  |  Crear Fórmulas Personalizadas  |  Analizar Datos y Generar Gráficos  |  Invocar Funciones de Kutools…
Funciones Populares: Buscar, Resaltar o Identificar Duplicados  |  Eliminar Filas en Blanco  |  Combinar Columnas o Celdas sin Perder Datos  |  Redondear sin Fórmula ...
Super VLookup: Criterios Múltiples  |  Valores Múltiples  |  A través de Hojas Múltiples  |  Coincidencia Difusa...
Lista Desplegable Avanzada: Lista Desplegable Fácil  |  Lista Desplegable Dependiente  |  Lista Desplegable con Selección Múltiple...
Administrador de Columnas: Agregar un Número Específico de Columnas  |  Mover Columnas  |  Cambiar Estado de Visibilidad de Columnas Ocultas  |  Comparar Columnas para Seleccionar Celdas Iguales y Diferentes ...
Funciones Destacadas: Cuadrícula de Enfoque  |  Vista de Diseño  |  Barra de Fórmulas Mejorada  |  Administrador de Libros y Hojas de Trabajo | Biblioteca de Recursos (AutoTexto)  |  Selector de Fechas  |  Combinar Hojas de Trabajo  |  Encriptar/Descifrar Celdas  |  Enviar Correos Electrónicos por Lista  |  Super Filtro  |  Filtro Especial (filtrar negrita/cursiva/tachado...) ...
Los 15 Mejores Conjuntos de Herramientas:  12 Herramientas de Texto (Agregar Texto, Eliminar Caracteres ...)  |  +50 Tipos de Gráficos (Diagrama de Gantt ...)  |  +40 Fórmulas Prácticas (Calcular edad basada en la fecha de nacimiento ...)  |  19 Herramientas de Inserción (Insertar código QR, Insertar imagen desde Ruta ...)  |  12 Herramientas de Conversión (Convertir a palabras, Conversión de moneda ...)  |  7 Herramientas de Combinación y División (Combinar Filas Avanzado, Dividir celdas de Excel ...)  |  ... y más
Usa Kutools en tu idioma preferido – compatible con inglés, español, alemán, francés, chino y más de 40 otros idiomas.

Kutools para Excel cuenta con más de 300 funciones, asegurando que lo que necesitas esté a solo un clic de distancia...

Office Tab - Habilita Lectura y Edición con Pestañas en Microsoft Office (incluye Excel)

  • ¡Un segundo para cambiar entre docenas de documentos abiertos!
  • Reduce cientos de clics del ratón cada día, di adiós al síndrome del túnel carpiano.
  • Incrementa tu productividad en un 50% al visualizar y editar múltiples documentos.
  • Trae pestañas eficientes a Office (incluye Excel), tal como Chrome, Edge y Firefox.