¿Cómo exportar e imprimir la lista de todas las carpetas y subcarpetas de Outlook?

Generalmente, puede pulsar las teclas **Ctrl + 6** para ver la lista completa de carpetas en el panel de navegación de Outlook. Sin embargo, no es posible imprimir directamente dicha lista. Este artículo presenta dos scripts de VBA que le permiten exportar e imprimir la lista de todas las carpetas y sus subcarpetas en Outlook.

• Exporte e imprima la lista de todas las carpetas de Outlook y sus subcarpetas en Nuevo Email
• Exporte e imprima la lista de todas las carpetas de Outlook y sus subcarpetas en el Bloc de notas

---

Exporte e imprima la lista de todas las carpetas de Outlook y sus subcarpetas en Nuevo Email

Este método presenta un script de VBA que exporta la lista de todas las carpetas y subcarpetas de una cuenta de correo electrónico especificada a un nuevo mensaje en Outlook, para que pueda imprimir fácilmente el listado de carpetas.

1. Pulse «Alt» + «F11» para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en «Insertar» > «Módulo» y pegue el siguiente código VBA en la nueva ventana del módulo.

VBA: Exporte la lista de carpetas y subcarpetas en un Nuevo Email en Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Pulse "F5" para ejecutar el código VBA.

4. En el cuadro de diálogo emergente **Seleccionar carpeta**, elija la cuenta de correo cuya lista de carpetas desee imprimir y haga clic en **Aceptar**.

5. La lista de carpetas de la cuenta seleccionada se copiará en un nuevo correo electrónico, tal como se muestra a continuación. Haga clic en «Archivo» > «Imprimir» para imprimir la lista de carpetas.

6. Tras imprimir, cierre el nuevo correo electrónico sin guardar los cambios.

---

Exporte e imprima la lista de todas las carpetas de Outlook y sus subcarpetas en el Bloc de notas

Este método ofrece un script de VBA que exporta al Bloc de notas la lista completa de carpetas y subcarpetas de una cuenta de correo electrónico especificada en Outlook, permitiéndole imprimir fácilmente el listado.

1. Pulse «Alt» + "F11" para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en «Insertar» > «Módulo» y, a continuación, pegue el siguiente código VBA en la nueva ventana del módulo.

VBA: Exporte la lista de todas las carpetas y subcarpetas de Outlook desde Outlook al Bloc de notas

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Pulse "F5" para ejecutar el código VBA. En el cuadro de diálogo **Seleccionar carpeta** que aparece, elija la cuenta de correo cuya lista de carpetas desea exportar e imprimir y, a continuación, haga clic en **Aceptar**.

4. Aparecerá el cuadro de diálogo Árbol de carpetas de salida. Haga clic en «Sí» o en «No» según desee incluir la sangría del árbol.

Ahora se crea y guarda en el escritorio un Archivo de Texto denominado «Outlook-Carpetas», como se muestra a continuación:

5. Haga doble clic para abrir el nuevo archivo de texto y, a continuación, seleccione «Archivo» > «Imprimir» para imprimir la lista exportada de carpetas de Outlook.

Artículos relacionados

Mostrar u ocultar la vista de lista de carpetas en Outlook