¿Cómo contar el número de páginas en archivos Pdf usando Excel?

Si tienes varios archivos PDF en una carpeta y necesitas listar sus nombres de archivo junto con el recuento de páginas en Excel, puedes hacerlo fácilmente con una sencilla macro VBA. Este tutorial te guiará a través de los pasos para extraer y mostrar rápidamente los nombres de los archivos PDF y sus respectivos números de página en una hoja de cálculo de Excel.

Mostrar nombres de archivos PDF y números de página en Excel con VBA

Mostrar nombres de archivos PDF y números de página en Excel con VBA

El siguiente código VBA puede ayudarte a mostrar todos los nombres de archivos PDF y sus números de página en una hoja de cálculo. Por favor, sigue estos pasos:

1. Abre una hoja de cálculo donde quieras obtener los archivos Pdf y los números de página.

2. Mantén presionadas las teclas "ALT" + "F11", y se abrirá la ventana "Microsoft Visual Basic para Aplicaciones".

3. Haz clic en "Insertar" > "Módulo", y pega la siguiente macro en la ventana "Módulo".

Código VBA: Enumerar todos los nombres de archivos Pdf y números de página en la hoja de cálculo:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. Después de pegar el código, presiona la tecla "F5" para ejecutar este código, y aparecerá una ventana de "Examinar", por favor selecciona la carpeta que contiene los archivos Pdf que deseas listar y contar páginas, ver captura de pantalla:

5. Luego, haz clic en el botón "Aceptar", todos los nombres de archivos Pdf y números de página se enumerarán en la hoja de trabajo actual, ver captura de pantalla: