¿Cómo expandir automáticamente todas las carpetas al iniciar Outlook?

Normalmente, al expandir o contraer una carpeta en el panel de navegación de Outlook y luego cerrar el programa, dicha carpeta conserva su estado (expandido o contraído) la próxima vez que abra Outlook. Pero, ¿qué pasa si desea que todas las carpetas se expandan automáticamente cada vez que inicie Outlook? Este artículo le ofrece una solución mediante VBA para lograrlo.

Expandir todas las carpetas automáticamente al iniciar Outlook mediante VBA

---

Expandir todas las carpetas automáticamente al iniciar Outlook mediante VBA

Esta guía muestra cómo usar un script VBA para expandir automáticamente todas las carpetas en la navegación cada vez que inicie Outlook. Siga estos pasos para implementar el script VBA:

1. Pulse Alt + F11 simultáneamente para abrir la ventana de Microsoft Visual Basic para Aplicaciones.
2. Expanda el proyecto Project 1y Objetos de Microsoft Outlooken el panel Proyecto, haga doble clic para abrir la ventana ThisOutlookSessiony, a continuación, pegue el siguiente código VBA en ella.

   

   VBA: Expandir todas las carpetas automáticamente en Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Guarde el código y cierre la ventana de Microsoft Visual Basic para Aplicaciones.

A partir de ahora, al reiniciar Outlook, todas las carpetas se expandirán automáticamente.

---

Artículos relacionados