¿Cómo enviar solo una hoja de trabajo a través de Outlook desde Excel?

Si desea enviar por correo electrónico una sola hoja de trabajo de un libro en Excel a través de Outlook, puede enviar la hoja como archivo adjunto, como contenido del cuerpo o como archivo PDF. Pero, ¿hay formas más rápidas de manejar este problema en Excel?

Enviar una sola hoja de trabajo como cuerpo desde Excel con el comando Enviar al destinatario de correo

Enviar una sola hoja de trabajo como archivo adjunto desde Excel con código VBA

Enviar una sola hoja de trabajo como archivo PDF desde Excel con código VBA

Enviar una sola hoja de trabajo como cuerpo desde Excel con el comando Enviar al destinatario de correo

Excel nos permite enviar la hoja de trabajo activa como contenido del cuerpo utilizando el comando Enviar al destinatario de correo. Puede hacer lo siguiente:

Si utiliza Excel 2007, 2010 o 2013, primero debe agregar este comando Enviar al destinatario de correo a la Barra de herramientas de acceso rápido.

1. Haga clic en el icono Personalizar barra de herramientas de acceso rápido y elija Más comandos, vea la captura de pantalla:

2. Y en el cuadro de diálogo Opciones de Excel, elija Comandos no incluidos en la cinta en la lista desplegable Elegir comandos de, luego seleccione la opción Enviar al destinatario de correo y haga clic en el botón Agregar >> para añadir este comando, finalmente haga clic en Aceptar para guardar esta configuración. Ver captura de pantalla:

3. El comando Enviar al destinatario de correo se ha insertado en la Barra de herramientas de acceso rápido, ver captura de pantalla:

4. Luego haga clic en este botón de icono Enviar al destinatario de correo, y aparecerá un cuadro de diálogo emergente, en el cuadro de diálogo Correo electrónico, marque Enviar la hoja actual como cuerpo del mensaje y haga clic en Aceptar. Ver captura de pantalla:

5. Y se mostrará un cuadro de edición de correo electrónico sobre los datos de la hoja de trabajo, puede ingresar sus destinatarios, asunto e introducción en los cuadros de texto correspondientes. Ver captura de pantalla:

6. Luego haga clic en Enviar esta hoja para enviar esta hoja de trabajo activa como cuerpo del mensaje a su persona específica.

Descubre la Magia de Excel con Kutools AI

• Ejecución Inteligente: Realiza operaciones en celdas, analiza datos y crea gráficos, todo impulsado por comandos simples.
• Fórmulas Personalizadas: Genera fórmulas adaptadas para optimizar tus flujos de trabajo.
• Codificación VBA: Escribe e implementa código VBA sin esfuerzo.
• Interpretación de Fórmulas: Comprende fórmulas complejas con facilidad.
• Traducción de Texto: Supera las barreras del idioma dentro de tus hojas de cálculo.

Potencia tus capacidades de Excel con herramientas impulsadas por IA. ¡Descarga Ahora y experimenta una eficiencia como nunca antes!

Enviar una sola hoja de trabajo como archivo adjunto desde Excel con código VBA

Si desea enviar la hoja de trabajo activa como archivo adjunto, el siguiente código VBA puede ayudarle.

1. Active la hoja de trabajo que desea enviar.

2. Mantenga presionadas las teclas ALT + F11, y se abrirá la ventana Microsoft Visual Basic para Aplicaciones.

3. Haga clic en Insertar > Módulo, y pegue el siguiente código en la Ventana de Módulo.

Código VBA: enviar hoja de trabajo actual como archivo adjunto desde Excel

Sub SendWorkSheet()
'Update 20131209
Dim xFile As String
Dim xFormat As Long
Dim Wb As Workbook
Dim Wb2 As Workbook
Dim FilePath As String
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
On Error Resume Next
Application.ScreenUpdating = False
Set Wb = Application.ActiveWorkbook
ActiveSheet.Copy
Set Wb2 = Application.ActiveWorkbook
Select Case Wb.FileFormat
Case xlOpenXMLWorkbook:
    xFile = ".xlsx"
    xFormat = xlOpenXMLWorkbook
Case xlOpenXMLWorkbookMacroEnabled:
    If Wb2.HasVBProject Then
        xFile = ".xlsm"
        xFormat = xlOpenXMLWorkbookMacroEnabled
    Else
        xFile = ".xlsx"
        xFormat = xlOpenXMLWorkbook
    End If
Case Excel8:
    xFile = ".xls"
    xFormat = Excel8
Case xlExcel12:
    xFile = ".xlsb"
    xFormat = xlExcel12
End Select
FilePath = Environ$("temp") & "\"
FileName = Wb.Name & Format(Now, "dd-mmm-yy h-mm-ss")
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
Wb2.SaveAs FilePath & FileName & xFile, FileFormat:=xFormat
With OutlookMail
    .To = "skyyang@extendoffice.com"
    .CC = ""
    .BCC = ""
    .Subject = "kte features"
    .Body = "Please check and read this document."
    .Attachments.Add Wb2.FullName
    .Send
End With
Wb2.Close
Kill FilePath & FileName & xFile
Set OutlookMail = Nothing
Set OutlookApp = Nothing
Application.ScreenUpdating = True
End Sub

Nota: En el código anterior, puede cambiar la siguiente información según sus necesidades.

• .To = "skyyang@extendoffice.com"
• .CC = ""
• .BCC = ""
• .Subject = "kte features"
• .Body = "Por favor, revise y lea este documento."

4. Luego presione la tecla F5 para ejecutar este código, y aparecerá un cuadro de diálogo emergente, haga clic en Permitir cuando termine la barra de progreso, y luego la hoja de trabajo actual se habrá enviado a su destinatario como archivo adjunto.

Enviar una sola hoja de trabajo como archivo PDF desde Excel con código VBA

A veces, necesita enviar su informe de hoja de trabajo a otros pero no quiere que otros lo modifiquen. En este caso, puede enviar la hoja de trabajo como un archivo PDF desde Excel.

1. Active la hoja de trabajo que desea enviar.

2. Mantenga presionadas las teclas ALT + F11, y se abrirá la ventana Microsoft Visual Basic para Aplicaciones.

3. Haga clic en Insertar > Módulo, y pegue el siguiente código en la Ventana de Módulo.

Código VBA: enviar hoja de trabajo actual como archivo PDF desde Excel

Sub SendWorkSheetToPDF()
'Update 20131209
Dim Wb As Workbook
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
On Error Resume Next
Set Wb = Application.ActiveWorkbook
FileName = Wb.FullName
xIndex = VBA.InStrRev(FileName, ".")
If xIndex > 1 Then FileName = VBA.Left(FileName, xIndex - 1)
FileName = FileName & "_" + ActiveSheet.Name & ".pdf"
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:=FileName
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
With OutlookMail
    .To = "skyyang@extendoffice.com"
    .CC = ""
    .BCC = ""
    .Subject = "kte features"
    .Body = "Please check and read this document."
    .Attachments.Add FileName
    .Send
End With
Kill FileName
Set OutlookMail = Nothing
Set OutlookApp = Nothing
End Sub

Nota: En el código anterior, puede cambiar la siguiente información según sus necesidades.

• .To = "skyyang@extendoffice.com"
• .CC = ""
• .BCC = ""
• .Subject = "kte features"
• .Body = "Por favor, revise y lea este documento."

4. Luego presione la tecla F5, y aparecerá un cuadro de diálogo emergente, haga clic en Permitir después de que termine la barra de progreso, entonces la hoja de trabajo activa se habrá enviado a la persona específica como archivo PDF.

Notas:

1. Estos métodos solo están disponibles cuando usa Outlook como su programa de correo.

2. Después de enviar la hoja de trabajo actual, puede ir a su Outlook para asegurarse de que el correo electrónico se haya enviado correctamente.

Crear Lista de Correo y Enviar Correos Electrónicos

Las utilidades Crear Lista de Correo y Enviar Correos Electrónicos de Kutools para Excel pueden crear rápidamente una lista de correo en una hoja de trabajo, luego enviar el mismo asunto, mismos contenidos y mismos archivos adjuntos a múltiples direcciones de correo electrónico.

Ir a Descargar

Artículos relacionados:

¿Cómo enviar el libro actual a través de Outlook desde Excel?

¿Cómo enviar / enviar por correo electrónico un rango de celdas a través de Outlook desde Excel?