Divida un documento de Word en varios archivos por Título 1 (guía paso a paso)

Al trabajar con documentos extensos de Word —como informes, libros de texto, manuales o documentos de proyecto—, es posible que necesite dividir el archivo en partes más pequeñas, por ejemplo, un capítulo por archivo. Si su documento ya utiliza el estilo Título 1 para los títulos principales de sección, dividirlo será mucho más sencillo. A continuación, le ofrecemos una guía completa para hacerlo de forma eficiente.

• Prepare su documento de Word
• Método 1: Dividir un documento de Word por encabezado 1 con la función Esquema
• Método 2: Dividir un documento de Word por encabezado 1 con código VBA
• Método 3: Dividir un documento de Word por encabezado 1 con Kutools para Word
• Conclusión

Prepare su documento de Word

Antes de aplicar cualquier método, asegúrese de que su documento esté correctamente estructurado. Word solo reconocerá los puntos de división si se aplica adecuadamente el estilo Título 1.

Aplique estilos:

Aplique los estilos de título de forma coherente: use el estilo Título 1 para los títulos de nivel 1, Título 2 para los de nivel 2 y así sucesivamente.

Seleccione su título → Vaya a la pestaña Inicio → Haga clic en «Título 1» en la galería de estilos.

Haga una copia de seguridad de su archivo:

Guarde siempre una copia de su documento original antes de dividirlo, ya que algunos métodos —como la vista Esquema— pueden resultar difíciles de deshacer.

Método 1: Divida un documento de Word por Título 1 con la función Esquema

De hecho, la vista Esquema integrada en Word facilita enormemente esta tarea: detecta automáticamente las secciones con estilo Título 1, permitiéndole organizar la estructura de su documento y exportar cada capítulo como un archivo independiente, sin necesidad de complementos ni pasos complicados.

1. Abra el documento de Word, vaya a la pestaña Vistay haga clic en Esquema, consulte la captura de pantalla:
   
2. En la pestaña Esquema que aparece, establezca el menú desplegable Mostrar nivel en Nivel 1. Así se contraerá todo excepto los títulos de nivel 1.
   
3. A continuación, pulse Ctrl + A para seleccionar todo el texto. Luego, haga clic en Mostrar documento en el grupo Documento maestro.
   
4. Siga haciendo clic en el botón Crear. Word colocará ahora cada sección dentro de un recuadro delgado.
   
5. Vaya a Archivo > Guardar como. Elija una carpeta nueva. Word generará automáticamente archivos separados .docx para cada Título 1, utilizando el texto del título como nombre del archivo. Además, creará un documento de índice independiente con hipervínculos a todos los archivos divididos, permitiéndole abrir cualquier documento con un solo clic.
   

Método 2: Divida un documento de Word por Título 1 con código VBA

Si tiene un documento muy largo, el método de Esquema puede provocar ocasionalmente errores de formato. Usar un script VBA resulta mucho más limpio y rápido.

1. Pulse Alt + F11 para abrir la ventana de Visual Basic para Aplicaciones.
2. Haga clic en Insertar>Módulo. Copie y pegue el siguiente código en el módulo en blanco:
   

   Sub SplitDocByHeading1()
       Dim StrTmplt As String
       Dim StrPath As String
       Dim StrFlNm As String
       Dim Rng As Range
       Dim i As Long
       Dim Doc As Document
       Dim fDialog As FileDialog
       Const StrNoChr As String = """*./\:?|"
       Application.ScreenUpdating = False
       Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
       With fDialog
           .Title = "Select a folder to save the split documents"
           .AllowMultiSelect = False
           If .Show <> -1 Then
               MsgBox "Operation cancelled.", vbInformation, "Split by Heading 1"
               Application.ScreenUpdating = True
               Exit Sub
           End If
           StrPath = .SelectedItems(1)
       End With
       If Right(StrPath, 1) <> "\" Then
           StrPath = StrPath & "\"
       End If
       With ActiveDocument
           StrTmplt = .AttachedTemplate.FullName
           With .Range
               With .Find
                   .ClearFormatting
                   .Replacement.ClearFormatting
                   .Text = ""
                   .Replacement.Text = ""
                   .Style = wdStyleHeading1
                   .Format = True
                   .Forward = True
                   .Wrap = wdFindStop
                   .Execute
               End With
               Do While .Find.Found
                   Set Rng = .Duplicate
                   StrFlNm = Split(Rng.Paragraphs(1).Range.Text, vbCr)(0)
                   For i = 1 To Len(StrNoChr)
                       StrFlNm = Replace(StrFlNm, Mid(StrNoChr, i, 1), "_")
                   Next i
                   StrFlNm = StrFlNm & ".docx"
                   Set Rng = Rng.GoTo(What:=wdGoToBookmark, Name:="\HeadingLevel")
                   Set Doc = Documents.Add(Template:=StrTmplt, Visible:=False)
                   With Doc
                       .Range.FormattedText = Rng.FormattedText
                       .SaveAs2 FileName:=StrPath & StrFlNm, _
                                FileFormat:=wdFormatXMLDocument, _
                                AddToRecentFiles:=False
                       .Close SaveChanges:=False
                   End With
                   .Collapse wdCollapseEnd
                   .Find.Execute
               Loop
           End With
       End With
       Set Doc = Nothing
       Set Rng = Nothing
       Application.ScreenUpdating = True
       MsgBox "Split completed successfully.", vbInformation, "Split by Heading 1"
   End Sub
   

3. Pulse F5 o haga clic en Ejecutar para ejecutar el código. Aparecerá una ventana solicitándole que seleccione una carpeta para guardar los archivos divididos. Consulte la captura de pantalla:
   
4. Haga clic en Aceptar y Word creará inmediatamente un archivo .docx para cada sección de Título 1. ¡Abra la carpeta y descubra el resultado!
   

Método 3: Divida un documento de Word por Título 1 con Kutools para Word

Aunque las herramientas integradas de Word y VBA permiten dividir documentos, exigen múltiples pasos, conocimientos técnicos y pueden incluso provocar la pérdida de formato. Kutools para Word ofrece una solución más limpia y eficiente: con su función *Dividir documento*, podrá separar un archivo por Título 1, salto de página, salto de sección, página, etc., ¡con un solo clic! Sin programación, sin trabajo manual y sin perder el formato. Kutools conserva estilos, diseño, imágenes, encabezados y pies de página, lo que lo convierte en la herramienta ideal para cualquier persona que trabaje con documentos extensos.

Después de descargar e instalar Kutools para Word, siga estos pasos:

1. Vaya a KUTOOLS PLUS > Dividir.
   
2. En el cuadro de diálogo Dividir documento, especifique las siguientes opciones:

   2,1 Elija Encabezado 1 en el menú desplegable Dividir por. (También puede seleccionar otras reglas de división, como salto de página, salto de sección, página, cada n páginas y más.)

   2,2 Especifique una carpeta para guardar los nuevos archivos divididos.

   2,3 Haga clic en el botón Aceptar.

   Consejo: También puede añadir un prefijo al título de cada archivo dividido escribiendo el texto deseado en el cuadro Prefijo del documento.

   
   

Resultado:
Kutools generará al instante varios archivos de Word basados en su estructura de Título 1, conservando íntegramente todos los encabezados y pies de página.

Conclusión

Artículos relacionados: