¿Cómo convertir varias citas en tareas de forma rápida en Outlook?

En este artículo, te explico cómo convertir una cita o varias citas en tareas de forma rápida y sencilla en Outlook.

Convertir una cita en tarea mediante arrastrar y soltar

Convertir varias citas en tareas aplicando código VBA

---

Convertir una cita en tarea mediante arrastrar y soltar

Para convertir una cita en tarea, basta con arrastrarla a la carpeta de tareas. Siga estos pasos:

1. En la ventana «Calendario», seleccione el elemento de cita que desea convertir en tarea y arrástrelo al icono «Tareas» situado en la parte inferior de Navegación, tal como se muestra en la siguiente captura de pantalla:

2. A continuación, aparecerá una nueva ventana de «Tarea». Haga clic en «Guardar y cerrar» para guardar esta cita como tarea.

---

Convertir varias citas en tareas aplicando código VBA

Si tiene varias citas que desea convertir en tareas, el siguiente código VBA le será de gran ayuda. Siga estos sencillos pasos:

1. Mantenga pulsadas las teclas «Alt + F11» para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. Haga clic en «Insertar» > «Módulo» y copie y pegue el siguiente código en el módulo en blanco que se abre:

Código VBA: Convertir varias citas en tareas

Sub ConvertAppointmentsToTasks()
Dim xItemCollection As VBA.Collection
Dim xActiveWindow As Object
Dim xItem As Object
Dim xSelection As Outlook.Selection
Dim xTaskFolder As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xTaskItem As Outlook.TaskItem
On Error Resume Next
Set xItemCollection = New VBA.Collection
Set xActiveWindow = Outlook.Application.ActiveWindow
If TypeOf xActiveWindow Is Inspector Then
    Set xItem = xActiveWindow.CurrentItem
    If xItem.Class = olAppointment Then xItemCollection.Add xItem
Else
    Set xSelection = xActiveWindow.Selection
    If xSelection Is Nothing Then Exit Sub
    For Each xItem In xSelection
        If xItem.Class = olAppointment Then xItemCollection.Add xItem
    Next
End If
Set xTaskFolder = Application.Session.PickFolder
If xTaskFolder Is Nothing Then Exit Sub
For Each xAppointmentItem In xItemCollection
    Set xTaskItem = xTaskFolder.Items.Add(olTaskItem)
    With xTaskItem
        .StartDate = Format(xAppointmentItem.Start, "Short Date")
        .DueDate = Format(xAppointmentItem.End, "Short Date")
        .Subject = xAppointmentItem.Subject & " (From Appt)"
        .Categories = xAppointmentItem.Categories
        .Body = xAppointmentItem.Body
        .Save
        .Display
    End With
Next
End Sub

3. Seleccione las citas que desea convertir en tareas y, a continuación, haga clic en el botón «Ejecutar macro» para ejecutar este código.

4. Aparecerá un cuadro de diálogo «Seleccionar carpeta». Elija la carpeta «Tareas» en la que desee guardar los resultados convertidos.

5. Haga clic en el botón «Aceptar» y todas las citas seleccionadas se convertirán en tareas. A continuación, guarde y cierre la ventana de «Tarea» una por una.

6. Ahora puede dirigirse a la carpeta de «Tareas»; todas las citas seleccionadas se han guardado como tareas.