¿Cómo mover archivos específicos de una carpeta a otra en Excel?

Supongamos que tengo una carpeta grande que contiene varios tipos de archivos, como docx, jpg, xlsx, etc., tal como se muestra en la siguiente captura de pantalla. Ahora, quiero mover algunos tipos de archivos específicos de la carpeta a otra carpeta nueva sin tener que moverlos uno por uno manualmente. ¿Tienes alguna buena idea para resolver esta tarea en Excel?

Mover archivos específicos de una carpeta a otra con código VBA

Mover archivos específicos de una carpeta a otra con código VBA

Para mover todos los tipos específicos de archivos de una carpeta a otra tan rápido como desee, el siguiente código VBA puede ayudarle, por favor haga lo siguiente:

1. Mantenga presionadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en Insertar > Módulo, y pegue el siguiente código en la Ventana del Módulo.

Código VBA: Mover tipos específicos de archivos de una carpeta a otra:

Sub MoveFiles()
'Updateby Extendoffice
    Dim xFd As FileDialog
    Dim xTFile As String
    Dim xExtArr As Variant
    Dim xExt As Variant
    Dim xSPath As String
    Dim xDPath As String
    Dim xSFile As String
    Dim xCount As Long
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    xFd.Title = "Please select the original folder:"
    If xFd.Show = -1 Then
        xSPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xSPath, 1) <> "\" Then xSPath = xSPath + "\"
    xFd.Title = "Please select the destination folder:"
    If xFd.Show = -1 Then
        xDPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xDPath, 1) <> "\" Then xDPath = xDPath + "\"
    xExtArr = Array("*.xlsx*", "*.jpg")
    For Each xExt In xExtArr
        xTFile = Dir(xSPath & xExt)
        Do While xTFile <> ""
            xSFile = xSPath & xTFile
            FileCopy xSFile, xDPath & xTFile
            Kill xSFile
            xTFile = Dir
            xCount = xCount + 1
        Loop
    Next
    MsgBox "Total number of moved files is: " & xCount, vbInformation, "Kutools for Excel"
End Sub

Nota: En el código anterior, "*.xlsx*", "*.jpg" en el script: xExtArr = Array("*.xlsx*", "*.jpg") son los tipos de archivos que desea mover, puede cambiarlos a otros o agregar otros tipos de archivos según sea necesario.

3. Luego presione la tecla F5 para ejecutar este código, y aparecerá una ventana que le recordará seleccionar la carpeta original de donde desea mover los archivos, vea la captura de pantalla:

4. Luego haga clic en Aceptar, y aparecerá otra ventana, por favor elija la carpeta de destino a donde desea mover los archivos, vea la captura de pantalla:

5. Y luego haga clic en Aceptar, aparecerá un cuadro de mensaje que le recordará cuántos archivos se han movido, ciérrelo, y podrá ver que los archivos jpg, xlsx específicos se han movido a la carpeta especificada, vea la captura de pantalla: