¿Cómo mover automáticamente distintos tipos de elementos eliminados a carpetas diferentes en Outlook?

En Outlook, todos los elementos eliminados (correos, tareas, contactos, etc.) se trasladan a la carpeta Elementos eliminados. Si desea organizarlos en subcarpetas diferenciadas por tipo dentro de la carpeta Elementos eliminados, tal como se muestra en la siguiente captura de pantalla, ¿cómo puede lograrlo en Outlook?

---

Mover automáticamente distintos tipos de Elementos eliminados a carpetas diferentes con código VBA

El siguiente código VBA le permite trasladar automáticamente los elementos eliminados a carpetas diferentes. Siga estos pasos:

1. Inicie Outlook y, a continuación, mantenga pulsadas las teclas ALT + F11 para abrir la ventana de Microsoft Visual Basic para Aplicaciones.

2. A continuación, haga doble clic en ThisOutlookSession en el panel Proyecto - Proyecto1 y copie y pegue el siguiente código en la ventana de código en blanco:

Código VBA: Mover automáticamente distintos tipos de Elementos eliminados a carpetas diferentes

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. A continuación, guarde este código y reinicie Outlook para activarlo.

4. A partir de ahora, cuando elimine un elemento, este se moverá automáticamente a la carpeta correspondiente a su tipo dentro de la carpeta Elementos eliminados.

5. Para ver el resultado, haga clic en el icono situado en la parte inferior del panel de carpetas y, a continuación, haga clic en Carpetas para acceder a «Expandir todas las carpetas» en el panel. Consulte las siguientes capturas de pantalla: