¿Cómo buscar y reemplazar el asunto de una cita en el calendario de Outlook?

Reemplazar el asunto de citas en el calendario de Outlook resulta especialmente útil cuando necesita sustituir varios asuntos por el mismo texto de forma masiva o eliminar la palabra «Copia» del campo de asunto tras importar datos en Outlook. Este artículo le ofrece código VBA para buscar y reemplazar múltiples asuntos de citas. Consulte más detalles a continuación.

Buscar y reemplazar el asunto de una cita con código VBA

---

Buscar y reemplazar el asunto de una cita con código VBA

En esta sección, puede buscar y reemplazar el asunto de una cita mediante el siguiente código VBA.

Buscar y reemplazar. En primer lugar, debe establecer el nivel de seguridad de macros en bajo en su Outlook.

1) En Outlook 2010 y 2013, haga clic en «Archivo» > «Opciones». En el cuadro de diálogo «Opciones de Outlook», seleccione «Centro de confianza» en el panel izquierdo y, a continuación, pulse el botón «Configuración del Centro de confianza».

En el cuadro de diálogo «Centro de confianza», haga clic en «Configuración de macros» en la barra izquierda, seleccione la opción «Habilitar todas las macros» en la sección «Configuración de macros» y, por último, haga clic en el botón «Aceptar». Vea la captura de pantalla:

2) En Outlook 2007, haga clic en «Herramientas» > «Centro de confianza». En el cuadro de diálogo «Centro de confianza», seleccione «Configuración de macros» en el panel izquierdo, active la opción «Sin comprobación de seguridad para macros» y haga clic en «Aceptar».

2. Pulse las teclas «Alt» + "F11" para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

3. En la ventana de «Microsoft Visual Basic para Aplicaciones», haga doble clic para expandir «Proyecto1» > «Objetos de Microsoft Outlook» > «ThisOutlookSession» y abrir así el editor de VBA. Vea la captura de pantalla:

4. Copie y pegue el siguiente código VBA en el editor de VBA y, a continuación, pulse la tecla F5 para ejecutarlo.

VBA: Buscar y reemplazar asunto de cita

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. Tras ejecutar el código, aparecerá un cuadro de diálogo de «Microsoft Outlook». Haga clic en el botón «Aceptar».

6. En el segundo cuadro de diálogo de «Microsoft Outlook», introduzca el texto que desea reemplazar y, a continuación, haga clic en «Aceptar».

7. En el tercer cuadro de diálogo de «Microsoft Outlook», introduzca el texto que desea usar como reemplazo y haga clic en «Aceptar».

Nota: Si solo desea eliminar todas las palabras «Copia» del asunto en el calendario especificado, deje este campo en blanco.

8. Haga clic en el botón «Aceptar» del cuadro de diálogo que aparece a continuación.

9. En el cuadro de diálogo «Seleccionar carpeta», elija su calendario bajo la cuenta de correo especificada y, a continuación, haga clic en «Aceptar». Vea la captura de pantalla:

10. A continuación, aparecerá un cuadro de diálogo confirmando que el reemplazo se ha completado correctamente. Haga clic en «Aceptar».

11. De este modo, todos los textos de los asuntos del calendario seleccionado se reemplazarán por el nuevo contenido.