¿Cómo buscar y reemplazar texto en el asunto de mensajes o tareas en Outlook?

En Outlook, si tiene varios asuntos de mensajes o tareas que desea reemplazar por un texto específico, claro que puede modificarlos uno por uno, pero ¿conoce algún método rápido para hacerlo de forma masiva en Outlook?

Buscar y reemplazar el texto del asunto en varios mensajes mediante código VBA

Buscar y reemplazar el texto del asunto en varias tareas mediante código VBA

---

Buscar y reemplazar el texto del asunto en varios mensajes mediante código VBA

Para buscar un texto específico y reemplazarlo por otro en los asuntos de varios mensajes, el siguiente código VBA le será de gran ayuda. Siga estos sencillos pasos:

1. Seleccione los correos electrónicos cuyo texto del asunto desea buscar y reemplazar y, a continuación, pulse las teclas «ALT + F11» para abrir la ventana de «Microsoft Visual Basic para Aplicaciones».

2. A continuación, haga clic en «Insertar» > «Módulo» y copie y pegue el siguiente código en el módulo en blanco que se abre (véase la captura de pantalla):

Código VBA: Buscar y reemplazar el texto del asunto en varios mensajes:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Notas: En el código anterior, `xNewSubject = Replace(.Subject, «kte», «[[PH_8]]»)`; `«kte»` es el texto antiguo que desea buscar y `«Kutools para Excel»` es el texto nuevo por el que desea reemplazarlo. Modifíquelos según sus necesidades.

3. Pulse después la tecla "F5" para ejecutar este código, y el texto específico en los asuntos de los mensajes se reemplazará por el texto nuevo que haya indicado (véase la captura de pantalla):

---

Buscar y reemplazar el texto del asunto en varias tareas mediante código VBA

Si necesita buscar y reemplazar el texto del asunto en tareas, el siguiente código VBA también le será de gran ayuda.

1. Pulse las teclas «Alt + F11» para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. A continuación, haga clic en «Insertar» > «Módulo» y copie y pegue el siguiente código en el módulo en blanco que se abre (véase la captura de pantalla):

Código VBA: Buscar y reemplazar el texto del asunto en todas las tareas:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Pulse después la tecla "F5" para ejecutar este código; aparecerá un cuadro de diálogo en el que deberá introducir el texto que desea buscar en los asuntos de las tareas (véase la captura de pantalla):

4. Haga clic en «Aceptar» y aparecerá otro cuadro de diálogo; introduzca el texto nuevo por el que desea reemplazarlo (véase la captura de pantalla):

5. A continuación, haga clic en «Aceptar» y aparecerá un cuadro de diálogo indicándole cuántos asuntos se han modificado (véase la captura de pantalla):

6. Haga clic en «Aceptar» y el texto antiguo en los asuntos de las tareas se habrá reemplazado por el nuevo (véase la captura de pantalla):