¿Cómo mantener la categoría al responder o reenviar un correo electrónico en Outlook?

Normalmente, cuando responde o reenvía un correo electrónico que ha categorizado, la categoría se elimina automáticamente del mensaje enviado. Si desea conservar la categoría en los correos salientes al responder o reenviar, este artículo le presentará un método para lograrlo.

Conservar la categoría al responder o reenviar un correo electrónico con código VBA

---

Conservar la categoría al responder o reenviar un correo electrónico con código VBA

1. Mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. En la ventana de Microsoft Visual Basic para Aplicaciones, haga doble clic en ThisOutlookSession del panel Project1 (VbaProject.OTM) para abrir el módulo y, a continuación, copie y pegue el siguiente código en el módulo en blanco.

Código VBA: Conservar la categoría al responder o reenviar un correo electrónico:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. A continuación, guarde y cierre esta ventana de código, y luego cierre y reinicie Outlook. Ahora, al responder o reenviar un correo electrónico con categoría, esta se conservará en el mensaje saliente en Elementos enviados; consulte la captura de pantalla: