¿Cómo responder habitualmente desde la carpeta Elementos enviados en Outlook?

Normalmente, al hacer clic en la función **Responder** desde la carpeta **Elementos enviados** para enviar un nuevo mensaje a los destinatarios originales, su propia dirección de correo electrónico aparece en el campo **Para**, como se muestra en la siguiente captura de pantalla. Esto puede resultar molesto si tiene que cambiarla manualmente cada vez. ¿Cómo puede configurar Outlook para que utilice la dirección del destinatario original en lugar de la suya?

Responder normalmente en la carpeta Elementos enviados desde Outlook con la función Responder a todos

Responder normalmente en la carpeta Elementos enviados desde Outlook con código VBA

---

Responder normalmente en la carpeta Elementos enviados desde Outlook con la función Responder a todos

En Outlook, la función Responder a todos puede ayudarle a resolver este problema. Siga estos pasos:

Cuando necesite responder al correo enviado para reenviarlo y conservar la dirección del destinatario original, haga clic en el botón Responder a todos, y la dirección del destinatario original aparecerá en el campo Para, tal como se muestra en la siguiente captura de pantalla:

---

Responder normalmente en la carpeta Elementos enviados desde Outlook con código VBA

A veces, es posible que olvide usar la función Responder a todos al contestar un mensaje enviado. Por eso, el siguiente código VBA le permitirá responder normalmente desde la carpeta Elementos enviados utilizando la función Responder. Siga estos pasos:

1. Mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. En la ventana de Microsoft Visual Basic para Aplicaciones, haga doble clic en ThisOutlookSession en el panel Project1 (VbaProject.OTM) para abrir el módulo y, a continuación, copie y pegue el siguiente código en el módulo en blanco.

Código VBA: Responder normalmente en la carpeta Elementos enviados desde Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. A continuación, guarde el código y reinicie Outlook para que surta efecto. Ahora, al hacer clic en Responder para reenviar un correo electrónico en la carpeta Elementos enviados, la dirección del destinatario original aparecerá en el campo Para, tal como necesita.