¿Cómo clasificar los correos electrónicos por mes en Outlook?

Autor: Xiaoyang Última modificación: 2022-10-19

Si hay muchos correos electrónicos en su Bandeja de entrada, para que el buzón se vea limpio y bien organizado, puede almacenarlos o archivarlos en diferentes carpetas según el mes específico de la hora de recepción de los correos electrónicos, como se muestra a continuación. Normalmente, puede crear las carpetas manualmente y luego moverlas una por una. Obviamente, este enfoque requerirá mucho tiempo y será problemático. En este artículo, hablaré sobre un código VBA para resolver esta tarea de manera rápida y sencilla.

Clasifique los correos electrónicos según el mes con código VBA

Para mover los correos electrónicos a diferentes carpetas según el mes, aplique el siguiente código VBA:

1. Haga clic para seleccionar el Buzón carpeta en la que desea clasificar los correos electrónicos.

2. Mantenga pulsado el ALT + F11 teclas para abrir el Microsoft Visual Basic para aplicaciones ventana.

3. Hacer clic en recuadro > Móduloy pegue el siguiente código en la ventana del módulo.

Código VBA: clasifique los correos electrónicos según el mes

Sub ClassifyEmailsbyMonth()
'Updateby ExtendOffice
Dim xCurFolder As Folder
Dim xMoveFolder As Folder
Dim xMail As MailItem
Dim I As Long
Dim xYear As String, xMonth As String
On Error Resume Next
Set xCurFolder = Application.ActiveExplorer.CurrentFolder
For I = xCurFolder.Items.Count To 1 Step -1
  DoEvents
  If xCurFolder.Items.Item(I).Class = olMail Then
    Set xMail = xCurFolder.Items.Item(I)
    xYear = Year(xMail.ReceivedTime)
    xMonth = Month(xMail.ReceivedTime)
    Set xMoveFolder = Nothing
    Set xMoveFolder = xCurFolder.Folders(xYear & "." & xMonth)
    If xMoveFolder Is Nothing Then
      Set xMoveFolder = xCurFolder.Folders.Add(xYear & "." & xMonth)
    End If
    xMail.Move xMoveFolder
  End If
Next
Set xMoveFolder = Nothing
Set xCurFolder = Nothing
End Sub

4. Entonces presione F5 para ejecutar este código, y todos los correos electrónicos en la carpeta Bandeja de entrada seleccionada se clasifican por mes específico del tiempo de recepción de los correos electrónicos, vea la captura de pantalla: